libkdegames/src/CMakeLists.txt

0001 set(kdegames_INCLUDE_INSTALL_DIR ${KDE_INSTALL_INCLUDEDIR}/KDEGames6)
0002 set(KDEGAMES_CMAKECONFIG_NAME "KDEGames6")
0003 set(KDEGAMES_OUTPUT_NAME KDEGames6)
0004 set(KDEGAMES_EXPORT_NAME KDEGames6)
0005
0006 ecm_setup_version(PROJECT
0007     VARIABLE_PREFIX KDEGAMES
0008     VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/kdegames_version.h"
0009     PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/${KDEGAMES_CMAKECONFIG_NAME}ConfigVersion.cmake"
0010     COMPATIBILITY SameMajorVersion
0011     SOVERSION 6
0012 )
0013
0014 add_subdirectory(carddecks)
0015 add_subdirectory(qml)
0016 add_subdirectory(private)
0017
0018 configure_file(libkdegames_capabilities.h.in ${CMAKE_CURRENT_BINARY_DIR}/libkdegames_capabilities.h)
0019 configure_file(highscore/config-highscore.h.in ${CMAKE_CURRENT_BINARY_DIR}/highscore/config-highscore.h )
0020
0021 add_library(KDEGames SHARED)
0022
0023 set_target_properties(KDEGames PROPERTIES
0024     OUTPUT_NAME ${KDEGAMES_OUTPUT_NAME}
0025     EXPORT_NAME ${KDEGAMES_EXPORT_NAME}
0026     VERSION     ${KDEGAMES_VERSION}
0027     SOVERSION   ${KDEGAMES_SOVERSION}
0028 )
0029
0030 target_sources(KDEGames PRIVATE
0031     audio/kgameaudioscene-${KGAUDIO_BACKEND}.cpp
0032     audio/kgamesound-${KGAUDIO_BACKEND}.cpp
0033     audio/virtualfileqt-${KGAUDIO_BACKEND}.cpp
0034     colorproxy_p.cpp colorproxy_p.h
0035 #   highscore/kconfigrawbackend.cpp
0036     highscore/kgamehighscore.cpp highscore/kgamehighscore.h
0037     highscore/kgamehighscoredialog.cpp highscore/kgamehighscoredialog.h
0038     kgameclock.cpp kgameclock.h
0039     kgamepopupitem.cpp kgamepopupitem.h
0040     kgamerendereditem.cpp kgamerendereditem.h
0041     kgamerenderedgraphicsobject.cpp kgamerenderedgraphicsobject.h
0042     kgamerendererclient.cpp kgamerendererclient.h
0043     kgamerenderer.cpp kgamerenderer.h
0044     kgameimageprovider.cpp kgameimageprovider_p.h
0045     kgamedifficulty.cpp kgamedifficulty.h
0046     kgametheme.cpp kgametheme.h
0047     kgamethemeprovider.cpp kgamethemeprovider.h
0048     kgamethemeselector.cpp kgamethemeselector.h
0049     kgamestandardaction.cpp kgamestandardaction.h
0050     kgamegraphicsviewrenderer.cpp kgamegraphicsviewrenderer.h
0051 )
0052
0053 ecm_generate_headers(kdegames_CamelCase_HEADERS
0054     HEADER_NAMES
0055         KGameClock
0056         KGamePopupItem
0057         KGameRenderedItem
0058         KGameRenderedGraphicsObject
0059         KGameGraphicsViewRenderer
0060         KGameRenderer
0061         KGameRendererClient
0062         KGameDifficulty,KGameDifficultyLevel
0063         KGameTheme
0064         KGameThemeProvider
0065         KGameThemeSelector
0066         KGameStandardAction
0067     REQUIRED_HEADERS kdegames_HEADERS
0068 )
0069
0070 ecm_generate_headers(kdegames_CamelCase_HEADERS
0071     HEADER_NAMES
0072         KGameHighscore
0073         KGameHighScoreDialog
0074     RELATIVE highscore
0075     REQUIRED_HEADERS kdegames_HEADERS
0076 )
0077
0078 ecm_generate_headers(kdegames_CamelCase_HEADERS
0079     HEADER_NAMES
0080         KGameAudioScene
0081         KGameSound
0082     RELATIVE audio
0083     REQUIRED_HEADERS kdegames_HEADERS
0084 )
0085
0086 ecm_qt_declare_logging_category(KDEGames
0087     HEADER kdegames_logging.h
0088     IDENTIFIER KDEGAMES_LOG
0089     CATEGORY_NAME kdegames
0090     DESCRIPTION "libkdegames"
0091     EXPORT KDEGAMES
0092 )
0093
0094 ecm_qt_declare_logging_category(KDEGames
0095     HEADER kdegames_audio_logging.h
0096     IDENTIFIER KDEGAMES_AUDIO_LOG
0097     CATEGORY_NAME kdegames.audio
0098     DESCRIPTION "libkdegames Audio"
0099     EXPORT KDEGAMES
0100 )
0101
0102 ecm_qt_declare_logging_category(KDEGames
0103     HEADER kdegames_highscore_logging.h
0104     IDENTIFIER KDEGAMES_HIGHSCORE_LOG
0105     CATEGORY_NAME kdegames.highscore
0106     DESCRIPTION "libkdegames Highscore"
0107     EXPORT KDEGAMES
0108 )
0109
0110 ecm_generate_export_header(KDEGames
0111     VERSION ${KDEGAMES_VERSION}
0112     DEPRECATED_BASE_VERSION 0
0113     DEPRECATION_VERSIONS
0114     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0115     USE_VERSION_HEADER
0116 )
0117
0118 target_link_libraries(KDEGames
0119     PUBLIC
0120         KF6::ConfigCore
0121         KF6::ConfigWidgets
0122         Qt6::Qml
0123     PRIVATE
0124         ${KGAUDIO_LINKLIBS}
0125         KF6::NewStuffWidgets
0126         KF6::IconThemes
0127         KF6::I18n
0128         KF6::XmlGui
0129         KF6::GuiAddons
0130         KF6::Completion
0131         Qt6::Xml
0132         Qt6::Svg
0133         Qt6::Quick
0134 )
0135
0136 target_include_directories(KDEGames
0137     INTERFACE
0138         "$<INSTALL_INTERFACE:${kdegames_INCLUDE_INSTALL_DIR}>"
0139     PRIVATE
0140         ${OPENAL_INCLUDE_DIR}
0141         ${SNDFILE_INCLUDE_DIR}
0142         highscore
0143         ${CMAKE_CURRENT_BINARY_DIR}/highscore
0144 )
0145
0146 install(TARGETS KDEGames EXPORT KDEGamesTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0147
0148
0149 ########### install files ###############
0150
0151 install(FILES ${kdegames_CamelCase_HEADERS}
0152     DESTINATION ${kdegames_INCLUDE_INSTALL_DIR}
0153     COMPONENT Devel
0154 )
0155
0156 install(FILES
0157     ${CMAKE_CURRENT_BINARY_DIR}/kdegames_export.h
0158     ${CMAKE_CURRENT_BINARY_DIR}/libkdegames_capabilities.h
0159     ${kdegames_HEADERS}
0160     DESTINATION ${kdegames_INCLUDE_INSTALL_DIR}
0161     COMPONENT Devel
0162 )
0163
0164 ########### generate exports ###############
0165
0166 # define the installation directory for the CMake files
0167 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/${KDEGAMES_CMAKECONFIG_NAME}")
0168
0169 # create the Config.cmake and ConfigVersion.cmake files
0170 configure_package_config_file(
0171     "${CMAKE_CURRENT_SOURCE_DIR}/KDEGamesConfig.cmake.in"
0172     "${CMAKE_CURRENT_BINARY_DIR}/${KDEGAMES_CMAKECONFIG_NAME}Config.cmake"
0173     INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0174 )
0175
0176 install(FILES
0177     "${CMAKE_CURRENT_BINARY_DIR}/${KDEGAMES_CMAKECONFIG_NAME}Config.cmake"
0178     "${CMAKE_CURRENT_BINARY_DIR}/${KDEGAMES_CMAKECONFIG_NAME}ConfigVersion.cmake"
0179     DESTINATION ${CMAKECONFIG_INSTALL_DIR}
0180     COMPONENT Devel
0181 )
0182
0183 install(EXPORT KDEGamesTargets
0184     DESTINATION ${CMAKECONFIG_INSTALL_DIR}
0185     FILE ${KDEGAMES_CMAKECONFIG_NAME}Targets.cmake
0186     COMPONENT Devel
0187 )
0188
0189 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/kdegames_version.h
0190     DESTINATION ${kdegames_INCLUDE_INSTALL_DIR}
0191     COMPONENT Devel
0192 )
0193
0194 ecm_qt_install_logging_categories(
0195     EXPORT KDEGAMES
0196     FILE libkdegames.categories
0197     DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0198 )