libksane/src/CMakeLists.txt

0001 add_library(KSaneWidgets)
0002
0003 set_target_properties(KSaneWidgets PROPERTIES
0004     VERSION     ${KSANE_VERSION}
0005     SOVERSION   ${KSANE_SOVERSION}
0006     EXPORT_NAME ${TARGET_EXPORT_NAME}
0007     OUTPUT_NAME ${LIBRARYFILE_NAME}
0008 )
0009
0010 target_compile_definitions(KSaneWidgets PRIVATE -DTRANSLATION_DOMAIN=\"libksane\")
0011
0012 if (KF5Wallet_FOUND)
0013     target_compile_definitions(KSaneWidgets PRIVATE -DHAVE_KF5WALLET)
0014     target_link_libraries(KSaneWidgets PRIVATE KF${KF_MAJOR_VERSION}::Wallet)
0015 endif()
0016
0017 target_sources(KSaneWidgets PRIVATE
0018     widgets/gammadisp.cpp
0019     widgets/labeledgamma.cpp
0020     widgets/labeledcheckbox.cpp
0021     widgets/labeledentry.cpp
0022     widgets/labeledcombo.cpp
0023     widgets/labeledfslider.cpp
0024     widgets/labeledslider.cpp
0025     widgets/ksanebutton.cpp
0026     widgets/ksaneoptionwidget.cpp
0027     ksaneviewer.cpp
0028     selectionitem.cpp
0029     hiderectitem.cpp
0030     ksanedevicedialog.cpp
0031     ksanewidget.cpp
0032     ksanewidget_p.cpp
0033     splittercollapser.cpp
0034 )
0035
0036 ecm_qt_declare_logging_category(KSaneWidgets
0037   HEADER ksane_debug.h
0038   IDENTIFIER KSANE_LOG
0039   CATEGORY_NAME org.kde.ksane
0040 )
0041
0042 if (QT_MAJOR_VERSION STREQUAL "5")
0043     set(_generate_export_header_version_args)
0044 else()
0045     # For Qt6/KF6 world transitively include the version header
0046     if(ECM_VERSION VERSION_LESS "5.106")
0047         set(include_version_header_code "#include <ksane_version.h>\n")
0048         set(_generate_export_header_version_args CUSTOM_CONTENT_FROM_VARIABLE include_version_header_code)
0049     else()
0050         set(_generate_export_header_version_args USE_VERSION_HEADER)
0051     endif()
0052 endif()
0053
0054 ecm_generate_export_header(KSaneWidgets
0055     BASE_NAME KSane
0056     VERSION ${KSANE_VERSION}
0057     DEPRECATED_BASE_VERSION 0
0058     ${_generate_export_header_version_args}
0059 )
0060
0061 target_include_directories(KSaneWidgets
0062     INTERFACE
0063         "$<INSTALL_INTERFACE:${KSANEWIDGETS_INSTALL_INCLUDEDIR}>"
0064     PRIVATE
0065         ${CMAKE_CURRENT_SOURCE_DIR}/widgets
0066 )
0067
0068 target_link_libraries(KSaneWidgets
0069     PUBLIC
0070         Qt${QT_MAJOR_VERSION}::Core
0071         Qt${QT_MAJOR_VERSION}::Gui
0072         Qt${QT_MAJOR_VERSION}::Widgets
0073     PRIVATE
0074         KF${KF_MAJOR_VERSION}::I18n
0075         KF${KF_MAJOR_VERSION}::WidgetsAddons
0076         KF${KF_MAJOR_VERSION}::TextWidgets
0077         ${KSANECORE_TARGET}
0078 )
0079
0080 ecm_generate_headers(KSane_HEADERS
0081     HEADER_NAMES
0082         KSaneWidget
0083     REQUIRED_HEADERS KSane_HEADERS
0084     RELATIVE "../src/"
0085 )
0086
0087 # Install files
0088
0089 ecm_install_icons(ICONS
0090   16-actions-black-white.png
0091   16-actions-color.png
0092   16-actions-gray-scale.png
0093   DESTINATION ${KDE_INSTALL_ICONDIR})
0094
0095 install(TARGETS KSaneWidgets
0096   EXPORT KSaneWidgetsTargets
0097   ${KDE_INSTALL_TARGETS_DEFAULT_ARGS}
0098 )
0099
0100 install(FILES
0101   ${CMAKE_CURRENT_BINARY_DIR}/ksane_export.h
0102   ${KSane_HEADERS}
0103   DESTINATION ${KSANEWIDGETS_INSTALL_INCLUDEDIR}
0104   COMPONENT Devel
0105 )