games/lskat/CMakeLists.txt

0001 cmake_minimum_required (VERSION 3.16 FATAL_ERROR)
0002
0003 # Release Service version, managed by release script
0004 set (RELEASE_SERVICE_VERSION_MAJOR "23")
0005 set (RELEASE_SERVICE_VERSION_MINOR "07")
0006 set (RELEASE_SERVICE_VERSION_MICRO "70")
0007 set (RELEASE_SERVICE_COMPACT_VERSION "${RELEASE_SERVICE_VERSION_MAJOR}${RELEASE_SERVICE_VERSION_MINOR}${RELEASE_SERVICE_VERSION_MICRO}")
0008
0009 # Bump LSKAT_BASE_VERSION once new features are added
0010 set(LSKAT_BASE_VERSION "1.50")
0011
0012 set(LSKAT_VERSION "${LSKAT_BASE_VERSION}.${RELEASE_SERVICE_COMPACT_VERSION}")
0013
0014 project(lskat VERSION ${LSKAT_VERSION})
0015
0016 set (QT_MIN_VERSION "5.15.2")
0017 set (KF_MIN_VERSION "5.92.0")
0018
0019 find_package(ECM ${KF_MIN_VERSION} REQUIRED CONFIG)
0020 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${ECM_MODULE_PATH} )
0021
0022 include(KDEInstallDirs)
0023 include(KDECMakeSettings)
0024 include(KDECompilerSettings NO_POLICY_SCOPE)
0025
0026 include(ECMAddAppIcon)
0027 include(ECMInstallIcons)
0028 include(ECMQtDeclareLoggingCategory)
0029 include(ECMSetupVersion)
0030 include(FeatureSummary)
0031 include(ECMDeprecationSettings)
0032 if (QT_MAJOR_VERSION STREQUAL "6")
0033     set(QT_REQUIRED_VERSION "6.4.0")
0034     set(KF_MIN_VERSION "5.240.0")
0035     set(KF_MAJOR_VERSION "6")
0036 else()
0037     set(KF_MAJOR_VERSION "5")
0038 endif()
0039
0040 find_package(Qt${QT_MAJOR_VERSION} ${QT_MIN_VERSION} REQUIRED NO_MODULE COMPONENTS Gui Svg Widgets)
0041
0042 find_package(KF${KF_MAJOR_VERSION} ${KF_MIN_VERSION} REQUIRED COMPONENTS
0043     Config
0044     CoreAddons
0045     Crash
0046     DocTools
0047     GuiAddons
0048     I18n
0049     WidgetsAddons
0050     XmlGui
0051 )
0052
0053 if (QT_MAJOR_VERSION STREQUAL "6")
0054     find_package(KDEGames6 7.5.0 REQUIRED)
0055 else()
0056     find_package(KF5KDEGames 7.3.0 REQUIRED)
0057 endif()
0058
0059 ecm_set_disabled_deprecation_versions(
0060     QT 6.4
0061     KF 5.103
0062     KDEGAMES 7.3
0063 )
0064
0065
0066 # added by KDE_COMPILERSETTINGS_LEVEL 5.85
0067 remove_definitions(
0068     -DQT_NO_CAST_FROM_ASCII
0069 )
0070
0071 add_subdirectory(src)
0072 add_subdirectory(grafix)
0073 add_subdirectory(doc)
0074
0075 ########### install files ###############
0076 install(PROGRAMS org.kde.lskat.desktop  DESTINATION  ${KDE_INSTALL_APPDIR})
0077 install(FILES org.kde.lskat.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR})
0078
0079 ecm_install_icons(ICONS
0080     128-apps-lskat.png
0081     16-apps-lskat.png
0082     22-apps-lskat.png
0083     32-apps-lskat.png
0084     48-apps-lskat.png
0085     64-apps-lskat.png
0086     DESTINATION ${KDE_INSTALL_ICONDIR} THEME hicolor
0087 )
0088
0089 ki18n_install(po)
0090 kdoctools_install(po)
0091
0092 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)