libkipi/src/CMakeLists.txt

0001 # SPDX-FileCopyrightText: 2010-2018 Gilles Caulier <caulier dot gilles at gmail dot com>
0002 #
0003 # SPDX-License-Identifier: BSD-3-Clause
0004
0005 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/libkipi_config.h.in ${CMAKE_CURRENT_BINARY_DIR}/libkipi_config.h)
0006
0007 include_directories(${CMAKE_CURRENT_BINARY_DIR})
0008 include_directories(${CMAKE_CURRENT_BINARY_DIR}/..)
0009
0010 set(KIPI_INSTALL_INCLUDEDIR ${KDE_INSTALL_INCLUDEDIR_KF}/KIPI)
0011
0012 add_library(KF5Kipi)
0013 add_library(KF5::Kipi ALIAS KF5Kipi)
0014 set_target_properties(KF5Kipi PROPERTIES
0015     VERSION     ${KIPI_VERSION}
0016     SOVERSION   ${KIPI_SOVERSION}
0017     EXPORT_NAME Kipi
0018 )
0019
0020 target_sources(KF5Kipi PRIVATE
0021     interface.cpp
0022     imagecollection.cpp
0023     imagecollectionshared.cpp
0024     imageinfoshared.cpp
0025     plugin.cpp
0026     imageinfo.cpp
0027     uploadwidget.cpp
0028     imagecollectionselector.cpp
0029     configwidget.cpp
0030     pluginloader.cpp
0031
0032     ${CMAKE_CURRENT_SOURCE_DIR}/../pics/libkipi.qrc
0033 )
0034
0035 ecm_generate_headers(kipi_CamelCase_HEADERS
0036
0037                      HEADER_NAMES
0038                      Plugin
0039                      PluginLoader
0040                      Interface
0041                      ImageInfo
0042                      ImageCollection
0043                      ImageInfoShared
0044                      ImageCollectionShared
0045                      ImageCollectionSelector
0046                      UploadWidget
0047                      ConfigWidget
0048
0049                      PREFIX           KIPI
0050                      REQUIRED_HEADERS kipi_HEADERS
0051 )
0052
0053 generate_export_header(KF5Kipi BASE_NAME libkipi EXPORT_MACRO_NAME LIBKIPI_EXPORT)
0054
0055 ecm_qt_declare_logging_category(KF5Kipi
0056     HEADER libkipi_debug.h
0057     IDENTIFIER LIBKIPI_LOG
0058     CATEGORY_NAME kipi.library
0059     DESCRIPTION "KIPI Library"
0060     EXPORT KIPI
0061 )
0062
0063 # disable adding of current source directory to interface, as it causes naming clashes
0064 set(CMAKE_INCLUDE_CURRENT_DIR_IN_INTERFACE OFF)
0065
0066 target_include_directories(KF5Kipi INTERFACE
0067                            "$<INSTALL_INTERFACE:${KIPI_INSTALL_INCLUDEDIR};${KIPI_INSTALL_INCLUDEDIR}/kipi>"
0068                            "$<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>"
0069 )
0070
0071 target_link_libraries(KF5Kipi
0072                       PUBLIC
0073                       Qt5::Gui
0074                       Qt5::Widgets
0075
0076                       KF5::XmlGui
0077                       KF5::Service
0078                       KF5::ConfigCore
0079 )
0080
0081 install(TARGETS KF5Kipi
0082         EXPORT  KF5KipiTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS}
0083 )
0084
0085
0086 # desktop file which define plugin service model, used by tools from kipi-plugins.
0087 install(FILES kipiplugin.desktop DESTINATION ${KDE_INSTALL_KSERVICETYPESDIR})
0088
0089 install(FILES   ${kipi_CamelCase_HEADERS}
0090     DESTINATION ${KIPI_INSTALL_INCLUDEDIR}/KIPI # C++ namespace
0091     COMPONENT   Devel
0092 )
0093
0094 install(FILES
0095         ${kipi_HEADERS}
0096         ${CMAKE_CURRENT_BINARY_DIR}/libkipi_export.h
0097         ${CMAKE_CURRENT_BINARY_DIR}/libkipi_config.h
0098     DESTINATION ${KIPI_INSTALL_INCLUDEDIR}/kipi # C++ namespace
0099     COMPONENT   Devel
0100 )
0101
0102 install(FILES       "${CMAKE_CURRENT_BINARY_DIR}/libkipi_version.h"
0103         DESTINATION "${KIPI_INSTALL_INCLUDEDIR}"
0104         COMPONENT   Devel
0105 )
0106
0107
0108 ecm_qt_install_logging_categories(
0109     EXPORT KIPI
0110     FILE kipi.categories
0111     DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0112 )