kpat/src/CMakeLists.txt

0001 add_subdirectory(libkcardgame)
0002
0003 add_executable(kpat)
0004
0005 ecm_setup_version(${kpat_VERSION}
0006     VARIABLE_PREFIX KPAT
0007     VERSION_HEADER kpat_version.h
0008 )
0009
0010 get_target_property(WITH_FCS_SOFT_SUSPEND FreecellSolver::FreecellSolver FREECELLSOLVER_HAS_SOFT_SUSPEND)
0011 configure_file(patsolve-config.h.in patsolve-config.h)
0012
0013 target_sources(kpat PRIVATE
0014     main.cpp
0015     dealer.cpp
0016     dealerinfo.cpp
0017     gameselectionscene.cpp
0018     mainwindow.cpp
0019     messagebox.cpp
0020     numbereddealdialog.cpp
0021     patpile.cpp
0022     pileutils.cpp
0023     renderer.cpp
0024     soundengine.cpp
0025     statisticsdialog.cpp
0026     view.cpp
0027     patsolve/abstract_fc_solve_solver.cpp
0028     patsolve/memory.cpp
0029     patsolve/patsolve.cpp
0030
0031     bakersdozen.cpp
0032     patsolve/bakersdozensolver.cpp
0033     castle.cpp
0034     patsolve/castlesolver.cpp
0035     clock.cpp
0036     patsolve/clocksolver.cpp
0037     fortyeight.cpp
0038     patsolve/fortyeightsolver.cpp
0039     freecell.cpp
0040     patsolve/freecellsolver.cpp
0041     golf.cpp
0042     grandf.cpp
0043     patsolve/grandfsolver.cpp
0044     gypsy.cpp
0045     patsolve/gypsysolver.cpp
0046     idiot.cpp
0047     patsolve/idiotsolver.cpp
0048     klondike.cpp
0049     patsolve/klondikesolver.cpp
0050     mod3.cpp
0051     patsolve/mod3solver.cpp
0052     simon.cpp
0053     patsolve/simonsolver.cpp
0054     spider.cpp
0055     patsolve/spidersolver2.cpp
0056     yukon.cpp
0057     patsolve/yukonsolver.cpp
0058     kpat.qrc
0059 )
0060 if (WITH_BH_SOLVER)
0061     target_sources(kpat PRIVATE
0062         patsolve/golfsolver.cpp
0063     )
0064 endif()
0065
0066 ki18n_wrap_ui(kpat statisticsdialog.ui)
0067 kconfig_add_kcfg_files(kpat settings.kcfgc)
0068
0069 ecm_qt_declare_logging_category(kpat
0070     HEADER kpat_debug.h
0071     IDENTIFIER KPAT_LOG
0072     CATEGORY_NAME org.kde.kpat
0073     DESCRIPTION "KPatience"
0074     EXPORT KPAT
0075 )
0076
0077 file(GLOB ICONS_SRCS "${CMAKE_SOURCE_DIR}/icons/*-apps-kpat.png")
0078 ecm_add_app_icon(kpat ICONS ${ICONS_SRCS})
0079
0080 target_link_libraries(kpat
0081     KDEGames6
0082     KF6::Crash
0083     KF6::DBusAddons
0084     KF6::I18n
0085     KF6::KIOCore
0086     KF6::GuiAddons
0087     KF6::Completion
0088     KF6::XmlGui
0089     kcardgame
0090     FreecellSolver::FreecellSolver
0091 )
0092 if (WITH_BH_SOLVER)
0093     target_link_libraries(kpat
0094         BlackHoleSolver::BlackHoleSolver
0095     )
0096 endif()
0097
0098 install(TARGETS kpat ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0099
0100 install(PROGRAMS org.kde.kpat.desktop  DESTINATION  ${KDE_INSTALL_APPDIR})
0101 install(FILES org.kde.kpat.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR})
0102 install(FILES kpat.kcfg DESTINATION ${KDE_INSTALL_KCFGDIR})
0103
0104 ecm_qt_install_logging_categories(
0105     EXPORT KPAT
0106     FILE kpat.categories
0107     DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0108 )