kgraphviewer/src/CMakeLists.txt

0001 ecm_setup_version(${PROJECT_VERSION}
0002     VARIABLE_PREFIX KGRAPHVIEWER
0003     SOVERSION ${KGRAPHVIEWERLIB_SOVERION}
0004     VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/config-kgraphviewer.h"
0005 )
0006
0007 add_subdirectory( part )
0008
0009 ########### kgraphviewer target ###############
0010
0011 add_executable(kgraphviewer)
0012
0013 target_sources(kgraphviewer PRIVATE
0014     main.cpp
0015     kgraphviewer.cpp
0016     kgraphviewerConfigDialog.cpp
0017
0018     kgraphviewer.qrc
0019 )
0020
0021 set(kgraphviewer_dbus_SRCS)
0022 qt_add_dbus_adaptor(kgraphviewer_dbus_SRCS org.kde.kgraphviewer.xml kgraphviewer.h KGraphViewerWindow)
0023 target_sources(kgraphviewer PRIVATE ${kgraphviewer_dbus_SRCS})
0024
0025 kconfig_add_kcfg_files(kgraphviewer kgraphviewersettings.kcfgc)
0026
0027 ki18n_wrap_ui(kgraphviewer
0028     preferencesReload.ui
0029     preferencesParsing.ui
0030     preferencesOpenInExistingWindow.ui
0031     preferencesReopenPreviouslyOpenedFiles.ui
0032     preferencesAppearance.ui
0033 )
0034
0035 ecm_qt_declare_logging_category(kgraphviewer
0036     HEADER kgraphviewer_debug.h
0037     IDENTIFIER KGRAPHVIEWER_LOG
0038     CATEGORY_NAME org.kde.kgraphviewer
0039     DEFAULT_SEVERITY Warning
0040     DESCRIPTION "KGraphViewer"
0041     EXPORT KGRAPHVIEWER
0042 )
0043
0044 target_link_libraries(kgraphviewer PRIVATE
0045     KF5::CoreAddons
0046     KF5::Parts
0047 )
0048
0049 install( TARGETS kgraphviewer ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0050
0051 ########### install kgraphviewer files ###############
0052
0053 ecm_install_icons(
0054     ICONS
0055     ${CMAKE_CURRENT_SOURCE_DIR}/16-apps-kgraphviewer.png
0056     ${CMAKE_CURRENT_SOURCE_DIR}/32-apps-kgraphviewer.png
0057     DESTINATION
0058     ${KDE_INSTALL_ICONDIR}
0059     THEME hicolor
0060 )
0061
0062 install( FILES kgraphviewersettings.kcfg DESTINATION ${KDE_INSTALL_KCFGDIR} )
0063 install( PROGRAMS org.kde.kgraphviewer.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
0064 install(FILES org.kde.kgraphviewer.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR})
0065
0066
0067 if(NOT BUILD_GRAPHEDITOR)
0068     return()
0069 endif()
0070
0071 add_executable(kgrapheditor)
0072
0073 target_sources(kgrapheditor PRIVATE
0074     kgrapheditormain.cpp
0075     kgrapheditor.cpp
0076     kgrapheditorConfigDialog.cpp
0077     KGraphEditorNodesTreeWidget.cpp
0078     KGraphEditorElementTreeWidget.cpp
0079
0080     kgrapheditor.qrc
0081 )
0082
0083 set(kgrapheditor_dbus_SRCS)
0084 qt_add_dbus_adaptor(kgrapheditor_dbus_SRCS org.kde.kgrapheditor.xml kgrapheditor.h KGraphEditor)
0085 target_sources(kgrapheditor PRIVATE ${kgrapheditor_dbus_SRCS})
0086
0087 kconfig_add_kcfg_files(kgrapheditor kgrapheditorsettings.kcfgc)
0088
0089 ki18n_wrap_ui(kgrapheditor
0090     preferencesReload.ui
0091     preferencesParsing.ui
0092     preferencesOpenInExistingWindow.ui
0093     preferencesReopenPreviouslyOpenedFiles.ui
0094 )
0095
0096 ecm_qt_declare_logging_category(kgrapheditor
0097     HEADER kgrapheditor_debug.h
0098     IDENTIFIER KGRAPHEDITOR_LOG
0099     CATEGORY_NAME org.kde.kgrapheditor
0100     DEFAULT_SEVERITY Warning
0101     DESCRIPTION "KGraphEditor"
0102     EXPORT KGRAPHVIEWER
0103 )
0104
0105 target_link_libraries(kgrapheditor PRIVATE
0106     KF5::CoreAddons
0107     KF5::Parts
0108 )
0109
0110 install( TARGETS kgrapheditor ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0111
0112 ########### install kgrapheditor files ###############
0113
0114 install(FILES kgrapheditorsettings.kcfg DESTINATION ${KDE_INSTALL_KCFGDIR})
0115 install(PROGRAMS org.kde.kgrapheditor.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
0116
0117
0118 #add_subdirectory(plasmaapplet)
0119