libraries/kasync/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.0)
0002
0003 project(KAsync VERSION 0.3.0)
0004
0005 # ECM setup
0006 find_package(ECM 5.10.0 CONFIG REQUIRED)
0007 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0008 set(CMAKE_CXX_STANDARD 17)
0009
0010 include(KDEInstallDirs)
0011 include(KDECMakeSettings)
0012 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0013 include(GenerateExportHeader)
0014 include(ECMGenerateHeaders)
0015 include(ECMGeneratePriFile)
0016 include(CMakePackageConfigHelpers)
0017 include(ECMSetupVersion)
0018 include(FeatureSummary)
0019
0020 kde_enable_exceptions()
0021
0022 set(QT_REQUIRED_VERSION "5.2.0")
0023
0024 ecm_setup_version(${KAsync_VERSION}
0025     VARIABLE_PREFIX KASYNC
0026     VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/kasync_version.h"
0027     PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KAsyncConfigVersion.cmake"
0028     SOVERSION 0
0029 )
0030
0031
0032 ########### Find packages ###########
0033 find_package(Qt5 ${QT_REQUIRED_VERSION} REQUIRED COMPONENTS Core Test)
0034
0035 ########### Targets ###########
0036 add_subdirectory(src)
0037 add_subdirectory(autotests)
0038
0039
0040 ########### CMake Config Files ###########
0041 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KAsync")
0042
0043 configure_package_config_file(
0044     "${CMAKE_CURRENT_SOURCE_DIR}/KAsyncConfig.cmake.in"
0045     "${CMAKE_CURRENT_BINARY_DIR}/KAsyncConfig.cmake"
0046     INSTALL_DESTINATION ${CMAKECONFIG_INSTALL_DIR}
0047 )
0048
0049 install(FILES
0050     "${CMAKE_CURRENT_BINARY_DIR}/KAsyncConfig.cmake"
0051     "${CMAKE_CURRENT_BINARY_DIR}/KAsyncConfigVersion.cmake"
0052     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0053     COMPONENT Devel
0054 )
0055
0056 install(EXPORT
0057     KAsyncTargets
0058     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0059     FILE KAsyncTargets.cmake
0060     )
0061
0062 install(FILES
0063     ${CMAKE_CURRENT_BINARY_DIR}/kasync_version.h
0064     DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel
0065 )
0066
0067 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)