src/private/CMakeLists.txt

0001 set(kdegamesprivate_INCLUDE_INSTALL_DIR ${kdegames_INCLUDE_INSTALL_DIR}/libkdegamesprivate)
0002 set(KDEGAMESPRIVATE_OUTPUT_NAME KDEGames6Private)
0003 set(KDEGAMESPRIVATE_EXPORT_NAME KDEGames6Private)
0004
0005 if(BUILD_TESTING)
0006     add_subdirectory(tests)
0007 endif()
0008
0009 add_library(KDEGamesPrivate SHARED)
0010
0011 set_target_properties(KDEGamesPrivate PROPERTIES
0012     OUTPUT_NAME ${KDEGAMESPRIVATE_OUTPUT_NAME}
0013     EXPORT_NAME ${KDEGAMESPRIVATE_EXPORT_NAME}
0014     VERSION     ${KDEGAMES_VERSION}
0015     SOVERSION   ${KDEGAMES_SOVERSION}
0016 )
0017
0018 ecm_generate_export_header(KDEGamesPrivate
0019     VERSION ${KDEGAMES_VERSION}
0020     DEPRECATED_BASE_VERSION 0
0021     DEPRECATION_VERSIONS
0022     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0023     USE_VERSION_HEADER
0024     VERSION_BASE_NAME KDEGames
0025 )
0026
0027 ecm_qt_declare_logging_category(KDEGamesPrivate
0028     HEADER kdegamesprivate_logging.h
0029     IDENTIFIER KDEGAMESPRIVATE_LOG
0030     CATEGORY_NAME kdegames.private
0031     DESCRIPTION "libkdegamesprivate"
0032     EXPORT KDEGAMES
0033 )
0034
0035 ecm_qt_declare_logging_category(KDEGamesPrivate
0036     HEADER kdegamesprivate_kgame_logging.h
0037     IDENTIFIER KDEGAMESPRIVATE_KGAME_LOG
0038     CATEGORY_NAME kdegames.private.kgame
0039     DESCRIPTION "libkdegamesprivate KGame"
0040     EXPORT KDEGAMES
0041 )
0042
0043 target_sources(KDEGamesPrivate PRIVATE
0044     kchatbase.cpp
0045     kchatbaseitemdelegate.cpp
0046     kchatbasemodel.cpp
0047     kgame/kgamechat.cpp
0048     kgame/kgame.cpp
0049     kgame/kgameerror.cpp
0050     kgame/kgameio.cpp
0051     kgame/kgamemessage.cpp
0052     kgame/kgamenetwork.cpp
0053     kgame/kgameproperty.cpp
0054     kgame/kgamepropertyhandler.cpp
0055     kgame/kgamesequence.cpp
0056     kgame/kmessageclient.cpp
0057     kgame/kmessageio.cpp
0058     kgame/kmessageserver.cpp
0059     kgame/kplayer.cpp
0060     kgamesvgdocument.cpp
0061 )
0062
0063 target_link_libraries(KDEGamesPrivate
0064     PUBLIC
0065         KDEGames
0066         KF6::Completion
0067         Qt6::Xml
0068         Qt6::Network
0069     PRIVATE
0070         KF6::DNSSD
0071         KF6::I18n
0072         KF6::Archive
0073         KF6::CoreAddons
0074         KF6::XmlGui
0075 )
0076
0077 target_include_directories(KDEGamesPrivate
0078     INTERFACE
0079         "$<INSTALL_INTERFACE:${kdegamesprivate_INCLUDE_INSTALL_DIR}>"
0080     PRIVATE
0081         kgame
0082 )
0083
0084 install(TARGETS KDEGamesPrivate
0085     EXPORT KDEGamesTargets
0086     ${KDE_INSTALL_TARGETS_DEFAULT_ARGS}
0087 )
0088
0089 install(FILES
0090     ${CMAKE_CURRENT_BINARY_DIR}/kdegamesprivate_export.h
0091     kchatbase.h
0092     kchatbaseitemdelegate.h
0093     kchatbasemodel.h
0094     kgamesvgdocument.h
0095     DESTINATION ${kdegamesprivate_INCLUDE_INSTALL_DIR}
0096     COMPONENT Devel
0097 )
0098
0099 install(FILES
0100     kgame/kgamechat.h
0101     kgame/kgameerror.h
0102     kgame/kgame.h
0103     kgame/kgameio.h
0104     kgame/kgamemessage.h
0105     kgame/kgamenetwork.h
0106     kgame/kgameproperty.h
0107     kgame/kgamepropertyhandler.h
0108     kgame/kgamesequence.h
0109     kgame/kgameversion.h
0110     kgame/kmessageclient.h
0111     kgame/kmessageio.h
0112     kgame/kmessageserver.h
0113     kgame/kplayer.h
0114     DESTINATION ${kdegamesprivate_INCLUDE_INSTALL_DIR}/kgame
0115     COMPONENT Devel
0116 )