kdsoap-ws-discovery-client/src/CMakeLists.txt

0001 # SPDX-FileCopyrightText: 2019 Casper Meijn <casper@meijn.net>
0002 # SPDX-License-Identifier: GPL-3.0-or-later
0003 #
0004
0005 cmake_minimum_required(VERSION 3.7)
0006
0007 set(GLOBAL_KSWSDL2CPP_OPTION)
0008 get_filename_component(KDWSDL_IMPORT_PATH ../wsdl/ ABSOLUTE)
0009 set(GLOBAL_KSWSDL2CPP_OPTION -import-path ${KDWSDL_IMPORT_PATH} -use-local-files-only)
0010
0011 set(KSWSDL2CPP_OPTION -namespace WSDiscovery200901 ${GLOBAL_KSWSDL2CPP_OPTION})
0012 KDSOAP_GENERATE_WSDL(KDSoapWSDiscoveryClient_WSDL ${KDWSDL_IMPORT_PATH}/docs.oasis-open.org/ws-dd/discovery/1.1/os/wsdd-discovery-1.1-wsdl-os.wsdl)
0013 set(KSWSDL2CPP_OPTION -namespace WSDiscovery200504 ${GLOBAL_KSWSDL2CPP_OPTION})
0014 KDSOAP_GENERATE_WSDL(KDSoapWSDiscoveryClient_WSDL ${KDWSDL_IMPORT_PATH}/schemas.xmlsoap.org/ws/2005/04/discovery/ws-discovery.wsdl)
0015
0016 set(KDSoapWSDiscoveryClient_SRCS
0017     "wsdiscoveryclient.cpp"
0018     "wsdiscoveryprobejob.cpp"
0019     "wsdiscoverytargetservice.cpp"
0020     "wsdiscoveryserviceaggregator.cpp"
0021 )
0022
0023 ecm_qt_declare_logging_category(KDSoapWSDiscoveryClient_SRCS
0024     HEADER loggingcategory.h
0025     IDENTIFIER KDSoapWSDiscoveryClient
0026     CATEGORY_NAME kdsoap.wsdiscoveryclient
0027     DEFAULT_SEVERITY Warning
0028 )
0029
0030 add_library(KDSoapWSDiscoveryClient ${KDSoapWSDiscoveryClient_SRCS} ${KDSoapWSDiscoveryClient_WSDL})
0031 generate_export_header(KDSoapWSDiscoveryClient BASE_NAME WSDiscoveryClient)
0032 add_library(KDSoap::WSDiscoveryClient ALIAS KDSoapWSDiscoveryClient)
0033
0034 target_include_directories(KDSoapWSDiscoveryClient
0035     INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}/KDSoapWSDiscoveryClient>"
0036 )
0037
0038 target_link_libraries(KDSoapWSDiscoveryClient
0039     PUBLIC
0040         Qt${QT_MAJOR_VERSION}::Core
0041         KDSoap::kdsoap
0042     PRIVATE
0043 )
0044
0045 set_target_properties(KDSoapWSDiscoveryClient PROPERTIES
0046     VERSION     ${WSDISCOVERY_VERSION_STRING}
0047     SOVERSION   ${WSDISCOVERY_SOVERSION}
0048     EXPORT_NAME "WSDiscoveryClient"
0049 )
0050
0051 ecm_generate_headers(KDSoapWSDiscoveryClient_HEADERS
0052     HEADER_NAMES
0053     WSDiscoveryClient
0054     WSDiscoveryProbeJob
0055     WSDiscoveryTargetService
0056     WSDiscoveryServiceAggregator
0057
0058     REQUIRED_HEADERS KDSoapWSDiscoveryClient_HEADERS
0059 )
0060
0061 install(TARGETS KDSoapWSDiscoveryClient
0062         EXPORT KDSoapWSDiscoveryClientTargets
0063         ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0064
0065 install(FILES
0066             ${CMAKE_CURRENT_BINARY_DIR}/wsdiscoveryclient_export.h
0067             ${KDSoapWSDiscoveryClient_HEADERS}
0068         DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KDSoapWSDiscoveryClient
0069         COMPONENT Devel)
0070
0071 if(BUILD_QCH)
0072     ecm_add_qch(
0073         KDSoapWSDiscoveryClient_QCH
0074         NAME KDSoapWSDiscoveryClient
0075         BASE_NAME KDSoapWSDiscoveryClient
0076         VERSION ${WSDISCOVERY_VERSION}
0077         ORG_DOMAIN net.meijn
0078         SOURCES # using only public headers, to cover only public API
0079             ${KDSoapWSDiscoveryClient_HEADERS}
0080         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0081         LINK_QCHS
0082             Qt${QT_MAJOR_VERSION}Core_QCH
0083             KDSoap_QCH
0084         BLANK_MACROS
0085             KARCHIVE_EXPORT
0086             KARCHIVE_DEPRECATED
0087         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0088         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0089         COMPONENT Devel
0090     )
0091 endif()