libraries/kdsoap-ws-discovery-client/CMakeLists.txt

0001 # SPDX-FileCopyrightText: 2019 Casper Meijn <casper@meijn.net>
0002 # SPDX-License-Identifier: GPL-3.0-or-later
0003
0004 cmake_minimum_required(VERSION 3.7)
0005
0006 project(kdsoap-ws-discovery-client VERSION 0.3.0)
0007
0008 include(FeatureSummary)
0009 find_package(ECM 5.54.0  NO_MODULE)
0010 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://develop.kde.org/products/frameworks/")
0011 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0012 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0013
0014 include(CTest)
0015 include(KDEInstallDirs)
0016 include(KDECompilerSettings NO_POLICY_SCOPE)
0017 include(KDECMakeSettings)
0018 include(KDEClangFormat)
0019 include(KDEGitCommitHooks)
0020
0021 include(GenerateExportHeader)
0022
0023 set(REQUIRED_QT_VERSION 5.9.0)
0024 find_package(Qt${QT_MAJOR_VERSION} ${REQUIRED_QT_VERSION} REQUIRED NO_MODULE COMPONENTS Core Network Xml)
0025
0026 set(KDSOAP_REQUIRED_VERSION 2.0.0)
0027
0028 if (QT_MAJOR_VERSION EQUAL "6")
0029     set(KDSOAP_PACKAGE KDSoap-qt6)
0030 else()
0031     set(KDSOAP_PACKAGE KDSoap)
0032 endif()
0033 find_package(${KDSOAP_PACKAGE} ${KDSOAP_REQUIRED_VERSION} REQUIRED)
0034 set_package_properties(${KDSOAP_PACKAGE} PROPERTIES
0035     DESCRIPTION "A Qt-based client-side and server-side SOAP component"
0036     URL "http://www.kdab.com/products/kd-soap"
0037     TYPE REQUIRED
0038     PURPOSE "Support for SOAP client protocol"
0039 )
0040
0041 if (BUILD_TESTING)
0042     find_package(Qt${QT_MAJOR_VERSION} ${REQUIRED_QT_VERSION} CONFIG REQUIRED Test)
0043 endif()
0044
0045 include(ECMSetupVersion)
0046 include(ECMGenerateHeaders)
0047 include(ECMQtDeclareLoggingCategory)
0048 include(ECMAddQch)
0049
0050 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0051 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0052
0053 ecm_setup_version(PROJECT
0054     VARIABLE_PREFIX WSDISCOVERY
0055     VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/kdsoap_wsdiscovery_client_version.h"
0056     PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KDSoapWSDiscoveryClientConfigVersion.cmake"
0057 )
0058
0059 add_definitions(
0060     -DQT_NO_SIGNALS_SLOTS_KEYWORDS
0061 )
0062
0063 add_subdirectory(src)
0064 add_subdirectory(examples)
0065 add_subdirectory(docs)
0066 if(BUILD_TESTING)
0067     add_subdirectory(autotests)
0068 endif()
0069
0070 # create a Config.cmake and a ConfigVersion.cmake file and install them
0071 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KDSoapWSDiscoveryClient")
0072
0073 if (BUILD_QCH)
0074     ecm_install_qch_export(
0075         TARGETS KDSoapWSDiscoveryClient_QCH
0076         FILE KDSoapWSDiscoveryClientQchTargets.cmake
0077         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0078         COMPONENT Devel
0079     )
0080     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KDSoapWSDiscoveryClientQchTargets.cmake\")")
0081 endif()
0082
0083 include(CMakePackageConfigHelpers)
0084
0085 configure_package_config_file(
0086     "${CMAKE_CURRENT_SOURCE_DIR}/KDSoapWSDiscoveryClientConfig.cmake.in"
0087     "${CMAKE_CURRENT_BINARY_DIR}/KDSoapWSDiscoveryClientConfig.cmake"
0088     INSTALL_DESTINATION ${CMAKECONFIG_INSTALL_DIR}
0089 )
0090
0091 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/kdsoap_wsdiscovery_client_version.h
0092         DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KDSoapWSDiscoveryClient
0093         COMPONENT Devel)
0094
0095 install(FILES
0096             "${CMAKE_CURRENT_BINARY_DIR}/KDSoapWSDiscoveryClientConfig.cmake"
0097             "${CMAKE_CURRENT_BINARY_DIR}/KDSoapWSDiscoveryClientConfigVersion.cmake"
0098         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0099         COMPONENT Devel)
0100
0101 install(EXPORT KDSoapWSDiscoveryClientTargets
0102         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0103         FILE KDSoapWSDiscoveryClientTargets.cmake
0104         NAMESPACE KDSoap::)
0105
0106 file(GLOB_RECURSE ALL_CLANG_FORMAT_SOURCE_FILES *.cpp *.h)
0107 kde_clang_format(${ALL_CLANG_FORMAT_SOURCE_FILES})
0108 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)
0109
0110 feature_summary(
0111     WHAT ALL
0112     FATAL_ON_MISSING_REQUIRED_PACKAGES
0113 )