impex/xcf/CMakeLists.txt

0001 add_subdirectory(tests)
0002
0003 set(XCFTOOLS_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/3rdparty/xcftools")
0004
0005 include(CheckCSourceCompiles)
0006 include(CheckIncludeFile)
0007 include(CheckSymbolExists)
0008
0009 # Tests for configure.h
0010 if(CMAKE_SYSTEM_PROCESSOR MATCHES "^(i?86.*|x86.*|x86_64.*|amd64.*|AMD64.*)")
0011 set(CAN_DO_UNALIGNED_WORDS 1)
0012 else()
0013 set(CAN_DO_UNALIGNED_WORDS 0)
0014 endif()
0015 set(ENABLE_NLS 1)
0016 CHECK_INCLUDE_FILE("arpa/inet.h" HAVE_ARPA_INET_H)
0017 check_symbol_exists(gettext "libintl.h" HAVE_GETTEXT)
0018 check_symbol_exists(iconv "iconv.h" HAVE_ICONV)
0019 CHECK_INCLUDE_FILE("inttypes.h" HAVE_INTTYPES_H)
0020 CHECK_INCLUDE_FILE("netinet/in.h" HAVE_NETINET_IN_H)
0021 check_symbol_exists(strcasecmp "strings.h" HAVE_STRCASECMP)
0022 if (NOT WIN32 AND NOT APPLE)
0023     set(ICONV_CONST const)
0024 else()
0025     set(ICONV_CONST "")
0026 endif()
0027 set(PACKAGE_STRING "${CMAKE_PROJECT_NAME}")
0028 set(PACKAGE_VERSION "${KRITA_VERSION_STRING}")
0029 set(PRECOMPUTED_SCALETABLE 1)
0030 check_c_source_compiles("#include <stdlib.h>
0031 #include <stdarg.h>
0032 #include <string.h>
0033 #include <float.h>
0034
0035 int
0036 main ()
0037 {
0038
0039   ;
0040   return 0;
0041 }" STDC_HEADERS)
0042 set(WORDS_BIGENDIAN ${CMAKE_WORDS_BIGENDIAN})
0043 # skip inline check for sanity
0044
0045 configure_file(${XCFTOOLS_SOURCE_DIR}/config.h.in config.h)
0046
0047 set(xcftools_SOURCES
0048     ${XCFTOOLS_SOURCE_DIR}/xcf-general.c
0049     ${XCFTOOLS_SOURCE_DIR}/utils.c
0050     ${XCFTOOLS_SOURCE_DIR}/enums.c
0051     ${XCFTOOLS_SOURCE_DIR}/pixels.c
0052     ${XCFTOOLS_SOURCE_DIR}/scaletab.c
0053     ${XCFTOOLS_SOURCE_DIR}/table.c
0054     ${XCFTOOLS_SOURCE_DIR}/enums.c
0055     ${XCFTOOLS_SOURCE_DIR}/flatspec.c
0056     ${XCFTOOLS_SOURCE_DIR}/flatten.c
0057 )
0058
0059 add_library(xcftools STATIC ${xcftools_SOURCES})
0060 set_property(TARGET xcftools PROPERTY C_STANDARD 11)
0061 set_property(TARGET xcftools PROPERTY POSITION_INDEPENDENT_CODE ON)
0062 target_include_directories(xcftools INTERFACE ${XCFTOOLS_SOURCE_DIR})
0063
0064 if (WIN32)
0065     target_link_libraries(xcftools PUBLIC ws2_32)
0066 endif()
0067
0068 if (CMAKE_C_COMPILER_ID MATCHES "GNU")
0069     target_compile_options(xcftools PRIVATE -Wno-undef -Wno-missing-format-attribute -Wno-sign-compare -Wno-format -Wno-suggest-attribute=format -Wno-format-security)
0070 elseif (CMAKE_C_COMPILER_ID MATCHES "Clang")
0071     target_compile_options(xcftools PRIVATE -Wno-undef -Wno-cast-align -Wno-sign-compare -Wno-format)
0072 endif ()
0073
0074 set(kritaxcfimport_SOURCES
0075     kis_xcf_import.cpp
0076 )
0077
0078 kis_add_library(kritaxcfimport MODULE ${kritaxcfimport_SOURCES})
0079
0080 target_link_libraries(kritaxcfimport kritaui xcftools)
0081
0082 install(TARGETS kritaxcfimport  DESTINATION ${KRITA_PLUGIN_INSTALL_DIR})
0083 install( PROGRAMS  krita_xcf.desktop  DESTINATION ${XDG_APPS_INSTALL_DIR})