games/ksirk/CMakeLists.txt

0001 cmake_minimum_required (VERSION 3.16 FATAL_ERROR)
0002
0003 # KDE Application Version, managed by release script
0004 set(RELEASE_SERVICE_VERSION_MAJOR "24")
0005 set(RELEASE_SERVICE_VERSION_MINOR "04")
0006 set(RELEASE_SERVICE_VERSION_MICRO "70")
0007 set(RELEASE_SERVICE_VERSION "${RELEASE_SERVICE_VERSION_MAJOR}.${RELEASE_SERVICE_VERSION_MINOR}.${RELEASE_SERVICE_VERSION_MICRO}")
0008
0009 project(ksirk VERSION ${RELEASE_SERVICE_VERSION})
0010
0011 set(QT_MIN_VERSION "6.5.0")
0012 set(KF_MIN_VERSION "5.240.0")
0013 set(KDE_QT_MODERNCODE_DEFINITIONS_LEVEL "5.84")
0014
0015 find_package(ECM ${KF_MIN_VERSION} REQUIRED CONFIG)
0016 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${ECM_MODULE_PATH} )
0017
0018 include(KDEInstallDirs)
0019 include(KDECMakeSettings)
0020 include(KDECompilerSettings NO_POLICY_SCOPE)
0021
0022 include(ECMAddAppIcon)
0023 include(ECMInstallIcons)
0024 include(ECMSetupVersion)
0025 include(ECMQtDeclareLoggingCategory)
0026 include(ECMDeprecationSettings)
0027 include(FeatureSummary)
0028
0029 # TODO: port libiris
0030 option(WITH_JABBER_SUPPORT "Build with support for network gaming using Jabber" OFF)
0031 add_feature_info(JABBER ${WITH_JABBER_SUPPORT} "Network gaming using Jabber")
0032
0033 find_package(Qt6 ${QT_MIN_VERSION} REQUIRED COMPONENTS
0034     Core5Compat
0035     Multimedia
0036     Svg
0037     SvgWidgets
0038     Widgets
0039     Test
0040 )
0041 find_package(KF6 ${KF_MIN_VERSION} REQUIRED COMPONENTS
0042     Completion
0043     Config
0044     ConfigWidgets
0045     CoreAddons
0046     Crash
0047     DBusAddons
0048     DocTools
0049     I18n
0050     NewStuff
0051     WidgetsAddons
0052     XmlGui
0053 )
0054
0055 find_package(KDEGames6 6.0.0 REQUIRED)
0056
0057 if(WITH_JABBER_SUPPORT)
0058     find_package(KF6 ${KF_MIN_VERSION} REQUIRED COMPONENTS
0059         KIO
0060         Wallet)
0061     find_package(Qca-qt6 2.1.0)
0062     set_package_properties(Qca-qt5 PROPERTIES
0063         DESCRIPTION "Support for encryption with Jabber"
0064         URL "https://download.kde.org/stable/qca-qt5"
0065         TYPE REQUIRED
0066     )
0067 endif()
0068
0069 kde_enable_exceptions()
0070
0071 add_definitions(
0072     -DQT_USE_FAST_OPERATOR_PLUS
0073     -DQT_NO_URL_CAST_FROM_STRING
0074 )
0075
0076 ecm_set_disabled_deprecation_versions(
0077     QT 6.5
0078     KF 5.239
0079     KDEGAMES 6.0
0080 )
0081
0082 ecm_setup_version(PROJECT
0083     VARIABLE_PREFIX KSIRK
0084     VERSION_HEADER ksirk_version.h
0085 )
0086
0087 add_subdirectory(ksirk)
0088 add_subdirectory(ksirkskineditor)
0089 add_subdirectory(doc)
0090
0091 ki18n_install(po)
0092 kdoctools_install(po)
0093
0094 ecm_qt_install_logging_categories(
0095     EXPORT KSIRK
0096     FILE ksirk.categories
0097     DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0098 )
0099
0100 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)