games/libkdegames/CMakeLists.txt

0001 cmake_minimum_required (VERSION 3.16 FATAL_ERROR)
0002
0003 # Release Service version, managed by release script
0004 set(RELEASE_SERVICE_VERSION_MAJOR "24")
0005 set(RELEASE_SERVICE_VERSION_MINOR "04")
0006 set(RELEASE_SERVICE_VERSION_MICRO "70")
0007
0008 # generate patch level from release service version
0009 set(_micro ${RELEASE_SERVICE_VERSION_MICRO})
0010 if (_micro LESS "10")
0011     string(PREPEND _micro "0") # pad with 0
0012 endif()
0013 set(RELEASE_SERVICE_BASED_PATCHLEVEL "${RELEASE_SERVICE_VERSION_MAJOR}${RELEASE_SERVICE_VERSION_MINOR}${_micro}")
0014
0015 project(libkdegames VERSION "6.0.${RELEASE_SERVICE_BASED_PATCHLEVEL}")
0016
0017 set(QT_MIN_VERSION "6.5.0")
0018 set(KF_MIN_VERSION "5.245.0")
0019
0020 find_package(ECM ${KF_MIN_VERSION} REQUIRED NO_MODULE)
0021 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules ${ECM_MODULE_PATH})
0022
0023 include(KDEInstallDirs)
0024 include(KDECMakeSettings)
0025 include(KDECompilerSettings NO_POLICY_SCOPE)
0026
0027 include(KDEClangFormat)
0028 include(KDEGitCommitHooks)
0029 include(ECMSetupVersion)
0030 include(ECMGenerateHeaders)
0031 include(ECMMarkNonGuiExecutable)
0032 include(ECMGenerateExportHeader)
0033 include(ECMQtDeclareLoggingCategory)
0034 include(ECMDeprecationSettings)
0035 include(ECMQmlModule)
0036 include(FeatureSummary)
0037 include(CMakePackageConfigHelpers)
0038
0039 find_package(Qt6 ${QT_MIN_VERSION} REQUIRED COMPONENTS
0040     Widgets
0041     Qml
0042     Quick
0043     Svg
0044     Test
0045 )
0046
0047 find_package(KF6 ${KF_MIN_VERSION} REQUIRED COMPONENTS
0048     Archive
0049     ColorScheme
0050     Completion
0051     Config
0052     ConfigWidgets
0053     DNSSD
0054     GuiAddons
0055     IconThemes
0056     I18n
0057     NewStuff
0058     XmlGui
0059 )
0060
0061 include(InternalMacros)
0062
0063 set(EXCLUDE_DEPRECATED_BEFORE_AND_AT 0 CACHE STRING "Control the range of deprecated API excluded from the build [default=0].")
0064
0065 set(HIGHSCORE_DIRECTORY "" CACHE STRING "Where to install system-wide highscores e.g. /var/games")
0066
0067 find_package(OpenAL)
0068 set_package_properties(OpenAL PROPERTIES
0069     URL "https://www.openal.org/"
0070     TYPE REQUIRED
0071 )
0072
0073 find_package(SndFile)
0074 set_package_properties(SndFile PROPERTIES
0075     URL "http://www.mega-nerd.com/libsndfile/"
0076     TYPE REQUIRED
0077 )
0078
0079 message(STATUS "Checking libsndfile capabilities")
0080 try_compile(SNDFILE_WORKS
0081     ${CMAKE_CURRENT_BINARY_DIR}/src/audio/check-libsndfile-capabilities
0082     ${CMAKE_CURRENT_SOURCE_DIR}/src/audio/check-libsndfile-capabilities.cpp
0083     CMAKE_FLAGS -DINCLUDE_DIRECTORIES=${SNDFILE_INCLUDE_DIR})
0084 if (NOT SNDFILE_WORKS)
0085     message(FATAL_ERROR "Your version of libsndfile (found in " ${SNDFILE_LIBRARIES} ") is too old. At least version 0.21 is needed.")
0086 endif (NOT SNDFILE_WORKS)
0087
0088 message (STATUS "INCLUDES FOR SOUND:  " ${OPENAL_INCLUDE_DIR} " " ${SNDFILE_INCLUDE_DIR})
0089 message (STATUS "LIBRARIES FOR SOUND: " ${OPENAL_LIBRARY} " " ${SNDFILE_LIBRARIES})
0090 set(KGAUDIO_LINKLIBS ${OPENAL_LIBRARY} ${SNDFILE_LIBRARIES})
0091 set(KGAUDIO_BACKEND openal)
0092 set(KGAUDIO_BACKEND_OPENAL TRUE) # for configure_file() below
0093
0094 add_definitions(-DTRANSLATION_DOMAIN="libkdegames6")
0095
0096 ecm_set_disabled_deprecation_versions(
0097     QT 6.5
0098     KF 5.239
0099 )
0100
0101 add_subdirectory(src)
0102
0103 if(BUILD_TESTING)
0104     add_subdirectory(tests)
0105 endif()
0106
0107 ki18n_install(po)
0108
0109 file(GLOB_RECURSE CLANG_FORMAT_SOURCE_FILES *.cpp *.h)
0110 kde_clang_format(${CLANG_FORMAT_SOURCE_FILES})
0111
0112 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)
0113
0114 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)