kdb/src/KDbConfig.cmake.in

0001 # KDbConfig.cmake provides information about the installed KDb library.
0002 # It can be used directly from CMake via find_package(KDb NO_MODULE)
0003 #
0004 # Any changes in this ".cmake" file will be overwritten by CMake, the source is the ".cmake.in" file.
0005 #
0006 # The following CMake variables are provided:
0007 #   KDb_VERSION_MAJOR - the major version number of KDb
0008 #   KDb_VERSION_MINOR - the minor version number of KDb
0009 #   KDb_VERSION_PATCH - the patch version number of KDb
0010 #   KDb_INCLUDE_DIRS  - the include directories to use
0011 #
0012 # Additionally, the following imported library targets are created, which may be used directly
0013 # with target_link_libraries():
0014 #   KDb - the KDb library
0015 #
0016 # Provided features are available under KDB_* variables at the end of this file.
0017
0018 @PACKAGE_INIT@
0019
0020 include(CMakeFindDependencyMacro)
0021
0022 find_dependency(Qt5Core @REQUIRED_QT_VERSION@)
0023 find_dependency(Qt5Widgets @REQUIRED_QT_VERSION@)
0024 find_dependency(Qt5Xml @REQUIRED_QT_VERSION@)
0025 find_dependency(KF5CoreAddons @REQUIRED_KF5_VERSION@)
0026
0027 include("${CMAKE_CURRENT_LIST_DIR}/KDbTargets.cmake")
0028 include("${CMAKE_CURRENT_LIST_DIR}/KDbQCHTargets.cmake")
0029
0030 # Features
0031 set(KDB_DEBUG_GUI @KDB_DEBUG_GUI@)
0032
0033 # Match COMPONENTS to features (KDB_ prefixes)
0034 #message(status " KDb_FIND_COMPONENTS=${KDb_FIND_COMPONENTS}")
0035 foreach (_COMP ${KDb_FIND_COMPONENTS})
0036     if(NOT DEFINED KDB_${_COMP} OR NOT ${KDB_${_COMP}})
0037         message(FATAL_ERROR "KDb does not contain required component ${_COMP}. Update KDb or remove this requirement.")
0038     endif()
0039 endforeach()
0040
0041 include(FeatureSummary)
0042 set_package_properties(KDb PROPERTIES
0043                        DESCRIPTION "Database connectivity and creation framework"
0044                        URL "https://community.kde.org/KDb")