kdegraphics-mobipocket/lib/CMakeLists.txt

0001 if (QT_MAJOR_VERSION STREQUAL "6")
0002     set(qmobipocket_INCLUDE_INSTALL_DIR ${KDE_INSTALL_INCLUDEDIR}/QMobipocket6)
0003 else()
0004     set(qmobipocket_INCLUDE_INSTALL_DIR ${KDE_INSTALL_INCLUDEDIR}/QMobipocket)
0005 endif()
0006
0007 add_library(qmobipocket SHARED)
0008 set_target_properties(qmobipocket PROPERTIES
0009     VERSION ${QMOBIPOCKET_VERSION}
0010     SOVERSION ${QMOBIPOCKET_SOVERSION}
0011 )
0012 if (QT_MAJOR_VERSION STREQUAL "6")
0013     set_target_properties(qmobipocket PROPERTIES
0014         LIBRARY_OUTPUT_NAME QMobipocket6
0015         EXPORT_NAME QMobipocket6
0016     )
0017 endif()
0018
0019 target_sources( qmobipocket PRIVATE
0020     decompressor.cpp
0021     mobipocket.cpp
0022     qfilestream.cpp
0023 )
0024
0025 if (QT_MAJOR_VERSION STREQUAL "5")
0026     set(_generate_export_header_version_args)
0027 else()
0028     # For Qt6/KF6 world transitively include the version header
0029     if(ECM_VERSION VERSION_LESS "5.106")
0030         set(include_version_header_code "#include <qmobipocket_version.h>\n")
0031         set(_generate_export_header_version_args CUSTOM_CONTENT_FROM_VARIABLE include_version_header_code)
0032     else()
0033         set(_generate_export_header_version_args USE_VERSION_HEADER)
0034     endif()
0035 endif()
0036
0037 ecm_generate_export_header(qmobipocket
0038      VERSION ${QMOBIPOCKET_VERSION}
0039      DEPRECATED_BASE_VERSION 0
0040     ${_generate_export_header_version_args}
0041 )
0042
0043 target_link_libraries (qmobipocket
0044     PUBLIC
0045     Qt${QT_MAJOR_VERSION}::Core
0046     Qt${QT_MAJOR_VERSION}::Gui
0047 )
0048
0049 if(TARGET Qt6::Core5Compat)
0050     target_link_libraries(qmobipocket PRIVATE Qt6::Core5Compat)
0051 endif()
0052
0053 target_include_directories(qmobipocket
0054     INTERFACE
0055         "$<INSTALL_INTERFACE:${qmobipocket_INCLUDE_INSTALL_DIR}>"
0056 )
0057
0058 install(FILES
0059     mobipocket.h
0060     qfilestream.h
0061     ${CMAKE_CURRENT_BINARY_DIR}/qmobipocket_export.h
0062     DESTINATION ${qmobipocket_INCLUDE_INSTALL_DIR}/qmobipocket
0063     COMPONENT Devel
0064 )
0065
0066 install(FILES
0067     ${CMAKE_CURRENT_BINARY_DIR}/qmobipocket_version.h
0068     DESTINATION ${qmobipocket_INCLUDE_INSTALL_DIR}
0069     COMPONENT Devel
0070 )
0071
0072 install(TARGETS qmobipocket EXPORT QMobipocketTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})