libraries/kcgroups/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.10)
0002
0003 set(KF5_VERSION "5.73.0") # handled by release scripts
0004 project(KCGroups VERSION ${KF5_VERSION})
0005
0006 include(FeatureSummary)
0007 find_package(ECM 5.73.0 NO_MODULE)
0008 set_package_properties(
0009     ECM
0010     PROPERTIES
0011     TYPE
0012     REQUIRED
0013     DESCRIPTION
0014     "Extra CMake Modules."
0015     URL
0016     "https://commits.kde.org/extra-cmake-modules")
0017 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND
0018                 FATAL_ON_MISSING_REQUIRED_PACKAGES)
0019
0020 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0021
0022 include(KDEInstallDirs)
0023 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0024 include(KDECMakeSettings)
0025 include(ECMQtDeclareLoggingCategory)
0026
0027 set(CMAKE_CXX_STANDARD 17)
0028 set(CMAKE_CXX_STANDARD_REQUIRED OFF)
0029
0030 set(REQUIRED_QT_VERSION 5.11.0)
0031 find_package(Qt${QT_MAJOR_VERSION}DBus ${REQUIRED_QT_VERSION} REQUIRED NO_MODULE)
0032
0033 include(GenerateExportHeader)
0034 include(CMakePackageConfigHelpers)
0035 include(ECMSetupVersion)
0036 include(ECMGenerateHeaders)
0037 include(ECMAddQch)
0038 include(CheckIncludeFileCXX)
0039
0040 ecm_setup_version(PROJECT
0041     VARIABLE_PREFIX KCGROUPS
0042     VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/kcgroups_version.h"
0043     PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF5CGroupsConfigVersion.cmake"
0044     SOVERSION 5)
0045
0046 add_subdirectory(src)
0047 if(BUILD_TESTING)
0048     add_subdirectory(tests)
0049 endif()
0050
0051 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0052 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0053
0054 # create a Config.cmake and a ConfigVersion.cmake file and install them
0055 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF5CGroups")
0056
0057 if (BUILD_QCH)
0058     ecm_install_qch_export(
0059         TARGETS KF5CGroups_QCH
0060         FILE KF5CGroupsQchTargets.cmake
0061         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0062         COMPONENT Devel
0063     )
0064     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF5CGroupsQchTargets.cmake\")")
0065 endif()
0066
0067 configure_package_config_file(
0068     "${CMAKE_CURRENT_SOURCE_DIR}/KF5CGroupsConfig.cmake.in"
0069     "${CMAKE_CURRENT_BINARY_DIR}/KF5CGroupsConfig.cmake" INSTALL_DESTINATION
0070     ${CMAKECONFIG_INSTALL_DIR})
0071
0072 install(
0073     FILES "${CMAKE_CURRENT_BINARY_DIR}/KF5CGroupsConfig.cmake"
0074           "${CMAKE_CURRENT_BINARY_DIR}/KF5CGroupsConfigVersion.cmake"
0075     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0076     COMPONENT Devel)
0077
0078 install(
0079     EXPORT KF5CGroupsTargets
0080     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0081     FILE KF5CGroupsTargets.cmake
0082     NAMESPACE KF5::
0083     COMPONENT Devel)
0084
0085 install(
0086     FILES ${CMAKE_CURRENT_BINARY_DIR}/kcgroups_version.h
0087     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}
0088     COMPONENT Devel)
0089
0090 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)