kdev-css/parser/CMakeLists.txt

0001 kdevpgqt_generate(_kdevpgList css NAMESPACE Css DEBUG_VISITOR TOKEN_TEXT
0002     "${css_SOURCE_DIR}/parser/css.g"
0003     "${css_SOURCE_DIR}/parser/tokenizer.h"
0004 )
0005 set( parser_SRCS
0006     ${_kdevpgList}
0007 )
0008
0009 # Copy tokenizer.ll to the builddir, so that flex doesn't write out
0010 # absolute paths in the generated file when we pass them as arguments.
0011 # In short, I don't want stuff like
0012 # '#line 2 "/home/kde/build/.../tokenizer.cpp" in SVN.
0013 add_custom_command(
0014     OUTPUT  "${CMAKE_CURRENT_BINARY_DIR}/tokenizer.flex"
0015     MAIN_DEPENDENCY "${CMAKE_CURRENT_SOURCE_DIR}/tokenizer.flex"
0016     COMMAND ${CMAKE_COMMAND}  ARGS -E copy_if_different
0017             "${CMAKE_CURRENT_SOURCE_DIR}/tokenizer.flex"
0018             "${CMAKE_CURRENT_BINARY_DIR}/tokenizer.flex"
0019 )
0020 set_source_files_properties(
0021     "${CMAKE_CURRENT_BINARY_DIR}/tokenizer.flex"
0022     GENERATED
0023 )
0024 # Add command to generate the lexer.
0025 add_custom_command(
0026     OUTPUT  "${CMAKE_CURRENT_BINARY_DIR}/tokenizer.cpp"
0027     MAIN_DEPENDENCY "${CMAKE_CURRENT_BINARY_DIR}/tokenizer.flex"
0028     COMMAND ${FLEX_EXECUTABLE}
0029     ARGS --nounistd -o"tokenizer.cpp" "tokenizer.flex"
0030     WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
0031 )
0032
0033 set(parser_STAT_SRCS
0034     ${kdevcss_LOG_SRCS}
0035     ${CMAKE_CURRENT_BINARY_DIR}/tokenizer.cpp
0036     parsesession.cpp
0037     editorintegrator.cpp
0038     htmlparser.cpp
0039 )
0040
0041 ### next target
0042 add_library(kdev4cssparser SHARED ${parser_SRCS} ${parser_STAT_SRCS} )
0043 generate_export_header(kdev4cssparser EXPORT_MACRO_NAME KDEVCSSPARSER_EXPORT
0044                                        EXPORT_FILE_NAME parserexport.h)
0045 target_link_libraries( kdev4cssparser LINK_PRIVATE
0046     KDev::Language
0047 )
0048 install(TARGETS kdev4cssparser DESTINATION ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0049
0050 if(BUILD_TESTING)
0051     ### next target
0052     if(WIN32)
0053         add_executable(css-parser main.cpp)
0054     else()
0055         add_executable(css-parser ${CMAKE_CURRENT_BINARY_DIR}/tokenizer.cpp main.cpp)
0056     endif()
0057     target_link_libraries(css-parser
0058         Qt5::Test
0059         KDev::Language
0060         KDev::Tests
0061         kdev4cssparser
0062     )
0063
0064     ### next target
0065     set(parsertest_SRCS test/parsertest.cpp
0066       # TODO: extra library!
0067         ${kdevcss_LOG_SRCS}
0068       ../duchain/tests/duchaintestbase.cpp
0069       ../duchain/builders/contextbuilder.cpp
0070       ../duchain/builders/declarationbuilder.cpp)
0071     ecm_add_test(${parsertest_SRCS}
0072         TEST_NAME parsertest
0073         LINK_LIBRARIES
0074             Qt5::Test
0075             kdev4cssparser
0076             KDev::Language
0077             KDev::Tests
0078     )
0079 endif()