src/part/CMakeLists.txt

0001 add_definitions(-DTRANSLATION_DOMAIN=\"kgraphviewer\")
0002
0003 ecm_qt_declare_logging_category(kgraphviewerlib_LIB_DEBUG_SRCS
0004     HEADER kgraphviewerlib_debug.h
0005     IDENTIFIER KGRAPHVIEWERLIB_LOG
0006     CATEGORY_NAME org.kde.kgraphviewer.lib
0007     DEFAULT_SEVERITY Warning
0008     DESCRIPTION "KGraphViewer (Library and KPart)"
0009     EXPORT KGRAPHVIEWER
0010 )
0011
0012 ########### next target ###############
0013
0014 add_library(kgraphviewerlib SHARED)
0015
0016 target_sources(kgraphviewerlib PRIVATE
0017     loadagraphthread.cpp
0018     layoutagraphthread.cpp
0019     graphelement.cpp
0020     graphsubgraph.cpp
0021     graphnode.cpp
0022     graphedge.cpp
0023     graphexporter.cpp
0024     pannerview.cpp
0025     canvassubgraph.cpp
0026     canvasnode.cpp
0027     canvasedge.cpp
0028     canvaselement.cpp
0029     dotgraph.cpp
0030     dotgraphview.cpp
0031     dot2qtconsts.cpp
0032     dotgrammar.cpp
0033     DotGraphParsingHelper.cpp
0034     FontsCache.cpp
0035     simpleprintingsettings.cpp
0036     simpleprintingengine.cpp
0037     simpleprintingcommand.cpp
0038     simpleprintingpagesetup.cpp
0039     simpleprintpreviewwindow_p.cpp
0040     simpleprintpreviewwindow.cpp
0041     KgvGlobal.cpp
0042     KgvUnit.cpp
0043     KgvUnitWidgets.cpp
0044     KgvPageLayoutColumns.cpp
0045     KgvPageLayoutDia.cpp
0046     KgvPageLayout.cpp
0047     KgvPageLayoutHeader.cpp
0048     KgvPageLayoutSize.cpp
0049     ${kgraphviewerlib_LIB_DEBUG_SRCS}
0050 )
0051
0052 kconfig_add_kcfg_files(kgraphviewerlib kgraphviewer_partsettings.kcfgc)
0053
0054 ki18n_wrap_ui(kgraphviewerlib
0055     simpleprintingpagesetupbase.ui
0056     KgvPageLayoutColumnsBase.ui
0057     KgvPageLayoutHeaderBase.ui
0058 )
0059
0060 target_include_directories(kgraphviewerlib PRIVATE
0061     ${CMAKE_CURRENT_SOURCE_DIR}/..
0062     ${Boost_INCLUDE_DIRS}
0063 )
0064
0065 target_link_libraries(kgraphviewerlib
0066     PUBLIC
0067         KF5::Parts
0068         Graphviz::Graphviz
0069     PRIVATE
0070         Qt${QT_MAJOR_VERSION}::Svg
0071         Qt${QT_MAJOR_VERSION}::PrintSupport
0072         KF5::WidgetsAddons
0073         KF5::XmlGui
0074         KF5::I18n
0075 )
0076
0077 set_target_properties(kgraphviewerlib PROPERTIES
0078     VERSION ${PROJECT_VERSION}
0079     SOVERSION ${KGRAPHVIEWER_SOVERSION}
0080     OUTPUT_NAME kgraphviewer
0081 )
0082
0083 install( TARGETS kgraphviewerlib ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0084
0085
0086 ########### next target ###############
0087
0088 configure_file(kgraphviewer_part.desktop.in ${CMAKE_CURRENT_BINARY_DIR}/kgraphviewer_part.desktop @ONLY)
0089
0090 ecm_setup_version(${PROJECT_VERSION}
0091     VARIABLE_PREFIX KGRAPHVIEWERPART
0092     PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KGraphViewerPartConfigVersion.cmake"
0093 )
0094
0095 add_library(kgraphviewerpart MODULE)
0096
0097 target_sources(kgraphviewerpart PRIVATE
0098     kgraphviewer_part.cpp
0099     ${kgraphviewerlib_LIB_DEBUG_SRCS}
0100
0101     kgraphviewer_part.qrc
0102 )
0103
0104 kcoreaddons_desktop_to_json(kgraphviewerpart ${CMAKE_CURRENT_BINARY_DIR}/kgraphviewer_part.desktop)
0105
0106 generate_export_header(kgraphviewerpart BASE_NAME kgraphviewer)
0107
0108 target_include_directories(kgraphviewerpart PRIVATE
0109     ${CMAKE_CURRENT_BINARY_DIR}/..
0110 )
0111
0112 target_link_libraries(kgraphviewerpart
0113     kgraphviewerlib
0114     KF5::Parts
0115 )
0116
0117 add_library(KGraphViewerPart INTERFACE)
0118
0119 target_include_directories(KGraphViewerPart INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}/kgraphviewer>")
0120
0121 install(TARGETS KGraphViewerPart EXPORT KGraphViewerPartTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0122
0123 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KGraphViewerPart")
0124 install(EXPORT KGraphViewerPartTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KGraphViewerPartTargets.cmake)
0125
0126 install(TARGETS kgraphviewerpart DESTINATION ${KDE_INSTALL_PLUGINDIR})
0127
0128 configure_package_config_file(
0129     "${CMAKE_CURRENT_SOURCE_DIR}/KGraphViewerPartConfig.cmake.in"
0130     "${CMAKE_CURRENT_BINARY_DIR}/KGraphViewerPartConfig.cmake"
0131     INSTALL_DESTINATION ${CMAKECONFIG_INSTALL_DIR}
0132 )
0133
0134 ########### configure AppStream metadata ###############
0135 configure_file(org.kde.libkgraphviewer.metainfo.xml.in "${CMAKE_CURRENT_BINARY_DIR}/org.kde.libkgraphviewer.metainfo.xml" IMMEDIATE @ONLY)
0136
0137 ########### install files ###############
0138
0139 install( FILES kgraphviewer_partsettings.kcfg DESTINATION ${KDE_INSTALL_KCFGDIR} )
0140
0141 install( FILES ${CMAKE_CURRENT_BINARY_DIR}/kgraphviewer_part.desktop DESTINATION ${KDE_INSTALL_KSERVICESDIR} )
0142 install( FILES chain.png DESTINATION ${KDE_INSTALL_DATADIR}/kgraphviewerpart/pics )
0143 install( FILES chain-broken.png DESTINATION ${KDE_INSTALL_DATADIR}/kgraphviewerpart/pics )
0144 install( FILES kgraphviewer-bev.png DESTINATION ${KDE_INSTALL_DATADIR}/kgraphviewerpart/pics )
0145 install( FILES kgraphviewer-newnode.png DESTINATION ${KDE_INSTALL_DATADIR}/kgraphviewerpart/pics )
0146 install( FILES kgraphviewer-newedge.png DESTINATION ${KDE_INSTALL_DATADIR}/kgraphviewerpart/pics )
0147 install( FILES "${CMAKE_CURRENT_BINARY_DIR}/org.kde.libkgraphviewer.metainfo.xml" DESTINATION ${KDE_INSTALL_METAINFODIR} )
0148
0149 install(FILES kgraphviewer_interface.h DESTINATION ${KDE_INSTALL_INCLUDEDIR}/kgraphviewer/ COMPONENT Devel)
0150
0151 install( FILES
0152     "${CMAKE_CURRENT_BINARY_DIR}/KGraphViewerPartConfig.cmake"
0153     "${CMAKE_CURRENT_BINARY_DIR}/KGraphViewerPartConfigVersion.cmake"
0154   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0155   COMPONENT Devel
0156 )