kdevelop/kdev-executebrowser/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.0)
0002
0003 project(executebrowser)
0004
0005 find_package(ECM "5.14.0" REQUIRED)
0006 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0007
0008 include(KDECompilerSettings NO_POLICY_SCOPE)
0009 include(KDEInstallDirs)
0010 include(KDECMakeSettings)
0011 include(ECMQtDeclareLoggingCategory)
0012 include(FeatureSummary)
0013
0014 set(KF5_DEP_VERSION "5.15.0")
0015 find_package(KF5 ${KF5_DEP_VERSION} REQUIRED COMPONENTS
0016     I18n
0017     ItemModels # needed because missing in KDevPlatformConfig.cmake, remove once dep on kdevplatform >=5.2.2
0018 )
0019
0020 set(KDEVPLATFORM_VERSION "5.1.0")
0021 find_package(KDevPlatform ${KDEVPLATFORM_VERSION} CONFIG)
0022 set_package_properties(KDevPlatform PROPERTIES
0023     TYPE REQUIRED
0024 )
0025
0026 if(CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID STREQUAL "Clang" OR CMAKE_CXX_COMPILER_ID STREQUAL "Intel")
0027     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11")
0028 endif()
0029
0030 add_definitions(-DTRANSLATION_DOMAIN=\"kdevexecutebrowser\")
0031
0032 set(kdevexecutebrowser_PART_UIS
0033     browserappconfig.ui
0034 )
0035
0036 set(kdevexecutebrowser_PART_SRCS
0037     executebrowserplugin.cpp
0038     browserappconfig.cpp
0039     browserappjob.cpp
0040 )
0041 ecm_qt_declare_logging_category(kdevexecutebrowser_PART_SRCS
0042     HEADER debug.h
0043     IDENTIFIER KDEV_EXECUTEBROWSER
0044     CATEGORY_NAME "kdevelop.plugins.executebrowser"
0045 )
0046
0047 ki18n_wrap_ui(kdevexecutebrowser_PART_SRCS ${kdevexecutebrowser_PART_UIS})
0048
0049 kdevplatform_add_plugin(kdevexecutebrowser JSON kdevexecutebrowser.json SOURCES ${kdevexecutebrowser_PART_SRCS})
0050 target_link_libraries(kdevexecutebrowser
0051     KDev::Interfaces
0052     KDev::Util
0053     KDev::Project
0054     KDev::OutputView
0055     KF5::I18n
0056 )
0057
0058 install(FILES iexecutebrowserplugin.h DESTINATION ${KDE_INSTALL_INCLUDEDIR}/kdevexecutebrowser COMPONENT Devel)
0059
0060 # kdebugsettings file
0061 install(FILES kdevexecutebrowser.categories DESTINATION ${KDE_INSTALL_CONFDIR})
0062
0063 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)