libraries/baloo-widgets/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 # KDE Application Version, managed by release script
0004 set (RELEASE_SERVICE_VERSION_MAJOR "23")
0005 set (RELEASE_SERVICE_VERSION_MINOR "04")
0006 set (RELEASE_SERVICE_VERSION_MICRO "1")
0007 set (RELEASE_SERVICE_VERSION "${RELEASE_SERVICE_VERSION_MAJOR}.${RELEASE_SERVICE_VERSION_MINOR}.${RELEASE_SERVICE_VERSION_MICRO}")
0008 project(baloo-widgets VERSION ${RELEASE_SERVICE_VERSION})
0009
0010 set(QT_MIN_VERSION "5.15.2")
0011 set(KF5_MIN_VERSION "5.92.0")
0012
0013 find_package(ECM ${KF5_MIN_VERSION} REQUIRED NO_MODULE)
0014 set(CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules" ${ECM_MODULE_PATH})
0015
0016
0017 include(KDEInstallDirs)
0018 include(KDECMakeSettings)
0019 include(KDECompilerSettings NO_POLICY_SCOPE)
0020 include(KDEClangFormat)
0021 include(KDEGitCommitHooks)
0022
0023 include(ECMSetupVersion)
0024 include(ECMInstallIcons)
0025
0026 include(GenerateExportHeader)
0027 include(FeatureSummary)
0028 include(ECMGenerateHeaders)
0029 include(ECMAddTests)
0030 include(ECMQtDeclareLoggingCategory)
0031 include(CMakePackageConfigHelpers)
0032 include(ECMDeprecationSettings)
0033
0034 find_package(Qt${QT_MAJOR_VERSION} ${QT_MIN_VERSION} REQUIRED NO_MODULE COMPONENTS Core Widgets Test)
0035 find_package(KF5 ${KF5_MIN_VERSION} REQUIRED COMPONENTS Config KIO I18n FileMetaData Baloo Service)
0036
0037 ecm_setup_version(PROJECT
0038                   VARIABLE_PREFIX BALOO_WIDGETS
0039                   SOVERSION 5
0040                   VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/baloowidgets_version.h"
0041                   PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF5BalooWidgetsConfigVersion.cmake")
0042
0043 ecm_set_disabled_deprecation_versions(QT 5.15.2
0044      KF 5.102.0
0045     )
0046 add_subdirectory(src)
0047 if (BUILD_TESTING)
0048   add_subdirectory(test)
0049   add_subdirectory(autotests)
0050 endif()
0051
0052 ki18n_install(po)
0053
0054 # Config files
0055 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF5BalooWidgets")
0056
0057 configure_package_config_file(
0058     "${CMAKE_CURRENT_SOURCE_DIR}/KF5BalooWidgetsConfig.cmake.in"
0059     "${CMAKE_CURRENT_BINARY_DIR}/KF5BalooWidgetsConfig.cmake"
0060     INSTALL_DESTINATION ${CMAKECONFIG_INSTALL_DIR}
0061 )
0062
0063 install(FILES
0064     "${CMAKE_CURRENT_BINARY_DIR}/KF5BalooWidgetsConfig.cmake"
0065     "${CMAKE_CURRENT_BINARY_DIR}/KF5BalooWidgetsConfigVersion.cmake"
0066     DESTINATION ${CMAKECONFIG_INSTALL_DIR}
0067     COMPONENT devel
0068 )
0069
0070 install(EXPORT KF5BalooWidgetsTargets
0071         NAMESPACE KF5::
0072         DESTINATION ${CMAKECONFIG_INSTALL_DIR}
0073         FILE KF5BalooWidgetsTargets.cmake
0074 )
0075
0076 feature_summary(WHAT ALL
0077     INCLUDE_QUIET_PACKAGES
0078     FATAL_ON_MISSING_REQUIRED_PACKAGES
0079 )
0080
0081 file(GLOB_RECURSE CLANG_FORMAT_SOURCE_FILES *.cpp *.h)
0082 kde_clang_format(${CLANG_FORMAT_SOURCE_FILES})
0083
0084 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)