games/skladnik/CMakeLists.txt

0001 cmake_minimum_required (VERSION 3.16 FATAL_ERROR)
0002
0003 project(skladnik VERSION "0.5.2")
0004
0005 set(QT_MIN_VERSION "5.15.2")
0006 set(KF_MIN_VERSION "5.91.0")
0007
0008 find_package(ECM ${KF_MIN_VERSION} REQUIRED NO_MODULE)
0009 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/cmake" ${ECM_MODULE_PATH} )
0010
0011 include(KDEInstallDirs)
0012 include(KDECMakeSettings)
0013 include(KDECompilerSettings NO_POLICY_SCOPE)
0014
0015 include(ECMDeprecationSettings)
0016 include(ECMInstallIcons)
0017 include(ECMSetupVersion)
0018 include(FeatureSummary)
0019
0020 if (QT_MAJOR_VERSION STREQUAL "6")
0021     set(QT_MIN_VERSION "6.5.0")
0022     set(KF_MIN_VERSION "6.0.0")
0023     set(KF_MAJOR_VERSION "6")
0024 else()
0025     set(KF_MAJOR_VERSION "5")
0026 endif()
0027
0028 find_package(Qt${QT_MAJOR_VERSION} ${QT_MIN_VERSION} REQUIRED COMPONENTS
0029     Core
0030     Gui
0031     Widgets
0032 )
0033
0034 find_package(KF${KF_MAJOR_VERSION} ${KF_MIN_VERSION} REQUIRED COMPONENTS
0035     Config
0036     ConfigWidgets
0037     CoreAddons
0038     Crash
0039     DBusAddons
0040     I18n
0041     KIO
0042     WidgetsAddons
0043     XmlGui
0044 )
0045
0046 find_package(KF${KF_MAJOR_VERSION}DocTools ${KF_MIN_VERSION})
0047
0048 if (QT_MAJOR_VERSION STREQUAL "6")
0049     find_package(KDEGames6 6.0.0 REQUIRED)
0050 else()
0051     find_package(KF5KDEGames 7.3.0 REQUIRED)
0052 endif()
0053
0054 if (QT_MAJOR_VERSION STREQUAL "6")
0055     ecm_set_disabled_deprecation_versions(
0056         QT 6.5
0057         KF 5.239
0058         KDEGAMES 6.0
0059     )
0060 else()
0061     ecm_set_disabled_deprecation_versions(
0062         QT 5.15.2
0063         KF 5.91
0064         KDEGAMES 7.3
0065     )
0066 endif()
0067
0068 add_subdirectory(src)
0069 add_subdirectory(icons)
0070 add_subdirectory(themes)
0071 if(KF${KF_MAJOR_VERSION}DocTools_FOUND)
0072     add_subdirectory(doc)
0073     kdoctools_install(po)
0074 endif()
0075
0076 ki18n_install(po)
0077
0078 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)