plugins/debuggercommon/CMakeLists.txt

0001 add_definitions(-DTRANSLATION_DOMAIN=\"kdevdebuggercommon\")
0002 set(debuggercommon_SRCS
0003     mi/mi.cpp
0004     mi/milexer.cpp
0005     mi/miparser.cpp
0006     mi/micommand.cpp
0007     mi/micommandqueue.cpp
0008     dbgglobal.cpp
0009     dialogs/selectcoredialog.cpp
0010     # debug session & debugger
0011     midebugger.cpp
0012     midebugsession.cpp
0013     midebuggerplugin.cpp
0014     midebugjobs.cpp
0015     # controllers
0016     mibreakpointcontroller.cpp
0017     miframestackmodel.cpp
0018     mivariablecontroller.cpp
0019     mivariable.cpp
0020     stringhelpers.cpp
0021     stty.cpp
0022     # tool views
0023     widgets/debuggerconsoleview.cpp
0024     widgets/disassemblewidget.cpp
0025     # register
0026     registers/registersview.cpp
0027     registers/registercontroller.cpp
0028     registers/registersmanager.cpp
0029     registers/registercontroller_x86.cpp
0030     registers/registercontroller_arm.cpp
0031     registers/modelsmanager.cpp
0032     registers/converters.cpp
0033 )
0034 if(KF5SysGuard_FOUND OR KSysGuard_FOUND)
0035     list(APPEND debuggercommon_SRCS
0036         dialogs/processselection.cpp
0037     )
0038 endif()
0039
0040 declare_qt_logging_category(debuggercommon_SRCS
0041     TYPE PLUGIN
0042     HEADER debuglog.h
0043     IDENTIFIER DEBUGGERCOMMON
0044     CATEGORY_BASENAME "debuggercommon"
0045 )
0046
0047 ki18n_wrap_ui(debuggercommon_SRCS
0048     dialogs/selectcoredialog.ui
0049     widgets/debuggerconsoleview.ui
0050     widgets/selectaddressdialog.ui
0051     registers/registersview.ui
0052 )
0053
0054 # Use old behavior (ignore the visibility properties for static libraries, object
0055 # libraries, and executables without exports) on target kdevdebuggercommon (so the
0056 # default public visibility is used).
0057 # kdevdebuggercommon is used by target test_gdb which is added by ecm_add_test,
0058 # which doesn't set CMP0063 so old behavior is used.
0059 # If kdevdebuggercommon honors visibility properties (set to hidden), it will cause
0060 # linker warnings about direct access to global weak symbol when link against test_gdb
0061 if(POLICY CMP0063)
0062     cmake_policy(SET CMP0063 OLD)
0063 endif()
0064
0065 add_library(kdevdebuggercommon STATIC ${debuggercommon_SRCS})
0066 target_link_libraries(kdevdebuggercommon
0067     PUBLIC
0068     KDev::Debugger
0069     KDev::OutputView
0070     KDev::Sublime
0071     PRIVATE
0072     Qt5::Core
0073     Qt5::Gui
0074     Qt5::Widgets
0075     KDev::Util
0076     KDev::Language
0077     KDev::IExecute
0078 )
0079 target_include_directories(kdevdebuggercommon
0080     PUBLIC ${CMAKE_CURRENT_BINARY_DIR}
0081 )
0082 if(KSysGuard_FOUND)
0083     target_link_libraries(kdevdebuggercommon
0084         PUBLIC
0085             KSysGuard::ProcessUi
0086     )
0087 elseif(KF5SysGuard_FOUND)
0088     target_link_libraries(kdevdebuggercommon
0089         PUBLIC
0090         KF5::ProcessUi
0091     )
0092 endif()
0093
0094 kde_target_enable_exceptions(kdevdebuggercommon PUBLIC)
0095
0096 if(BUILD_TESTING)
0097     add_subdirectory(tests)
0098 endif()