baloo-widgets/src/CMakeLists.txt

0001 add_definitions(-DTRANSLATION_DOMAIN=\"baloowidgets5\")
0002
0003 add_subdirectory(filepropertiesplugin)
0004 add_subdirectory(tagsfileitemactionplugin)
0005
0006 add_library(KF${QT_MAJOR_VERSION}BalooWidgets)
0007 add_library(KF${QT_MAJOR_VERSION}::BalooWidgets ALIAS KF${QT_MAJOR_VERSION}BalooWidgets)
0008 set_target_properties(KF${QT_MAJOR_VERSION}BalooWidgets PROPERTIES
0009     VERSION     ${BALOO_WIDGETS_VERSION}
0010     SOVERSION   ${BALOO_WIDGETS_SOVERSION}
0011     EXPORT_NAME BalooWidgets
0012 )
0013
0014 target_sources(KF${QT_MAJOR_VERSION}BalooWidgets PRIVATE
0015     extractor.cpp
0016     extractorutil_p.h
0017     filefetchjob.cpp
0018     filefetchjob.h
0019     filemetadataconfigwidget.cpp
0020     filemetadataconfigwidget.h
0021     filemetadataprovider.cpp
0022     filemetadataprovider.h
0023     filemetadatautil.cpp
0024     filemetadatautil_p.h
0025     filemetadatawidget.cpp
0026     filemetadatawidget.h
0027     kblocklayout.cpp
0028     kblocklayout.h
0029     kcommentwidget.cpp
0030     kcommentwidget_p.h
0031     keditcommentdialog.cpp
0032     keditcommentdialog.h
0033     kedittagsdialog.cpp
0034     kedittagsdialog_p.h
0035     metadatafilter.cpp
0036     metadatafilter.h
0037     ondemandextractor.cpp
0038     ondemandextractor.h
0039     tagcheckbox.cpp
0040     tagcheckbox.h
0041     tagwidget.cpp
0042     tagwidget.h
0043     widgetfactory.cpp
0044     widgetfactory.h
0045 )
0046
0047 ecm_qt_declare_logging_category(KF${QT_MAJOR_VERSION}BalooWidgets
0048     HEADER "widgetsdebug.h"
0049     IDENTIFIER "Baloo::WIDGETS"
0050     DEFAULT_SEVERITY Warning
0051     CATEGORY_NAME "org.kde.baloo.widgets"
0052     DESCRIPTION "Baloo Widgets"
0053     EXPORT BALOO_WIDGETS
0054 )
0055
0056 target_link_libraries(KF${QT_MAJOR_VERSION}BalooWidgets
0057   PUBLIC
0058   Qt${QT_MAJOR_VERSION}::Widgets
0059   Qt${QT_MAJOR_VERSION}::Core
0060   KF${QT_MAJOR_VERSION}::KIOCore # KFileItem
0061   KF${QT_MAJOR_VERSION}::CoreAddons # KProcess, KJob
0062
0063   PRIVATE
0064   KF${QT_MAJOR_VERSION}::I18n
0065   KF${QT_MAJOR_VERSION}::FileMetaData
0066   KF${QT_MAJOR_VERSION}::WidgetsAddons
0067   KF${QT_MAJOR_VERSION}::Baloo
0068   KF${QT_MAJOR_VERSION}::CoreAddons
0069   KF${QT_MAJOR_VERSION}::ConfigGui
0070   KF${QT_MAJOR_VERSION}::Service
0071 )
0072
0073 target_include_directories(KF${QT_MAJOR_VERSION}BalooWidgets INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/BalooWidgets>")
0074
0075 ecm_generate_export_header(KF${QT_MAJOR_VERSION}BalooWidgets
0076     BASE_NAME BALOO_WIDGETS
0077     EXPORT_FILE_NAME widgets_export.h
0078     VERSION ${BALOO_WIDGETS_VERSION}
0079     DEPRECATED_BASE_VERSION 0
0080     DEPRECATION_VERSIONS 23.08
0081     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0082 )
0083
0084 install(TARGETS KF${QT_MAJOR_VERSION}BalooWidgets EXPORT KF${QT_MAJOR_VERSION}BalooWidgetsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0085
0086 ecm_generate_headers(KFBalooWidgets_CamelCase_HEADERS
0087     HEADER_NAMES
0088     TagWidget
0089     FileMetaDataWidget
0090     FileMetaDataConfigWidget
0091
0092     PREFIX baloo
0093     REQUIRED_HEADERS KFBalooWidgets_HEADERS
0094 )
0095
0096 install(FILES
0097   ${KFBalooWidgets_CamelCase_HEADERS}
0098   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/BalooWidgets/Baloo
0099   COMPONENT Devel
0100 )
0101
0102 install(FILES
0103   ${CMAKE_CURRENT_BINARY_DIR}/widgets_export.h
0104   ${KFBalooWidgets_HEADERS}
0105   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/BalooWidgets/baloo
0106   COMPONENT Devel
0107 )
0108
0109 #
0110 # Extractor Process
0111 #
0112 add_executable(baloo_filemetadata_temp_extractor extractor.cpp)
0113 target_link_libraries(baloo_filemetadata_temp_extractor
0114   Qt${QT_MAJOR_VERSION}::Core
0115   KF${QT_MAJOR_VERSION}::I18n
0116   KF${QT_MAJOR_VERSION}::FileMetaData
0117 )
0118
0119 install(TARGETS baloo_filemetadata_temp_extractor DESTINATION ${KDE_INSTALL_BINDIR})
0120
0121 ecm_qt_install_logging_categories(
0122     EXPORT BALOO_WIDGETS
0123     FILE baloo-widgets.categories
0124     DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0125 )