gwenview/app/CMakeLists.txt

0001 include_directories(
0002     ${CMAKE_CURRENT_SOURCE_DIR}/..
0003     )
0004
0005 # For lib/gwenviewconfig.h and config-gwenview.h
0006 include_directories(
0007     ${CMAKE_CURRENT_BINARY_DIR}/..
0008     )
0009
0010 set(gwenview_SRCS
0011     abstractcontextmanageritem.cpp
0012     alignwithsidebarwidgetaction.cpp
0013     configdialog.cpp
0014     gvcore.cpp
0015     documentinfoprovider.cpp
0016     viewmainpage.cpp
0017     fileoperations.cpp
0018     filtercontroller.cpp
0019     folderviewcontextmanageritem.cpp
0020     fullscreencontent.cpp
0021     infocontextmanageritem.cpp
0022     imagemetainfodialog.cpp
0023     imageopscontextmanageritem.cpp
0024     fileopscontextmanageritem.cpp
0025     main.cpp
0026     mainwindow.cpp
0027     preloader.cpp
0028     renamedialog.cpp
0029     saveallhelper.cpp
0030     savebar.cpp
0031     sidebar.cpp
0032     startmainpage.cpp
0033     thumbnailviewhelper.cpp
0034     browsemainpage.cpp
0035     gwenview.qrc
0036
0037     abstractcontextmanageritem.h
0038     alignwithsidebarwidgetaction.h
0039     configdialog.h
0040     gvcore.h
0041     documentinfoprovider.h
0042     viewmainpage.h
0043     fileoperations.h
0044     filtercontroller.h
0045     folderviewcontextmanageritem.h
0046     fullscreencontent.h
0047     infocontextmanageritem.h
0048     imagemetainfodialog.h
0049     imageopscontextmanageritem.h
0050     fileopscontextmanageritem.h
0051     mainwindow.h
0052     preloader.h
0053     renamedialog.h
0054     saveallhelper.h
0055     savebar.h
0056     sidebar.h
0057     startmainpage.h
0058     thumbnailviewhelper.h
0059     browsemainpage.h
0060     )
0061 ecm_qt_declare_logging_category(gwenview_SRCS HEADER gwenview_app_debug.h IDENTIFIER GWENVIEW_APP_LOG CATEGORY_NAME org.kde.kdegraphics.gwenview.app DESCRIPTION "gwenview app (kdegraphics)" EXPORT GWENVIEW)
0062 # need by GV_RETURN_VALUE_IF_FAIL
0063 ecm_qt_declare_logging_category(gwenview_SRCS HEADER gwenview_lib_debug.h IDENTIFIER GWENVIEW_LIB_LOG CATEGORY_NAME org.kde.kdegraphics.gwenview.lib DESCRIPTION "gwenview lib (kdegraphics)" EXPORT GWENVIEW)
0064
0065 if (NOT GWENVIEW_SEMANTICINFO_BACKEND_NONE)
0066     set (gwenview_SRCS
0067         ${gwenview_SRCS}
0068         semanticinfocontextmanageritem.cpp
0069         semanticinfocontextmanageritem.h
0070         )
0071 endif()
0072
0073 kde_source_files_enable_exceptions(
0074     main.cpp
0075     )
0076
0077 ki18n_wrap_ui(gwenview_SRCS
0078     advancedconfigpage.ui
0079     fullscreenconfigwidget.ui
0080     generalconfigpage.ui
0081     imageviewconfigpage.ui
0082     renamedialog.ui
0083     semanticinfodialog.ui
0084     startmainpage.ui
0085     browsemainpage.ui
0086     )
0087
0088 if (NOT GWENVIEW_SEMANTICINFO_BACKEND_NONE)
0089     ki18n_wrap_ui(gwenview_SRCS
0090         semanticinfosidebaritem.ui
0091         )
0092 endif()
0093
0094 file(GLOB ICONS_SRCS "${CMAKE_CURRENT_SOURCE_DIR}/../icons/*-apps-gwenview.png")
0095 ecm_add_app_icon(gwenview_SRCS ICONS ${ICONS_SRCS})
0096
0097 add_executable(gwenview ${gwenview_SRCS})
0098
0099 target_link_libraries(gwenview
0100     KF6::ItemModels
0101     KF6::WidgetsAddons
0102     KF6::GuiAddons
0103     gwenviewlib
0104     )
0105
0106 if (HAVE_KACTIVITIES)
0107
0108     if (QT_MAJOR_VERSION STREQUAL "6")
0109         target_link_libraries(gwenview Plasma::Activities)
0110     else()
0111         target_link_libraries(gwenview KF5::Activities)
0112     endif()
0113 endif()
0114
0115 if (KF6Purpose_FOUND)
0116     target_link_libraries(gwenview KF6::PurposeWidgets)
0117 endif()
0118
0119 target_link_libraries(gwenview LINK_INTERFACE_LIBRARIES KF6::KIOCore Qt::Core)
0120
0121 if (HAVE_TIFF)
0122     target_link_libraries(gwenview TIFF::TIFF)
0123 endif()
0124
0125 if (APPLE)
0126     # own plist template
0127     set_target_properties (gwenview PROPERTIES MACOSX_BUNDLE_INFO_PLIST ${CMAKE_CURRENT_SOURCE_DIR}/MacOSXBundleInfo.plist.in)
0128     # the MacOSX bundle display name property (CFBundleDisplayName) is not currently supported by cmake,
0129     # so has to be set for all targets in this cmake file
0130     set(MACOSX_BUNDLE_DISPLAY_NAME Gwenview5)
0131     set_target_properties(gwenview PROPERTIES MACOSX_BUNDLE_GUI_IDENTIFIER "org.kde.gwenview")
0132     set_target_properties(gwenview PROPERTIES MACOSX_BUNDLE_BUNDLE_NAME "Gwenview5")
0133     set_target_properties(gwenview PROPERTIES MACOSX_BUNDLE_DISPLAY_NAME "Gwenview5")
0134     set_target_properties(gwenview PROPERTIES MACOSX_BUNDLE_INFO_STRING "Gwenview, KDE Image Viewer")
0135     set_target_properties(gwenview PROPERTIES MACOSX_BUNDLE_LONG_VERSION_STRING "Gwenview ${RELEASE_SERVICE_VERSION}")
0136     set_target_properties(gwenview PROPERTIES MACOSX_BUNDLE_SHORT_VERSION_STRING "${KDE_APPLICATIONS_VERSION_MAJOR}.${RELEASE_SERVICE_VERSION_MINOR}")
0137     set_target_properties(gwenview PROPERTIES MACOSX_BUNDLE_BUNDLE_VERSION "${RELEASE_SERVICE_VERSION}")
0138     set_target_properties(gwenview PROPERTIES MACOSX_BUNDLE_COPYRIGHT "2002-2016 The Gwenview Authors")
0139 endif (APPLE)
0140
0141 configure_file(org.kde.gwenview.desktop.cmake ${CMAKE_CURRENT_BINARY_DIR}/org.kde.gwenview.desktop)
0142
0143 install(TARGETS gwenview
0144     ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0145
0146 install(PROGRAMS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.gwenview.desktop
0147     DESTINATION ${KDE_INSTALL_APPDIR})
0148 install(FILES org.kde.gwenview.appdata.xml
0149     DESTINATION ${KDE_INSTALL_METAINFODIR})
0150
0151 # slideshowfileitemaction plugin
0152
0153 add_definitions(-DTRANSLATION_DOMAIN=\"gwenview\")
0154
0155 kcoreaddons_add_plugin(slideshowfileitemaction
0156     SOURCES slideshowfileitemaction.cpp slideshowfileitemaction.h
0157     INSTALL_NAMESPACE "kf6/kfileitemaction")
0158
0159 target_link_libraries(slideshowfileitemaction
0160     KF6::I18n
0161     KF6::KIOWidgets
0162     KF6::Notifications)
0163
0164 if(kImageAnnotator_FOUND)
0165     target_link_libraries(gwenview kImageAnnotator::kImageAnnotator)
0166 endif()