kdevelop/kdevelop-pg-qt/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 project(kdevelop-pg-qt VERSION 2.2.90)
0004
0005 find_package(ECM 5.91.0 REQUIRED NO_MODULE)
0006 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0007
0008 set(KDE_COMPILERSETTINGS_LEVEL 5.84)
0009
0010 include(KDEInstallDirs)
0011 include(KDECMakeSettings)
0012 include(KDECompilerSettings NO_POLICY_SCOPE)
0013
0014 include(ECMAddTests)
0015 include(ECMMarkNonGuiExecutable)
0016 include(ECMSetupVersion)
0017 include(ECMDeprecationSettings)
0018
0019 include(FeatureSummary)
0020 include(WriteBasicConfigVersionFile)
0021 include(CMakePackageConfigHelpers)
0022
0023 set(CMAKECONFIG_INSTALL_DIR ${KDE_INSTALL_CMAKEPACKAGEDIR}/KDevelop-PG-Qt)
0024 configure_package_config_file("${CMAKE_CURRENT_SOURCE_DIR}/KDevelop-PG-QtConfig.cmake.in"
0025                               "${CMAKE_CURRENT_BINARY_DIR}/KDevelop-PG-QtConfig.cmake"
0026                               INSTALL_DESTINATION ${CMAKECONFIG_INSTALL_DIR}
0027 )
0028 ecm_setup_version(${kdevelop-pg-qt_VERSION_MAJOR}.${kdevelop-pg-qt_VERSION_MINOR}.${kdevelop-pg-qt_VERSION_PATCH}
0029                   VARIABLE_PREFIX KDEVELOP_PG_QT
0030                   VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/kdevelop-pg-qt_version.h"
0031                   PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KDevelop-PG-QtConfigVersion.cmake"
0032                   SOVERSION ${KDEVELOP_PG_QT_LIB_SOVERSION}
0033 )
0034 install(FILES
0035         "${CMAKE_CURRENT_BINARY_DIR}/kdevelop-pg-qt_version.h"
0036         DESTINATION "${KDE_INSTALL_INCLUDEDIR}/kdevelop-pg-qt")
0037 install(FILES
0038         "${CMAKE_CURRENT_BINARY_DIR}/KDevelop-PG-QtConfig.cmake"
0039         "${CMAKE_CURRENT_BINARY_DIR}/KDevelop-PG-QtConfigVersion.cmake"
0040         DESTINATION "${CMAKECONFIG_INSTALL_DIR}" )
0041
0042 if(BUILD_TESTING)
0043   set(REQUIRED_QT_TESTCOMPONENTS Test)
0044 endif()
0045 set(REQUIRED_QT_VERSION 5.15.2)
0046 find_package(Qt${QT_MAJOR_VERSION} ${REQUIRED_QT_VERSION} CONFIG REQUIRED
0047   COMPONENTS
0048     Core
0049     ${REQUIRED_QT_TESTCOMPONENTS}
0050 )
0051
0052 include_directories(${CMAKE_CURRENT_SOURCE_DIR}/include)
0053
0054 find_program(FLEX_EXECUTABLE
0055   NAMES flex
0056   PATHS /usr/bin
0057   DOC "Flex executable")
0058
0059 find_program(BISON_EXECUTABLE
0060   NAMES bison
0061   PATHS /usr/bin
0062   DOC "bison executable")
0063
0064 ecm_set_disabled_deprecation_versions(
0065     QT 5.15.2
0066 )
0067
0068 add_definitions(
0069     -DQT_NO_SIGNALS_SLOTS_KEYWORDS
0070     -DQT_STRICT_ITERATORS
0071     -DQT_USE_QSTRINGBUILDER
0072     -DQT_NO_URL_CAST_FROM_STRING
0073     -DQT_NO_CAST_FROM_BYTEARRAY
0074     -DQT_NO_CAST_TO_ASCII
0075 )
0076
0077 # Silence a few warnings
0078 if (CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID MATCHES "Clang")
0079     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-missing-field-initializers -Wno-unused-local-typedefs")
0080 endif()
0081
0082 add_subdirectory(include)
0083 add_subdirectory(kdev-pg)
0084 add_subdirectory(examples EXCLUDE_FROM_ALL)
0085
0086 if(BUILD_TESTING)
0087   add_subdirectory(tests)
0088 endif()
0089
0090 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)