graphics/symboleditor/CMakeLists.txt

0001 cmake_minimum_required (VERSION 3.16)
0002
0003 set(CMAKE_EXPORT_COMPILE_COMMANDS ON)
0004
0005 project (SymbolEditor)
0006
0007 find_package (ECM REQUIRED NO_MODULE)
0008 set (CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0009
0010 include (KDEInstallDirs)
0011 include (KDECMakeSettings)
0012 include (KDECompilerSettings)
0013 include (ECMInstallIcons)
0014 include (FeatureSummary)
0015
0016 kde_enable_exceptions ()
0017
0018 find_package (Qt5 CONFIG REQUIRED
0019     Core
0020     Widgets
0021 )
0022
0023 find_package (KF5DocTools)
0024
0025 find_package (KF5 REQUIRED COMPONENTS
0026     Config
0027     I18n
0028     KIO
0029     WidgetsAddons
0030     XmlGui
0031 )
0032
0033 find_package (Doxygen)
0034 find_package (SharedMimeInfo)
0035
0036 if (DOXYGEN_FOUND)
0037     configure_file (${CMAKE_CURRENT_SOURCE_DIR}/Doxyfile.in ${CMAKE_CURRENT_BINARY_DIR}/Doxyfile @ONLY)
0038     add_custom_target (doc ${DOXYGEN_EXECUTABLE} ${CMAKE_CURRENT_BINARY_DIR}/Doxyfile
0039                        WORKING_DIRECTORY ${CMAKE_CURENT_BINARY_DIR}
0040                        COMMENT "Generating API documentation with Doxygen" VERBATIM)
0041 endif (DOXYGEN_FOUND)
0042
0043 include_directories (BEFORE ${CMAKE_CURENT_BINARY_DIR})
0044
0045 set (SymbolEditor_SRCS
0046     src/Commands.cpp
0047     src/ConfigurationDialogs.cpp
0048     src/Editor.cpp
0049     src/Exceptions.cpp
0050     src/Main.cpp
0051     src/MainWindow.cpp
0052     src/Symbol.cpp
0053     src/SymbolLibrary.cpp
0054     src/SymbolListWidget.cpp
0055
0056     SymbolEditor.qrc
0057 )
0058
0059 file (GLOB SymbolEditor_UI ${CMAKE_CURRENT_SOURCE_DIR}/ui/*.ui)
0060 ki18n_wrap_ui (SymbolEditor_SRCS ${SymbolEditor_UI})
0061
0062 add_subdirectory (icons)
0063
0064 ki18n_install(po)
0065
0066 if (KF5DocTools_FOUND)
0067     add_subdirectory (doc)
0068     kdoctools_install(po)
0069 endif (KF5DocTools_FOUND)
0070
0071 kconfig_add_kcfg_files (SymbolEditor_SRCS SymbolEditor.kcfgc)
0072
0073 ecm_install_icons (ICONS sc-apps-symboleditor.svgz DESTINATION ${KDE_INSTALL_ICONDIR})
0074
0075 add_executable (SymbolEditor ${SymbolEditor_SRCS})
0076
0077 target_link_libraries (SymbolEditor
0078     Qt5::Core
0079     Qt5::Widgets
0080     KF5::ConfigGui
0081     KF5::I18n
0082     KF5::KIOFileWidgets
0083     KF5::WidgetsAddons
0084     KF5::XmlGui
0085 )
0086
0087 add_definitions (
0088     -DQT_NO_CAST_FROM_ASCII
0089     -DQT_NO_CAST_TO_ASCII
0090 )
0091
0092 if (SILENCE_DEPRECATED)
0093     add_definitions( -Wno-deprecated-declarations )
0094 endif (SILENCE_DEPRECATED)
0095
0096 install (TARGETS SymbolEditor DESTINATION ${KDE_INSTALL_BINDIR})
0097 install (FILES SymbolEditor.kcfg DESTINATION ${KDE_INSTALL_KCFGDIR})
0098 install (FILES org.kde.SymbolEditor.desktop DESTINATION ${KDE_INSTALL_APPDIR})
0099 install (FILES org.kde.SymbolEditor.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR})
0100
0101 IF (SHARED_MIME_INFO_FOUND AND IS_DIRECTORY ${KDE_INSTALL_MIMEDIR})
0102     install (FILES SymbolEditor.xml DESTINATION ${KDE_INSTALL_MIMEDIR})
0103     update_xdg_mimetypes (${KDE_INSTALL_MIMEDIR})
0104 ENDIF (SHARED_MIME_INFO_FOUND AND IS_DIRECTORY ${KDE_INSTALL_MIMEDIR})
0105
0106 feature_summary (WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)