plugins/custom-definesandincludes/CMakeLists.txt

0001 add_definitions(-DTRANSLATION_DOMAIN=\"kdevcustomdefinesandincludes\")
0002
0003 declare_qt_logging_category(kdevdefinesandincludesmanager_LOG_SRCS
0004     TYPE PLUGIN
0005     IDENTIFIER DEFINESANDINCLUDES
0006     CATEGORY_BASENAME "definesandincludes"
0007 )
0008
0009 if(BUILD_TESTING)
0010     add_subdirectory(tests)
0011 endif()
0012 add_subdirectory(compilerprovider)
0013 add_subdirectory(noprojectincludesanddefines)
0014
0015 set( kdevdefinesandincludesmanager_SRCS
0016         definesandincludesmanager.cpp
0017         kcm_widget/projectpathsmodel.cpp
0018         kcm_widget/definesmodel.cpp
0019         kcm_widget/includesmodel.cpp
0020         kcm_widget/includeswidget.cpp
0021         kcm_widget/defineswidget.cpp
0022         kcm_widget/projectpathswidget.cpp
0023         kcm_widget/definesandincludesconfigpage.cpp
0024         kcm_widget/parserwidget.cpp
0025         compilerprovider/icompiler.cpp # TODO: is this really necessary
0026     )
0027
0028 ki18n_wrap_ui(kdevdefinesandincludesmanager_SRCS
0029     kcm_widget/batchedit.ui
0030     kcm_widget/includeswidget.ui
0031     kcm_widget/defineswidget.ui
0032     kcm_widget/projectpathswidget.ui
0033     kcm_widget/parserwidget.ui
0034 )
0035 kconfig_add_kcfg_files( kdevdefinesandincludesmanager_SRCS kcm_widget/customdefinesandincludes.kcfgc)
0036
0037 kdevplatform_add_plugin(kdevdefinesandincludesmanager SOURCES ${kdevdefinesandincludesmanager_SRCS})
0038 target_link_libraries( kdevdefinesandincludesmanager
0039     PRIVATE
0040         kdevnoprojectincludesanddefines
0041         kdevcompilerprovider
0042         KDev::Project
0043         KDev::Util
0044         KDev::Language
0045 )
0046
0047 option(BUILD_kdev_includepathsconverter "Build utility to modify include paths of a project from command line." ON)
0048 if(BUILD_kdev_includepathsconverter)
0049     add_executable(kdev_includepathsconverter includepathsconverter.cpp)
0050     ecm_mark_nongui_executable(kdev_includepathsconverter)
0051     target_link_libraries(kdev_includepathsconverter
0052         PRIVATE
0053             kdevcompilerprovider
0054             KDev::Project
0055     )
0056     install(TARGETS kdev_includepathsconverter ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} )
0057 endif()
0058
0059 install(FILES
0060     idefinesandincludesmanager.h
0061     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/kdevelop/custom-definesandincludes COMPONENT Devel
0062 )
0063
0064 add_library(kdevdefinesandincludesmanager_interface INTERFACE)
0065 add_library(KDev::DefinesAndIncludesManager ALIAS kdevdefinesandincludesmanager_interface)
0066 target_include_directories(kdevdefinesandincludesmanager_interface INTERFACE
0067      "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/../>"
0068      "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}/kdevelop>"
0069 )
0070 set_target_properties(kdevdefinesandincludesmanager_interface PROPERTIES
0071     EXPORT_NAME DefinesAndIncludesManager
0072 )
0073 install(TARGETS kdevdefinesandincludesmanager_interface EXPORT KDevelopTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})