kdevelop/kdev-xdebug/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.0.0)
0002 project(xdebug)
0003
0004 find_package (ECM "5.14.0" REQUIRED NO_MODULE)
0005 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${ECM_MODULE_PATH})
0006
0007 include(KDECompilerSettings NO_POLICY_SCOPE)
0008 include(ECMAddTests)
0009 include(ECMQtDeclareLoggingCategory)
0010 include(KDEInstallDirs)
0011 include(KDECMakeSettings)
0012 include(FeatureSummary)
0013
0014 set(QT_MIN_VERSION "5.5.0")
0015 find_package(Qt5 ${QT_MIN_VERSION} CONFIG REQUIRED Core Widgets Test)
0016 set(KF5_DEP_VERSION "5.15.0")
0017 find_package(KF5 ${KF5_DEP_VERSION} REQUIRED COMPONENTS
0018     TextEditor
0019     I18n
0020     ItemModels # needed because missing in KDevPlatformConfig.cmake, remove once dep on kdevplatform >=5.2.2
0021 )
0022
0023 find_package(KDevPlatform 5.1 CONFIG)
0024 set_package_properties(KDevPlatform PROPERTIES
0025     TYPE REQUIRED
0026 )
0027
0028 # TODO: That plugin should install a CMake config file
0029 find_path(EXECUTEBROWSER_INCLUDE_DIR iexecutebrowserplugin.h PATH_SUFFIXES kdevexecutebrowser)
0030 include_directories(${EXECUTEBROWSER_INCLUDE_DIR})
0031
0032 add_definitions(-DTRANSLATION_DOMAIN=\"kdevxdebug\")
0033
0034 set(kdevxdebugcore_PART_SRCS
0035     connection.cpp
0036     debugsession.cpp
0037     debugjob.cpp
0038     framestackmodel.cpp
0039     breakpointcontroller.cpp
0040     variablecontroller.cpp
0041     variable.cpp
0042     stringhelpers.cpp
0043 )
0044
0045 set(kdevxdebug_PART_SRCS
0046     xdebugplugin.cpp
0047     launchconfig.cpp
0048     launchconfigurationpage.cpp
0049 )
0050
0051 ki18n_wrap_ui(kdevxdebug_PART_SRCS
0052     launchconfigurationpage.ui
0053 )
0054
0055 ecm_qt_declare_logging_category(kdevxdebugcore_PART_SRCS
0056     HEADER debuggerdebug.h
0057     IDENTIFIER KDEV_PHP_DEBUGGER
0058     CATEGORY_NAME "kdevelop.languages.php.debugger"
0059 )
0060
0061
0062 kdevplatform_add_plugin(kdevxdebug JSON kdevxdebug.json SOURCES ${kdevxdebug_PART_SRCS} ${kdevxdebugcore_PART_SRCS})
0063
0064 target_link_libraries(kdevxdebug
0065     KDev::Interfaces
0066     KDev::Debugger
0067     KDev::OutputView
0068     KDev::Shell
0069     KDev::Util
0070 )
0071
0072 if (BUILD_TESTING AND TARGET KDev::Tests)
0073 set(connectiontest_SRCS
0074     tests/connectiontest.cpp
0075 )
0076 ecm_add_test(${connectiontest_SRCS}
0077     ${kdevxdebugcore_PART_SRCS}
0078     TEST_NAME connectiontest
0079     LINK_LIBRARIES
0080         KDev::Interfaces
0081         KDev::Tests
0082         KDev::Debugger
0083         KDev::OutputView
0084         KDev::Shell
0085         KDev::Util
0086         Qt5::Test
0087 )
0088 endif()
0089
0090 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)