plugins/patchreview/CMakeLists.txt

0001 find_package(LibKompareDiff2 5.1 CONFIG)
0002 set_package_properties(LibKompareDiff2 PROPERTIES
0003     PURPOSE "Required for building the patch review plugin."
0004     TYPE REQUIRED
0005 )
0006
0007 find_package(KF5Purpose CONFIG QUIET)
0008 set_package_properties(KF5Purpose PROPERTIES DESCRIPTION "Support for patch sharing"
0009                        TYPE OPTIONAL
0010                       )
0011 if (NOT KF5Purpose_FOUND)
0012     find_package(KDEExperimentalPurpose QUIET)
0013     set_package_properties(KDEExperimentalPurpose PROPERTIES DESCRIPTION "EXPERIMENTAL. Support for patch sharing"
0014                         URL "https://projects.kde.org/projects/playground/libs/purpose"
0015                         TYPE OPTIONAL
0016                         )
0017 endif()
0018
0019 add_definitions(-DTRANSLATION_DOMAIN=\"kdevpatchreview\")
0020 kde_enable_exceptions()
0021
0022 set(patchreview_PART_SRCS
0023     patchreview.cpp
0024     patchhighlighter.cpp
0025     patchreviewtoolview.cpp
0026     localpatchsource.cpp
0027 )
0028
0029 declare_qt_logging_category(patchreview_PART_SRCS
0030     TYPE PLUGIN
0031     IDENTIFIER PLUGIN_PATCHREVIEW
0032     CATEGORY_BASENAME "patchreview"
0033 )
0034 ki18n_wrap_ui(patchreview_PART_SRCS patchreview.ui localpatchwidget.ui)
0035
0036 qt5_add_resources(patchreview_PART_SRCS kdevpatchreview.qrc)
0037 kdevplatform_add_plugin(kdevpatchreview SOURCES ${patchreview_PART_SRCS})
0038 target_link_libraries(kdevpatchreview
0039     KDev::Project
0040     KDev::Interfaces
0041     KDev::Util
0042     KDev::Language
0043     KDev::Vcs
0044     KDev::Sublime
0045     ${LIBKOMPAREDIFF2_LIBRARIES} # from cmake config file, has matching target name, which changed for 5.1
0046     KF5::IconThemes
0047     KF5::TextEditor
0048     KF5::Parts
0049 )
0050 if (LibKompareDiff2_VERSION VERSION_GREATER_EQUAL 5.4.0)
0051     # KompareDiff2 installs a working version header only since 5.4 (23.08.0)
0052     # so to work also with old versions instead of the sources including
0053     # the version header a compile definition flag is used
0054     target_compile_definitions(kdevpatchreview PRIVATE WITH_KOMPAREDIFF2_5_4_OR_NEWER)
0055 endif()
0056 if (KF5Purpose_FOUND)
0057     target_compile_definitions(kdevpatchreview PRIVATE WITH_PURPOSE)
0058     target_link_libraries(kdevpatchreview KF5::PurposeWidgets)
0059 elseif (KDEExperimentalPurpose_FOUND)
0060     target_compile_definitions(kdevpatchreview PRIVATE WITH_PURPOSE)
0061     target_link_libraries(kdevpatchreview KDEExperimental::PurposeWidgets)
0062 endif()