Warning, /graphics/arianna/CMakeLists.txt is written in an unsupported language. File is not indexed.

0001 # SPDX-FileCopyrightText: 2021 Carl Schwan <carlschwan@kde.org>
0002 # SPDX-License-Identifier: BSD-2-Clause
0003 
0004 cmake_minimum_required(VERSION 3.16)
0005 
0006 # KDE Applications version, managed by release script.
0007 set(RELEASE_SERVICE_VERSION_MAJOR "23")
0008 set(RELEASE_SERVICE_VERSION_MINOR "08")
0009 set(RELEASE_SERVICE_VERSION_MICRO "5")
0010 set(RELEASE_SERVICE_VERSION "${RELEASE_SERVICE_VERSION_MAJOR}.${RELEASE_SERVICE_VERSION_MINOR}.${RELEASE_SERVICE_VERSION_MICRO}")
0011 project(arianna VERSION ${RELEASE_SERVICE_VERSION})
0012 
0013 set(KF_MIN_VERSION "5.98.0")
0014 set(QT_MIN_VERSION "5.15.0")
0015 
0016 find_package(ECM ${KF_MIN_VERSION} REQUIRED NO_MODULE)
0017 
0018 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH} ${CMAKE_SOURCE_DIR}/cmake)
0019 
0020 set(CMAKE_CXX_STANDARD 17)
0021 set(CMAKE_CXX_STANDARD_REQUIRED ON)
0022 
0023 include(FeatureSummary)
0024 include(ECMSetupVersion)
0025 include(KDEInstallDirs)
0026 include(ECMFindQmlModule)
0027 include(KDEClangFormat)
0028 include(ECMQtDeclareLoggingCategory)
0029 include(KDECMakeSettings)
0030 include(KDECompilerSettings NO_POLICY_SCOPE)
0031 include(ECMAddAppIcon)
0032 include(KDEGitCommitHooks)
0033 include(ECMAddTests)
0034 include(ECMCheckOutboundLicense)
0035 include(KDEClangFormat)
0036 
0037 ecm_setup_version(${PROJECT_VERSION}
0038     VARIABLE_PREFIX ARIANNA
0039     VERSION_HEADER ${CMAKE_CURRENT_BINARY_DIR}/arianna-version.h
0040 )
0041 
0042 find_package(Qt${QT_MAJOR_VERSION} ${QT_MIN_VERSION} NO_MODULE COMPONENTS Widgets Core Quick Gui QuickControls2 WebSockets WebChannel Test Svg Sql Xml)
0043 set_package_properties(Qt${QT_MAJOR_VERSION} PROPERTIES
0044     TYPE REQUIRED
0045     PURPOSE "Basic application components"
0046 )
0047 find_package(KF${QT_MAJOR_VERSION} ${KF_MIN_VERSION} COMPONENTS Kirigami2 I18n Config CoreAddons DBusAddons WindowSystem FileMetaData Archive QuickCharts)
0048 set_package_properties(KF${QT_MAJOR_VERSION} PROPERTIES
0049     TYPE REQUIRED
0050     PURPOSE "Basic application components"
0051 )
0052 set_package_properties(KF${QT_MAJOR_VERSION}Kirigami2 PROPERTIES
0053     TYPE REQUIRED
0054     PURPOSE "Kirigami application UI framework"
0055 )
0056 find_package(KF${QT_MAJOR_VERSION}KirigamiAddons 0.10 REQUIRED)
0057 find_package(KF${QT_MAJOR_VERSION}QQC2DesktopStyle REQUIRED)
0058 
0059 if (${QT_MAJOR_VERSION} STREQUAL 5)
0060     find_package(Qt${QT_MAJOR_VERSION} ${QT_MIN_VERSION} NO_MODULE COMPONENTS WebEngine)
0061 else()
0062     find_package(Qt${QT_MAJOR_VERSION} ${QT_MIN_VERSION} NO_MODULE COMPONENTS WebEngineQuick)
0063 endif()
0064 
0065 if (NOT WIN32)
0066     find_package(KF${QT_MAJOR_VERSION} ${KF_MIN_VERSION} COMPONENTS Baloo)
0067 endif()
0068 
0069 add_definitions(-DQT_NO_FOREACH -DQT_NO_KEYWORDS)
0070 
0071 add_subdirectory(src)
0072 
0073 ki18n_install(po)
0074 
0075 install(FILES org.kde.arianna.desktop DESTINATION ${KDE_INSTALL_APPDIR})
0076 install(FILES org.kde.arianna.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR})
0077 install(FILES org.kde.arianna.svg DESTINATION ${KDE_INSTALL_FULL_ICONDIR}/hicolor/scalable/apps)
0078 
0079 ecm_qt_install_logging_categories(
0080     EXPORT ARIANNA
0081     FILE arianna.categories
0082     SORT DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0083 )
0084 
0085 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)
0086 
0087 file(GLOB_RECURSE ALL_CLANG_FORMAT_SOURCE_FILES src/*.cpp src/*.h)
0088 kde_clang_format(${ALL_CLANG_FORMAT_SOURCE_FILES})
0089 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)