kdevelop/kdev-css/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.0)
0002 project(css)
0003
0004 set(VERSION_MAJOR 4)
0005 set(VERSION_MINOR 90)
0006 set(VERSION_PATCH 90)
0007
0008 set(CMAKE_CXX_STANDARD 17)
0009 set(CMAKE_CXX_STANDARD_REQUIRED YES)
0010
0011 find_package (ECM "5.14.0" REQUIRED NO_MODULE)
0012 message(STATUS "${CMAKE_MODULE_PATH}")
0013 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${ECM_MODULE_PATH})
0014 message(STATUS "${CMAKE_MODULE_PATH}")
0015
0016 include(KDECompilerSettings NO_POLICY_SCOPE)
0017 include(ECMAddTests)
0018 include(ECMQtDeclareLoggingCategory)
0019 include(KDEInstallDirs)
0020 include(KDECMakeSettings)
0021 include(GenerateExportHeader)
0022 include(FeatureSummary)
0023
0024 set(QT_MIN_VERSION "5.5.0")
0025 find_package(Qt5 ${QT_MIN_VERSION} CONFIG REQUIRED Core Widgets Test)
0026 set(KF5_DEP_VERSION "5.15.0")
0027 find_package(KF5 ${KF5_DEP_VERSION} REQUIRED COMPONENTS
0028     I18n
0029     TextEditor
0030 )
0031 set(KDEVPLATFORM_DEP_VERSION "5.2.80")
0032 find_package(KDevPlatform ${KDEVPLATFORM_DEP_VERSION} CONFIG)
0033 set_package_properties(KDevPlatform PROPERTIES
0034     TYPE REQUIRED
0035 )
0036
0037 configure_file(
0038   "${CMAKE_CURRENT_SOURCE_DIR}/version.h.cmake"
0039   "${CMAKE_CURRENT_BINARY_DIR}/version.h"
0040   @ONLY
0041 )
0042
0043 find_package(KDevelop-PG-Qt CONFIG)
0044 set_package_properties(KDevelop-PG-Qt PROPERTIES
0045     TYPE REQUIRED
0046 )
0047
0048 find_package(FLEX)
0049 set_package_properties(FLEX PROPERTIES
0050     TYPE REQUIRED
0051 )
0052
0053 add_definitions(-DTRANSLATION_DOMAIN=\"kdevcss\")
0054
0055 include_directories(
0056     ${CMAKE_CURRENT_BINARY_DIR} # debug.h
0057     ${CMAKE_CURRENT_BINARY_DIR}/parser
0058     ${FLEX_INCLUDE_DIRS}
0059     ${KDEVPGQT_INCLUDE_DIR}
0060 )
0061
0062 ecm_qt_declare_logging_category(kdevcss_LOG_SRCS
0063     HEADER debug.h
0064     IDENTIFIER KDEV_CSS
0065     CATEGORY_NAME "kdevelop.languages.css"
0066 )
0067
0068 add_subdirectory(parser)
0069
0070 set(kdevcss_PART_SRCS
0071     csslanguagesupport.cpp
0072     completion/model.cpp
0073     completion/contentassistdata.cpp
0074     parsejob.cpp
0075     duchain/builders/contextbuilder.cpp
0076     duchain/builders/declarationbuilder.cpp
0077     navigation/fieldnavigationcontext.cpp
0078     navigation/navigationwidget.cpp
0079     navigation/valuenavigationcontext.cpp
0080     navigation/colornavigationcontext.cpp
0081     ${kdevcss_LOG_SRCS}
0082 )
0083
0084 qt5_add_resources(kdevcss_PART_SRCS kdevcssresources.qrc)
0085
0086 kdevplatform_add_plugin(kdevcsssupport JSON kdevcsssupport.json
0087     SOURCES ${kdevcss_PART_SRCS})
0088 target_link_libraries(kdevcsssupport
0089     kdev4cssparser
0090
0091     KDev::Interfaces
0092     KDev::Language
0093
0094     KF5::I18n
0095     KF5::TextEditor
0096 )
0097
0098 # kdebugsettings file
0099 install(FILES kdevcsssupport.categories DESTINATION ${KDE_INSTALL_CONFDIR})
0100
0101 if(BUILD_TESTING)
0102     ### next target
0103     set(completionmodeltest_SRCS
0104         completion/test/modeltest.cpp
0105         completion/model.cpp
0106         completion/contentassistdata.cpp
0107         ##TODO: put this into a shared lib
0108         duchain/tests/duchaintestbase.cpp
0109         duchain/builders/contextbuilder.cpp
0110         duchain/builders/declarationbuilder.cpp
0111         ${kdevcss_LOG_SRCS}
0112     )
0113
0114     qt5_add_resources(completionmodeltest_SRCS kdevcssresources.qrc)
0115
0116     ecm_add_test(${completionmodeltest_SRCS}
0117         TEST_NAME completionmodeltest
0118         LINK_LIBRARIES
0119             Qt5::Test
0120             kdev4cssparser
0121             KDev::Interfaces KDev::Language KDev::Tests
0122             KF5::I18n KF5::TextEditor
0123     )
0124
0125     ### next target
0126     set(duchaintest_SRCS
0127         duchain/tests/duchain.cpp
0128         duchain/tests/duchaintestbase.cpp
0129         duchain/builders/contextbuilder.cpp
0130         duchain/builders/declarationbuilder.cpp
0131         ${kdevcss_LOG_SRCS}
0132     )
0133     ecm_add_test(${duchaintest_SRCS}
0134         TEST_NAME duchaintest
0135         LINK_LIBRARIES
0136             kdev4cssparser
0137             Qt5::Test
0138             KDev::Interfaces KDev::Language KDev::Tests
0139             KF5::I18n KF5::TextEditor
0140     )
0141
0142     ### next target
0143     set(parsejobtest_SRCS
0144         duchain/tests/parsejobtest.cpp
0145     )
0146     ecm_add_test(${parsejobtest_SRCS}
0147         TEST_NAME parsejobtest
0148         LINK_LIBRARIES
0149             Qt5::Test
0150             KDev::Interfaces KDev::Language KDev::Tests
0151             KF5::I18n KF5::TextEditor
0152     )
0153 endif()
0154
0155 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)