arianna/src/CMakeLists.txt

0001 # SPDX-FileCopyrightText: 2021 Carl Schwan <carlschwan@kde.org>
0002 # SPDX-License-Identifier: BSD-2-Clause
0003
0004 add_library(arianna_static STATIC)
0005
0006 ecm_qt_declare_logging_category(arianna_static
0007     HEADER arianna_debug.h
0008     IDENTIFIER ARIANNA_LOG
0009     CATEGORY_NAME org.kde.arianna
0010     DESCRIPTION "arianna"
0011     DEFAULT_SEVERITY Warning
0012     EXPORT ARIANNA
0013 )
0014
0015 target_sources(arianna_static PRIVATE
0016     clipboard.cpp
0017     clipboard.h
0018     format.cpp
0019     format.h
0020     bookdatabase.cpp
0021     bookdatabase.h
0022     categoryentriesmodel.cpp
0023     categoryentriesmodel.h
0024     propertycontainer.cpp
0025     propertycontainer.h
0026     booklistmodel.cpp
0027     booklistmodel.h
0028     epubcontainer.cpp
0029     epubcontainer.h
0030     tableofcontentmodel.cpp
0031     tableofcontentmodel.h
0032
0033     navigation.h
0034     navigation.cpp
0035
0036     contentlist/contentlist.cpp
0037     contentlist/contentlist.h
0038     contentlist/contentquery.cpp
0039     contentlist/contentquery.h
0040     contentlist/contentlisterbase.cpp
0041     contentlist/contentlisterbase.h
0042     contentlist/filesystemcontentlister.cpp
0043     contentlist/filesystemcontentlister.h
0044     contentlist/manualcontentlister.cpp
0045     contentlist/manualcontentlister.h
0046     ${debug_files_SRCS}
0047 )
0048
0049 kconfig_add_kcfg_files(arianna_static GENERATE_MOC config.kcfgc)
0050
0051 target_link_libraries(arianna_static PUBLIC
0052     Qt::Quick
0053     Qt::Qml
0054     Qt::Gui
0055     Qt::Network
0056     Qt::WebSockets
0057     Qt::QuickControls2
0058     Qt::Svg
0059     Qt::Sql
0060     Qt::Xml
0061     Qt::Widgets
0062     KF${QT_MAJOR_VERSION}::I18n
0063     KF${QT_MAJOR_VERSION}::Kirigami2
0064     KF${QT_MAJOR_VERSION}::ConfigCore
0065     KF${QT_MAJOR_VERSION}::ConfigGui
0066     KF${QT_MAJOR_VERSION}::WindowSystem
0067     KF${QT_MAJOR_VERSION}::DBusAddons
0068     KF${QT_MAJOR_VERSION}::FileMetaData
0069     KF${QT_MAJOR_VERSION}::Archive
0070     KF${QT_MAJOR_VERSION}::CoreAddons)
0071
0072 if (${QT_MAJOR_VERSION} STREQUAL 5)
0073     target_link_libraries(arianna_static PUBLIC Qt::WebEngine)
0074 else()
0075     target_link_libraries(arianna_static PUBLIC Qt::WebEngineQuick)
0076 endif()
0077
0078 if (NOT WIN32)
0079     target_link_libraries(arianna_static PUBLIC KF${QT_MAJOR_VERSION}::Baloo)
0080     target_sources(arianna_static PRIVATE contentlist/baloocontentlister.cpp contentlist/baloocontentlister.h)
0081     target_compile_definitions(arianna_static PUBLIC -DHAVE_BALOO)
0082 endif()
0083
0084 if (BUILD_TESTING)
0085     add_subdirectory(autotests)
0086 endif()
0087
0088 if(QT_MAJOR_VERSION STREQUAL "5")
0089        set(QML_QTGRAPHICAL_EFFECTS_IMPORT "QtGraphicalEffects 1.15")
0090        set(KIRIGAMI_PLACEITEM_ICON "icon")
0091        set(KIRIGAMI_ACTIONS "actions.main")
0092        set(QTQUICKDIALOG_VERSION "1.3")
0093        set(DIALOG_FONTDIALOG_FONT "font")
0094 else()
0095        set(QML_QTGRAPHICAL_EFFECTS_IMPORT "Qt5Compat.GraphicalEffects")
0096        set(KIRIGAMI_PLACEITEM_ICON "icon.name")
0097        set(KIRIGAMI_ACTIONS "actions")
0098        set(QTQUICKDIALOG_VERSION "")
0099        set(DIALOG_FONTDIALOG_FONT "currentFont")
0100 endif()
0101
0102 configure_file(content/ui/GridBrowserDelegate.qml ${CMAKE_CURRENT_BINARY_DIR}/content/ui/GridBrowserDelegate.qml)
0103 configure_file(content/ui/main.qml ${CMAKE_CURRENT_BINARY_DIR}/content/ui/main.qml)
0104 configure_file(content/ui/LibraryPage.qml ${CMAKE_CURRENT_BINARY_DIR}/content/ui/LibraryPage.qml)
0105 configure_file(content/ui/SettingsPage.qml ${CMAKE_CURRENT_BINARY_DIR}/content/ui/SettingsPage.qml)
0106 configure_file(resources.qrc.in ${CMAKE_CURRENT_SOURCE_DIR}/resources.qrc)
0107
0108 add_executable(arianna
0109     main.cpp
0110     ${CMAKE_CURRENT_SOURCE_DIR}/resources.qrc
0111 )
0112
0113 target_include_directories(arianna PRIVATE ${CMAKE_BINARY_DIR})
0114 target_link_libraries(arianna PRIVATE arianna_static)
0115
0116 install(TARGETS arianna ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})