graphics/colord-kde/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16 FATAL_ERROR)
0002
0003 set (CMAKE_CXX_STANDARD 17)
0004
0005 # KDE Application Version, managed by release script
0006 set (RELEASE_SERVICE_VERSION_MAJOR "24")
0007 set (RELEASE_SERVICE_VERSION_MINOR "04")
0008 set (RELEASE_SERVICE_VERSION_MICRO "70")
0009 set (RELEASE_SERVICE_VERSION "${RELEASE_SERVICE_VERSION_MAJOR}.${RELEASE_SERVICE_VERSION_MINOR}.${RELEASE_SERVICE_VERSION_MICRO}")
0010
0011 project(colord-kde VERSION ${RELEASE_SERVICE_VERSION})
0012
0013 set(KF_MIN_VERSION "5.240.0")
0014 set(REQUIRED_QT_VERSION "6.5.0")
0015 set(KDE_COMPILERSETTINGS_LEVEL "5.82")
0016
0017 find_package(ECM ${KF_MIN_VERSION} REQUIRED NO_MODULE)
0018 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${ECM_MODULE_PATH})
0019
0020
0021 include(KDEInstallDirs)
0022 include(KDECMakeSettings)
0023 include(KDECompilerSettings NO_POLICY_SCOPE)
0024
0025 include(FindPkgConfig)
0026 include(ECMOptionalAddSubdirectory)
0027 include(FeatureSummary)
0028 include(ECMSetupVersion)
0029 include(ECMFindQmlModule)
0030 include(ECMPoQmTools)
0031 include(KDEGitCommitHooks)
0032 include(KDEClangFormat)
0033 include(ECMDeprecationSettings)
0034
0035 file(GLOB_RECURSE ALL_CLANG_FORMAT_SOURCE_FILES *.cpp *.h *.c)
0036 kde_clang_format(${ALL_CLANG_FORMAT_SOURCE_FILES})
0037
0038 ecm_setup_version("${PROJECT_VERSION}"
0039     VARIABLE_PREFIX "COLORD_KDE"
0040     VERSION_HEADER "version.h"
0041 )
0042
0043 find_package(Qt6 ${REQUIRED_QT_VERSION} CONFIG REQUIRED COMPONENTS
0044     Core
0045     DBus
0046     Widgets
0047 )
0048
0049 option(WITHOUT_X11 "Build without colord-kded for X11 integration (skips finding X11)" OFF)
0050 if(NOT WITHOUT_X11)
0051     find_package(X11)
0052     set_package_properties(X11 PROPERTIES
0053         TYPE OPTIONAL
0054         PURPOSE "For colord integration on X11"
0055     )
0056     set(HAVE_X11 ${X11_FOUND})
0057 endif()
0058
0059 if (HAVE_X11)
0060     find_package(XCB REQUIRED COMPONENTS XCB RANDR)
0061 endif()
0062
0063 find_package(KF6 ${KF_MIN_VERSION} REQUIRED CoreAddons DBusAddons I18n KCMUtils
0064              WidgetsAddons WindowSystem ItemModels)
0065
0066 add_definitions(-DTRANSLATION_DOMAIN=\"colord-kde\")
0067
0068 add_definitions(-DQT_USE_FAST_CONCATENATION -DQT_USE_FAST_OPERATOR_PLUS)
0069
0070 pkg_check_modules(LCMS2 REQUIRED lcms2 IMPORTED_TARGET)
0071
0072 include_directories(${CMAKE_SOURCE_DIR}
0073     ${CMAKE_CURRENT_SOURCE_DIR}
0074     ${CMAKE_CURRENT_BINARY_DIR}
0075 )
0076
0077 ecm_set_disabled_deprecation_versions(
0078         KF 5.100.0)
0079
0080
0081 if (HAVE_X11)
0082     add_subdirectory(colord-kded)
0083 endif()
0084 add_subdirectory(colord-kcm)
0085 add_subdirectory(icc-importer)
0086
0087 ki18n_install(po)
0088 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)
0089 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)