graphics/kdegraphics-thumbnailers/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002 project(kdegraphics-thumbnailers)
0003
0004 set(QT_MIN_VERSION "5.15.2")
0005 set(KF_MIN_VERSION "5.92.0")
0006 set(KDE_COMPILERSETTINGS_LEVEL "5.82")
0007 set(CMAKE_CXX_STANDARD 17)
0008 set(CMAKE_CXX_STANDARD_REQUIRED ON)
0009 find_package(ECM ${KF_MIN_VERSION} REQUIRED NO_MODULE)
0010 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0011
0012 include(ECMOptionalAddSubdirectory)
0013 include(KDEInstallDirs)
0014 include(KDECMakeSettings)
0015 include(KDECompilerSettings NO_POLICY_SCOPE)
0016 include(FeatureSummary)
0017 include(ECMDeprecationSettings)
0018
0019 find_package(Qt${QT_MAJOR_VERSION} ${QT_MIN_VERSION} CONFIG REQUIRED COMPONENTS Gui)
0020 find_package(KF${QT_MAJOR_VERSION} ${KF_MIN_VERSION} REQUIRED COMPONENTS KIO)
0021 find_package(KF${QT_MAJOR_VERSION} ${KF_MIN_VERSION} REQUIRED COMPONENTS Archive)
0022 add_definitions(-DQT_USE_QSTRINGBUILDER)
0023
0024 option(DISABLE_MOBIPOCKET "Disable the mobipocket thumbnailer." OFF)
0025
0026 if(QT_MAJOR_VERSION STREQUAL "6")
0027     set(KExiv2PackageName KExiv2Qt6)
0028 else()
0029     set(KExiv2PackageName KF5KExiv2)
0030 endif()
0031 find_package(${KExiv2PackageName})
0032 set_package_properties(${KExiv2PackageName}    PROPERTIES
0033                        DESCRIPTION "A library for reading and writing image metadata"
0034                        URL         "www.kde.org"
0035                        TYPE        OPTIONAL
0036                        PURPOSE     "Required to build the RAW thumbnailer"
0037 )
0038
0039 if(QT_MAJOR_VERSION STREQUAL "6")
0040     set(KDcrawPackageName KDcrawQt6)
0041 else()
0042     set(KDcrawPackageName KF5KDcraw)
0043 endif()
0044 find_package(${KDcrawPackageName})
0045 set_package_properties(${KDcrawPackageName}    PROPERTIES
0046                        DESCRIPTION "A library for accessing raw files"
0047                        URL         "www.kde.org"
0048                        TYPE        OPTIONAL
0049                        PURPOSE     "Required to build the RAW thumbnailer"
0050 )
0051
0052 if (DISABLE_MOBIPOCKET)
0053     set(MOBIPOCKET_REQUIRED_TYPE "OPTIONAL")
0054     set(DISABLE_MOBIPOCKET_TEXT "")
0055 else()
0056     set(MOBIPOCKET_REQUIRED_TYPE "REQUIRED")
0057     set(DISABLE_MOBIPOCKET_TEXT "Disable with DISABLE_MOBIPOCKET")
0058 endif()
0059
0060 if(QT_MAJOR_VERSION STREQUAL "6")
0061     find_package(QMobipocket6)
0062     set_package_properties("QMobipocket6"    PROPERTIES
0063                         DESCRIPTION "A library for accessing mobipocket files"
0064                         URL         "www.kde.org"
0065                         TYPE        ${MOBIPOCKET_REQUIRED_TYPE}
0066                         PURPOSE     "Required to build the mobipocket thumbnailer. ${DISABLE_MOBIPOCKET_TEXT}"
0067     )
0068 else()
0069     find_package(QMobipocket)
0070     set_package_properties("QMobipocket"    PROPERTIES
0071                         DESCRIPTION "A library for accessing mobipocket files"
0072                         URL         "www.kde.org"
0073                         TYPE        ${MOBIPOCKET_REQUIRED_TYPE}
0074                         PURPOSE     "Required to build the mobipocket thumbnailer. ${DISABLE_MOBIPOCKET_TEXT}"
0075     )
0076 endif()
0077
0078
0079 ecm_set_disabled_deprecation_versions(QT 5.15.2 KF 5.100.0
0080     )
0081
0082 ecm_optional_add_subdirectory(ps)
0083
0084 if(${KExiv2PackageName}_FOUND AND ${KDcrawPackageName}_FOUND)
0085 ecm_optional_add_subdirectory(raw)
0086 endif()
0087
0088 ecm_optional_add_subdirectory(blend)
0089
0090 if(QMobipocket6_FOUND OR QMobipocket_FOUND)
0091 ecm_optional_add_subdirectory(mobipocket)
0092 endif()
0093
0094 install(FILES org.kde.kdegraphics-thumbnailers.metainfo.xml
0095         DESTINATION ${KDE_INSTALL_METAINFODIR})
0096
0097 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)