libkmahjongg/tilesets/CMakeLists.txt

0001 # SPDX-FileCopyrightText: 2021, 2023 Friedrich W. H. Kossebau <kossebau@kde.org>
0002 #
0003 # SPDX-License-Identifier: BSD-3-Clause
0004
0005 function(list_with_tileset_rendering_check id old_file new_file)
0006     # symbolic target for cheking this file, always outdated
0007     set(check_rendering_output "check_rendering_${old_file}")
0008     set_property(SOURCE ${check_rendering_output} PROPERTY SYMBOLIC 1)
0009
0010     add_custom_command(
0011         OUTPUT ${check_rendering_output}
0012         COMMAND ${CMAKE_COMMAND}
0013         ARGS
0014             "-DID=${id}"
0015             "-DWORKING_DIR=${CMAKE_CURRENT_BINARY_DIR}"
0016             "-DRENDERELEMENT=$<TARGET_FILE:renderelement>"
0017             "-DCOMPARE=${ImageMagick_compare_EXECUTABLE}"
0018             "-DOLD_FILE=${CMAKE_CURRENT_SOURCE_DIR}/${old_file}"
0019             "-DNEW_FILE=${new_file}"
0020             -P ${CMAKE_CURRENT_SOURCE_DIR}/CompareTilesetsSVGs.cmake
0021         COMMENT "Checking SVG of ${id}"
0022     )
0023
0024     # add to general target
0025     set(target_check_rendering_output "check_rendering_tileset_${id}")
0026     add_custom_target(${target_check_rendering_output} DEPENDS ${check_rendering_output})
0027     add_dependencies(check_rendering ${target_check_rendering_output})
0028 endfunction()
0029
0030 function(install_tileset id)
0031     cmake_parse_arguments(ARGS "NO_CLEANING" "" "" ${ARGN})
0032
0033     set(generate_args)
0034     if (ARGS_NO_CLEANING)
0035         list(APPEND generate_args NO_CLEANING)
0036     endif()
0037
0038     set(svgz "${CMAKE_CURRENT_BINARY_DIR}/${id}.svgz")
0039     generate_svgz(${id}.svg ${svgz} "tileset-" ${generate_args})
0040     if(BUILD_SVG_CHECKS)
0041         list_with_tileset_rendering_check(${id} ${id}.svg ${svgz})
0042     endif()
0043     install(
0044         FILES
0045             ${id}.desktop
0046             ${svgz}
0047         DESTINATION ${KDE_INSTALL_DATADIR}/kmahjongglib/tilesets
0048     )
0049 endfunction()
0050
0051 install_tileset(default)
0052 install_tileset(classic)
0053 #install_tileset(bamboo)
0054 install_tileset(traditional)
0055 install_tileset(alphabet)
0056 install_tileset(egypt)
0057 install_tileset(jade)