kdevelop/kdevplatform/CMakeLists.txt

0001 # kdevplatform soversion
0002 # E.g. for KDevelop 5.2.0 => SOVERSION 52 (we only promise ABI compatibility between patch version updates)
0003 set(KDEVPLATFORM_SOVERSION ${KDEVELOP_SOVERSION})
0004
0005 # Increase this to reset incompatible item-repositories.
0006 # Changing KDevelop's major or minor version automatically resets the itemrepository as well.
0007 set(KDEV_ITEMREPOSITORY_INCREMENT 4)
0008
0009 set(KDevPlatform_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
0010 set(KDevPlatform_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
0011
0012 set(CMAKE_MODULE_PATH ${KDevPlatform_SOURCE_DIR}/cmake/modules ${ECM_MODULE_PATH})
0013 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KDevPlatform")
0014
0015 include(KDevPlatformMacros)
0016 include(KDevPlatformMacrosInternal)
0017
0018 # have to set required in find_package call already
0019 # as macros & imported targets are used later, so would fail over that before doing summary log
0020 find_package(Grantlee5 CONFIG REQUIRED)
0021 set_package_properties(Grantlee5 PROPERTIES
0022     PURPOSE "Grantlee templating library, needed for file templates"
0023     URL "http://www.grantlee.org/"
0024     TYPE REQUIRED)
0025
0026 set(Boost_ADDITIONAL_VERSIONS 1.39.0 1.39)
0027 find_package(Boost 1.35.0)
0028 set_package_properties(Boost PROPERTIES
0029     PURPOSE "Boost libraries for enabling the classbrowser"
0030     URL "https://www.boost.org/"
0031     TYPE REQUIRED)
0032
0033 configure_file( ${CMAKE_CURRENT_SOURCE_DIR}/config-kdevplatform.h.cmake
0034                 ${CMAKE_CURRENT_BINARY_DIR}/config-kdevplatform.h )
0035
0036 include_directories(${KDevPlatform_SOURCE_DIR} ${KDevPlatform_BINARY_DIR})
0037
0038 if(BUILD_TESTING)
0039   set(KDEV_FIND_DEP_QT5TEST "find_dependency(Qt5Test \"${QT_MIN_VERSION}\")")
0040 endif()
0041 configure_package_config_file("${CMAKE_CURRENT_SOURCE_DIR}/KDevPlatformConfig.cmake.in"
0042                               "${CMAKE_CURRENT_BINARY_DIR}/KDevPlatformConfig.cmake"
0043                               INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0044 )
0045
0046 ecm_setup_version(PROJECT
0047                   VARIABLE_PREFIX KDEVPLATFORM
0048                   VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/kdevplatform_version.h"
0049                   PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KDevPlatformConfigVersion.cmake"
0050                   SOVERSION ${KDEVPLATFORM_SOVERSION}
0051 )
0052
0053 add_subdirectory(sublime)
0054 add_subdirectory(interfaces)
0055 add_subdirectory(project)
0056 add_subdirectory(language)
0057 add_subdirectory(shell)
0058 add_subdirectory(util)
0059 add_subdirectory(outputview)
0060 add_subdirectory(vcs)
0061 add_subdirectory(pics)
0062 add_subdirectory(debugger)
0063 add_subdirectory(documentation)
0064 add_subdirectory(serialization)
0065 add_subdirectory(template)
0066 if(BUILD_TESTING)
0067   add_subdirectory(tests)
0068 endif()
0069
0070
0071 install( FILES
0072         "${KDevPlatform_BINARY_DIR}/kdevplatform_version.h"
0073         "${KDevPlatform_BINARY_DIR}/config-kdevplatform.h"
0074         DESTINATION "${KDE_INSTALL_INCLUDEDIR}/kdevplatform" )
0075 install( FILES
0076         "${KDevPlatform_BINARY_DIR}/KDevPlatformConfig.cmake"
0077         "${KDevPlatform_BINARY_DIR}/KDevPlatformConfigVersion.cmake"
0078         cmake/modules/KDevPlatformMacros.cmake
0079         DESTINATION "${CMAKECONFIG_INSTALL_DIR}" )
0080 install( EXPORT KDevPlatformTargets
0081          DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0082          NAMESPACE KDev::
0083          FILE KDevPlatformTargets.cmake )
0084
0085 # kdebugsettings file
0086 install_qt_logging_categories(TYPE LIBRARY)