src/carddecks/CMakeLists.txt

0001 # SPDX-FileCopyrightText: 2021, 2023 Friedrich W. H. Kossebau <kossebau@kde.org>
0002 #
0003 # SPDX-License-Identifier: BSD-3-Clause
0004
0005 option(BUILD_SVG_CHECKS "Build SVG rendering checks." OFF)
0006 add_feature_info(BUILD_SVG_CHECKS BUILD_SVG_CHECKS "Build SVG rendering checks.")
0007
0008 if(BUILD_SVG_CHECKS)
0009     find_package(ImageMagick COMPONENTS compare)
0010     set_package_properties(ImageMagick PROPERTIES
0011         TYPE REQUIRED
0012         PURPOSE "For checking cleaned SVG file renderings"
0013     )
0014
0015     add_subdirectory(tools)
0016 endif()
0017
0018 function(install_carddeck id)
0019     set(options AUTHORS COPYING COPYRIGHT NO_CLEANING)
0020     set(oneValueArgs PREVIEW SVG)
0021     set(multiValueArgs)
0022     cmake_parse_arguments(ARG "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})
0023
0024     set(output_dir "${CMAKE_CURRENT_BINARY_DIR}/${id}")
0025     file(MAKE_DIRECTORY "${output_dir}")
0026
0027     set(generate_args)
0028     if (ARG_NO_CLEANING)
0029         list(APPEND generate_args NO_CLEANING)
0030     endif()
0031
0032     set(svgz "${output_dir}/${ARG_SVG}z")
0033     generate_svgz("${id}/${ARG_SVG}" ${svgz} "carddeck-${id}-" ${generate_args})
0034     if(BUILD_SVG_CHECKS)
0035         list_with_rendering_check(${id} "${id}/${ARG_SVG}" ${svgz})
0036     endif()
0037
0038     set(copyright_files)
0039     if (ARG_COPYRIGHT)
0040         list(APPEND copyright_files "${id}/COPYRIGHT")
0041     endif()
0042     if (ARG_COPYING)
0043         list(APPEND copyright_files "${id}/COPYING")
0044     endif()
0045     if (ARG_AUTHORS)
0046         list(APPEND copyright_files "${id}/AUTHORS")
0047     endif()
0048
0049     install(
0050         FILES
0051             ${copyright_files}
0052             ${id}/index.desktop
0053             ${id}/${ARG_PREVIEW}
0054             ${svgz}
0055         DESTINATION ${KDE_INSTALL_DATADIR}/carddecks/${id}
0056     )
0057 endfunction()
0058
0059 # Disabling svgcleaner due to issues with: card back
0060 # Yet to be analysed.
0061 install_carddeck(svg-ancient-egyptians      PREVIEW 11.png              SVG Ancient_Egyptians.svg   NO_CLEANING)
0062 install_carddeck(svg-dondorf                PREVIEW 11.png              SVG dondorf.svg)
0063 install_carddeck(svg-future                 PREVIEW 11.png              SVG future.svg)
0064 install_carddeck(svg-gm-paris               PREVIEW 11.png              SVG paris.svg)
0065 install_carddeck(svg-jolly-royal            PREVIEW 11.png              SVG jolly-royal.svg)
0066 install_carddeck(svg-konqi-modern           PREVIEW 11.png              SVG konqi.svg)
0067 install_carddeck(svg-nicu-ornamental        PREVIEW 11.png              SVG ornamental.svg  AUTHORS COPYING)
0068 install_carddeck(svg-nicu-white             PREVIEW 11.png              SVG white.svg  AUTHORS COPYING)
0069 install_carddeck(svg-oxygen                 PREVIEW 11.png              SVG oxygen.svg)
0070 install_carddeck(svg-oxygen-air             PREVIEW 11.png              SVG oxygen-air.svg)
0071 install_carddeck(svg-oxygen-white           PREVIEW 11.png              SVG oxygen-white.svg)
0072 # Disabling svgcleaner due to issues with: cards king_*, queen_*, jack_*
0073 # svgcleaner when removing default attributes fails over <use> e.g. with card decos setting some style,
0074 # where the copied (sub)elements explicitly want to (re)set some default value, e.g. to stroke:none
0075 # -> --remove-default-attributes=no helps
0076 # Some other stroke issue though yet to be analysed
0077 install_carddeck(svg-penguins               PREVIEW 11.png              SVG penguins.svg  COPYRIGHT   NO_CLEANING)
0078 install_carddeck(svg-standard               PREVIEW 11.png              SVG standard.svg)
0079 install_carddeck(svg-tigullio-international PREVIEW queen-of-hearts.png SVG tigullio-international.svg)
0080 install_carddeck(svg-xskat-french           PREVIEW 11.png              SVG french.svg  COPYRIGHT)
0081 install_carddeck(svg-xskat-german           PREVIEW 11.png              SVG german.svg  COPYRIGHT)