Warning, /kdevelop/kdevelop/app/CMakeLists.txt is written in an unsupported language. File is not indexed.

0001 find_package(KF5Plasma CONFIG)
0002 set_package_properties(KF5Plasma PROPERTIES
0003     PURPOSE "Plasma libraries for enabling the plasma addons"
0004     URL "https://www.kde.org"
0005     TYPE OPTIONAL)
0006 if(KF5Plasma_FOUND)
0007     add_subdirectory(plasma)
0008 endif()
0009 
0010 option(KDEVELOP_SINGLE_APP "Use QtSingleApplication as KDevelop's base" OFF)
0011 
0012 set(kdevelop_SRCS  main.cpp kdevideextension.cpp)
0013 set_source_files_properties(main.cpp PROPERTIES
0014     COMPILE_DEFINITIONS "RELEASE_SERVICE_VERSION_STRING=\"${RELEASE_SERVICE_VERSION}\""
0015 )
0016 declare_qt_logging_category(kdevelop_SRCS
0017     IDENTIFIER APP
0018     TYPE APP
0019 )
0020 
0021 qt5_add_resources(kdevelop_SRCS kdevelop.qrc)
0022 
0023 #TODO: remove CMAKE_CURRENT_SOURCE_DIR prefix when ECM is fixed
0024 set(kdevelop_PNG_ICONS
0025     ${CMAKE_CURRENT_SOURCE_DIR}/icons/16-apps-kdevelop.png
0026     ${CMAKE_CURRENT_SOURCE_DIR}/icons/32-apps-kdevelop.png
0027     ${CMAKE_CURRENT_SOURCE_DIR}/icons/48-apps-kdevelop.png
0028     ${CMAKE_CURRENT_SOURCE_DIR}/icons/64-apps-kdevelop.png
0029     ${CMAKE_CURRENT_SOURCE_DIR}/icons/128-apps-kdevelop.png
0030     ${CMAKE_CURRENT_SOURCE_DIR}/icons/256-apps-kdevelop.png
0031     ${CMAKE_CURRENT_SOURCE_DIR}/icons/512-apps-kdevelop.png
0032     ${CMAKE_CURRENT_SOURCE_DIR}/icons/1024-apps-kdevelop.png
0033 )
0034 set(kdevelop_SVG_ICONS
0035     ${CMAKE_CURRENT_SOURCE_DIR}/icons/sc-apps-kdevelop.svg
0036 )
0037 ecm_install_icons(
0038     ICONS
0039         ${kdevelop_PNG_ICONS}
0040         ${kdevelop_SVG_ICONS}
0041     DESTINATION ${KDE_INSTALL_ICONDIR}
0042 )
0043 ecm_add_app_icon(kdevelop_SRCS
0044     ICONS ${kdevelop_PNG_ICONS}
0045 )
0046 
0047 qt5_add_resources(kdevelop_SRCS kdevelop.qrc)
0048 add_executable(kdevelop ${kdevelop_SRCS} )
0049 target_link_libraries(kdevelop
0050     KDev::Interfaces
0051     KDev::Shell
0052     KDev::Util
0053 
0054     KF5::Declarative
0055     KF5::Crash
0056 
0057     Qt5::Quick
0058 )
0059 IF(APPLE)
0060     target_link_libraries(kdevelop "-framework CoreFoundation")
0061 ENDIF()
0062 if(KDEVELOP_SINGLE_APP)
0063     add_subdirectory(3rdparty/qtsingleapplication)
0064     target_link_libraries(kdevelop qtsingleapplication)
0065 endif()
0066 
0067 install(TARGETS kdevelop ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} )
0068 
0069 install(FILES kdevelop! DESTINATION bin PERMISSIONS OWNER_EXECUTE OWNER_WRITE OWNER_READ GROUP_EXECUTE GROUP_READ WORLD_EXECUTE WORLD_READ)
0070 configure_file(start-kdevelop.py.in ${CMAKE_CURRENT_BINARY_DIR}/start-kdevelop.py @ONLY)
0071 
0072 option(INSTALL_KDEVELOP_LAUNCH_WRAPPER "Install a wrapper script that sets required environment variables. Only useful when installing into a separate prefix" OFF)
0073 if(INSTALL_KDEVELOP_LAUNCH_WRAPPER)
0074     install(FILES ${CMAKE_CURRENT_BINARY_DIR}/start-kdevelop.py DESTINATION bin PERMISSIONS OWNER_EXECUTE OWNER_WRITE OWNER_READ GROUP_EXECUTE GROUP_READ WORLD_EXECUTE WORLD_READ)
0075 endif()
0076 
0077 if (WIN32)
0078 install(FILES windows/kdevelop-msvc.bat DESTINATION bin PERMISSIONS OWNER_EXECUTE OWNER_READ GROUP_EXECUTE GROUP_READ WORLD_EXECUTE WORLD_READ)
0079 endif (WIN32)
0080 
0081 if (APPLE)
0082     # the MacOSX bundle display name property (CFBundleDisplayName) is not currently supported by cmake,
0083     # so has to be set for all targets in this cmake file
0084     set(MACOSX_BUNDLE_DISPLAY_NAME KDevelop)
0085     # We provide our own Info.plist to disable AppNap for KDevelop:
0086     set_target_properties(kdevelop PROPERTIES MACOSX_BUNDLE_INFO_PLIST ${CMAKE_CURRENT_SOURCE_DIR}/Info.plist.in)
0087     set_target_properties(kdevelop PROPERTIES MACOSX_BUNDLE_GUI_IDENTIFIER "org.kde.KDevelop")
0088     set_target_properties(kdevelop PROPERTIES MACOSX_BUNDLE_BUNDLE_NAME "KDevelop")
0089     set_target_properties(kdevelop PROPERTIES MACOSX_BUNDLE_DISPLAY_NAME "KDevelop")
0090     set_target_properties(kdevelop PROPERTIES MACOSX_BUNDLE_INFO_STRING "The KDevelop Integrated Development Environment")
0091     set_target_properties(kdevelop PROPERTIES MACOSX_BUNDLE_LONG_VERSION_STRING "KDevelop ${KDevelop_VERSION_MAJOR}.${KDevelop_VERSION_MINOR}")
0092     set_target_properties(kdevelop PROPERTIES MACOSX_BUNDLE_SHORT_VERSION_STRING "${KDevelop_VERSION_MAJOR}.${KDevelop_VERSION_MINOR}")
0093     set_target_properties(kdevelop PROPERTIES MACOSX_BUNDLE_BUNDLE_VERSION "${KDevelop_VERSION_MAJOR}.${KDevelop_VERSION_MINOR}")
0094     set_target_properties(kdevelop PROPERTIES MACOSX_BUNDLE_ICON_FILE "kdevelop_SRCS.icns")
0095     set_target_properties(kdevelop PROPERTIES MACOSX_BUNDLE_COPYRIGHT "KDevelop Team")
0096 endif (APPLE)
0097 
0098 
0099 ########### install files ###############
0100 
0101 install( PROGRAMS org.kde.kdevelop.desktop  DESTINATION  ${KDE_INSTALL_APPDIR} )
0102 install( PROGRAMS org.kde.kdevelop_ps.desktop  DESTINATION  ${KDE_INSTALL_APPDIR} )
0103 install( PROGRAMS org.kde.kdevelop_kdev4.desktop  DESTINATION  ${KDE_INSTALL_APPDIR} )
0104 install( FILES kdevelop.notifyrc DESTINATION ${KDE_INSTALL_KNOTIFY5RCDIR} )
0105 install( FILES kdevelop.xml DESTINATION ${KDE_INSTALL_MIMEDIR} )
0106 update_xdg_mimetypes( ${KDE_INSTALL_MIMEDIR} )