kdevplatform/documentation/CMakeLists.txt

0001 add_definitions(-DTRANSLATION_DOMAIN=\"kdevplatform\")
0002
0003 find_package(Qt5WebEngineWidgets CONFIG)
0004 if(TARGET Qt5::WebEngineWidgets)
0005     set_package_properties(Qt5WebEngineWidgets PROPERTIES
0006         PURPOSE "QtWebEngine, for integrated documentation"
0007         URL "https://qt.io/"
0008         TYPE REQUIRED)
0009 else()
0010     find_package(Qt5WebKitWidgets CONFIG)
0011     set_package_properties(Qt5WebKitWidgets PROPERTIES
0012         PURPOSE "QtWebKit, for integrated documentation"
0013         URL "https://qt.io/"
0014         TYPE REQUIRED)
0015     set(USE_QTWEBKIT 1)
0016 endif()
0017
0018 set(KDevPlatformDocumentation_LIB_SRCS
0019     standarddocumentationview.cpp
0020     documentationfindwidget.cpp
0021     documentationview.cpp
0022 )
0023
0024 declare_qt_logging_category(KDevPlatformDocumentation_LIB_SRCS
0025     TYPE LIBRARY
0026     CATEGORY_BASENAME "documentation"
0027 )
0028
0029 ki18n_wrap_ui(KDevPlatformDocumentation_LIB_SRCS documentationfindwidget.ui)
0030 kdevplatform_add_library(KDevPlatformDocumentation SOURCES ${KDevPlatformDocumentation_LIB_SRCS})
0031
0032 target_link_libraries(KDevPlatformDocumentation
0033 PUBLIC
0034     KDev::Interfaces
0035 PRIVATE
0036     KDev::Util
0037 )
0038
0039 if(USE_QTWEBKIT)
0040     target_link_libraries(KDevPlatformDocumentation PRIVATE Qt5::WebKitWidgets)
0041     target_compile_definitions(KDevPlatformDocumentation PUBLIC -DUSE_QTWEBKIT)
0042 else()
0043     target_link_libraries(KDevPlatformDocumentation PRIVATE Qt5::WebEngineWidgets)
0044 endif()
0045
0046 install(FILES
0047     documentationfindwidget.h
0048     standarddocumentationview.h
0049     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/kdevplatform/documentation COMPONENT Devel
0050  )