src/core/CMakeLists.txt

0001 # SPDX-FileCopyrightText: AtCore Authors
0002 # SPDX-License-Identifier: BSD-3-Clause
0003
0004 #
0005 # Create the Library.
0006 #
0007 configure_file(
0008     atcore_default_folders.h.in
0009     ${CMAKE_CURRENT_BINARY_DIR}/atcore_default_folders.h
0010 )
0011
0012 find_package(Qt${QT_MAJOR_VERSION} REQUIRED COMPONENTS
0013     Quick
0014 )
0015
0016 set(AtCoreLib_SRCS
0017     atcore.cpp
0018     beddeform.cpp
0019     gcodecommands.cpp
0020     ifirmware.cpp
0021     machineinfo.cpp
0022     printthread.cpp
0023     seriallayer.cpp
0024     temperature.cpp
0025 )
0026
0027 add_library(AtCore SHARED ${AtCoreLib_SRCS})
0028 target_link_libraries(AtCore Qt::Core Qt::SerialPort Qt::Quick)
0029
0030 #
0031 #
0032 # Configure the Library
0033 #
0034 #
0035
0036 add_library(AtCore::AtCore ALIAS AtCore)
0037
0038 target_include_directories(AtCore INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}/AtCore>")
0039
0040 set_target_properties(AtCore PROPERTIES VERSION ${ATCORE_VERSION_STRING}
0041     SOVERSION ${ATCORE_SOVERSION}
0042     EXPORT_NAME AtCore
0043 )
0044
0045
0046 ecm_generate_headers(ATCORE_CamelCase_HEADERS
0047     HEADER_NAMES
0048     AtCore
0049     BedDeform
0050     GCodeCommands
0051     IFirmware
0052     MachineInfo
0053     SerialLayer
0054     Temperature
0055     REQUIRED_HEADERS ATCORE_HEADERS
0056 )
0057
0058 ecm_create_qm_loader(AtCoreLib_SRCS atcore_qt)
0059
0060 generate_export_header(AtCore BASE_NAME atcore)
0061
0062
0063 configure_package_config_file("${CMAKE_CURRENT_SOURCE_DIR}/AtCoreConfig.cmake.in"
0064                               "${CMAKE_CURRENT_BINARY_DIR}/AtCoreConfig.cmake"
0065                               INSTALL_DESTINATION ${CMAKECONFIG_INSTALL_DIR}
0066 )
0067
0068
0069 #
0070 #
0071 # Install the Library
0072 #
0073 #
0074
0075 install(FILES
0076     "${CMAKE_CURRENT_BINARY_DIR}/AtCoreConfig.cmake"
0077     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0078     COMPONENT Devel
0079 )
0080
0081 install(FILES
0082     ${CMAKE_CURRENT_BINARY_DIR}/atcore_export.h
0083     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/AtCore COMPONENT Devel
0084 )
0085
0086 install(FILES
0087     ${CMAKE_CURRENT_BINARY_DIR}/atcore_default_folders.h
0088     ${ATCORE_HEADERS}
0089     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/AtCore COMPONENT Devel
0090 )
0091
0092 install(FILES
0093     ${ATCORE_CamelCase_HEADERS}
0094     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/AtCore
0095 )
0096
0097 install(
0098     TARGETS
0099         AtCore
0100     EXPORT
0101         AtCoreTargets
0102     ${KDE_INSTALL_TARGETS_DEFAULT_ARGS}
0103 )
0104 if(${QT_MAJOR_VERSION} EQUAL "5")
0105   ecm_generate_pri_file(
0106       BASE_NAME AtCore
0107       LIB_NAME AtCore
0108       DEPS "Qt${QT_MAJOR_VERSION}Core Qt${QT_MAJOR_VERSION}SerialPort"
0109       FILENAME_VAR PRI_FILENAME
0110       INCLUDE_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/include/AtCore
0111   )
0112   install(FILES ${PRI_FILENAME} DESTINATION ${ECM_MKSPECS_INSTALL_DIR})
0113 endif()