cmake/modules/FindLibRaw.cmake

0001 # - Find LibRaw
0002 # Find the LibRaw library <http://www.libraw.org>
0003 # This module defines
0004 #  LibRaw_VERSION_STRING, the version string of LibRaw
0005 #  LibRaw_INCLUDE_DIR, where to find libraw.h
0006 #  LibRaw_LIBRARIES, the libraries needed to use LibRaw (non-thread-safe)
0007 #  LibRaw_r_LIBRARIES, the libraries needed to use LibRaw (thread-safe)
0008 #  LibRaw_DEFINITIONS, the definitions needed to use LibRaw (non-thread-safe)
0009 #  LibRaw_r_DEFINITIONS, the definitions needed to use LibRaw (thread-safe)
0010 #
0011 # SPDX-FileCopyrightText: 2013 Pino Toscano <pino at kde dot org>
0012 # SPDX-FileCopyrightText: 2013 Gilles Caulier <caulier dot gilles at gmail dot com>
0013 #
0014 # SPDX-License-Identifier: BSD-3-Clause
0015 #
0016
0017 FIND_PACKAGE(PkgConfig)
0018
0019 IF(PKG_CONFIG_FOUND)
0020    PKG_CHECK_MODULES(PC_LIBRAW libraw)
0021    SET(LibRaw_DEFINITIONS ${PC_LIBRAW_CFLAGS_OTHER})
0022
0023    PKG_CHECK_MODULES(PC_LIBRAW_R libraw_r)
0024    SET(LibRaw_r_DEFINITIONS ${PC_LIBRAW_R_CFLAGS_OTHER})
0025 ENDIF()
0026
0027 FIND_PATH(LibRaw_INCLUDE_DIR libraw.h
0028           HINTS
0029           ${PC_LIBRAW_INCLUDEDIR}
0030           ${PC_LibRaw_INCLUDE_DIRS}
0031           PATH_SUFFIXES libraw
0032          )
0033
0034 FIND_LIBRARY(LibRaw_LIBRARIES NAMES raw
0035              HINTS
0036              ${PC_LIBRAW_LIBDIR}
0037              ${PC_LIBRAW_LIBRARY_DIRS}
0038             )
0039
0040 FIND_LIBRARY(LibRaw_r_LIBRARIES NAMES raw_r
0041              HINTS
0042              ${PC_LIBRAW_R_LIBDIR}
0043              ${PC_LIBRAW_R_LIBRARY_DIRS}
0044             )
0045
0046 IF(LibRaw_INCLUDE_DIR)
0047    FILE(READ ${LibRaw_INCLUDE_DIR}/libraw_version.h _libraw_version_content)
0048
0049    STRING(REGEX MATCH "#define LIBRAW_MAJOR_VERSION[ \t]*([0-9]*)\n" _version_major_match ${_libraw_version_content})
0050    SET(_libraw_version_major "${CMAKE_MATCH_1}")
0051
0052    STRING(REGEX MATCH "#define LIBRAW_MINOR_VERSION[ \t]*([0-9]*)\n" _version_minor_match ${_libraw_version_content})
0053    SET(_libraw_version_minor "${CMAKE_MATCH_1}")
0054
0055    STRING(REGEX MATCH "#define LIBRAW_PATCH_VERSION[ \t]*([0-9]*)\n" _version_patch_match ${_libraw_version_content})
0056    SET(_libraw_version_patch "${CMAKE_MATCH_1}")
0057
0058    IF(_version_major_match AND _version_minor_match AND _version_patch_match)
0059       SET(LibRaw_VERSION_STRING "${_libraw_version_major}.${_libraw_version_minor}.${_libraw_version_patch}")
0060    ELSE()
0061       IF(NOT LibRaw_FIND_QUIETLY)
0062          MESSAGE(STATUS "Failed to get version information from ${LibRaw_INCLUDE_DIR}/libraw_version.h")
0063       ENDIF()
0064    ENDIF()
0065 ENDIF()
0066
0067 INCLUDE(FindPackageHandleStandardArgs)
0068 FIND_PACKAGE_HANDLE_STANDARD_ARGS(LibRaw
0069                                   REQUIRED_VARS LibRaw_LIBRARIES LibRaw_INCLUDE_DIR
0070                                   VERSION_VAR LibRaw_VERSION_STRING
0071                                  )
0072
0073 MARK_AS_ADVANCED(LibRaw_VERSION_STRING
0074                  LibRaw_INCLUDE_DIR
0075                  LibRaw_LIBRARIES
0076                  LibRaw_r_LIBRARIES
0077                  LibRaw_DEFINITIONS
0078                  LibRaw_r_DEFINITIONS
0079                  )