games/knights/CMakeLists.txt

0001 cmake_minimum_required (VERSION 3.16 FATAL_ERROR)
0002
0003 # Release Service version, managed by release script
0004 set (RELEASE_SERVICE_VERSION_MAJOR "24")
0005 set (RELEASE_SERVICE_VERSION_MINOR "04")
0006 set (RELEASE_SERVICE_VERSION_MICRO "70")
0007 set (RELEASE_SERVICE_COMPACT_VERSION "${RELEASE_SERVICE_VERSION_MAJOR}${RELEASE_SERVICE_VERSION_MINOR}${RELEASE_SERVICE_VERSION_MICRO}")
0008
0009 # Bump KNIGHTS_BASE_VERSION once new features are added
0010 set(KNIGHTS_BASE_VERSION "2.6")
0011 set(KNIGHTS_VERSION "${KNIGHTS_BASE_VERSION}.${RELEASE_SERVICE_COMPACT_VERSION}")
0012
0013 project(Knights VERSION ${KNIGHTS_VERSION})
0014
0015 set(QT_MIN_VERSION "6.5.0")
0016 set(KF_MIN_VERSION "5.245.0")
0017 set(PLASMA_MIN_VERSION "5.27.80")
0018
0019 find_package(ECM ${KF_MIN_VERSION} REQUIRED CONFIG)
0020 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake ${ECM_MODULE_PATH})
0021
0022 if(CMAKE_COMPILER_IS_GNUCXX)
0023     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wpointer-arith -Wunreachable-code -fno-omit-frame-pointer -fstack-protector")
0024 endif(CMAKE_COMPILER_IS_GNUCXX)
0025
0026 #set(CMAKE_CXX_FLAGS_PROFILE "-fprofile-arcs -ftest-coverage -pg")
0027
0028 include(KDEInstallDirs)
0029 include(KDECMakeSettings)
0030 include(KDECompilerSettings NO_POLICY_SCOPE)
0031
0032 include(ECMAddAppIcon)
0033 include(ECMInstallIcons)
0034 include(ECMQtDeclareLoggingCategory)
0035 include(ECMSetupVersion)
0036 include(ECMDeprecationSettings)
0037 include(FeatureSummary)
0038
0039 include(InternalMacros)
0040
0041 find_package(Qt6 ${QT_MIN_VERSION} REQUIRED COMPONENTS
0042     Concurrent
0043     Core
0044     Core5Compat
0045     Gui
0046     Widgets
0047     Svg
0048 )
0049
0050 find_package(Qt6TextToSpeech ${QT_MIN_VERSION} QUIET)
0051 set_package_properties(Qt6TextToSpeech PROPERTIES
0052     PURPOSE "Speaking of opponents moves"
0053 )
0054 if (Qt6TextToSpeech_FOUND)
0055     add_definitions(-DHAVE_SPEECH)
0056 endif ()
0057
0058 find_package(KF6 ${KF_MIN_VERSION} REQUIRED COMPONENTS
0059     CoreAddons
0060     DBusAddons
0061     ConfigWidgets
0062     Crash
0063     TextWidgets
0064     XmlGui
0065     KIO
0066     Plotting
0067     DocTools
0068     Wallet
0069     Svg
0070 )
0071
0072 find_package(Plasma ${PLASMA_MIN_VERSION} REQUIRED)
0073 set_package_properties(Plasma PROPERTIES
0074     TYPE RUNTIME
0075     PURPOSE "clock svg (part of the desktop theme)"
0076 )
0077
0078 find_package(KDEGames6 6.0.0 REQUIRED)
0079
0080 ecm_set_disabled_deprecation_versions(
0081     QT 6.5
0082     KF 5.239
0083     KDEGAMES 6.0
0084 )
0085
0086 add_subdirectory(doc)
0087 add_subdirectory(icons)
0088 add_subdirectory(sounds)
0089 add_subdirectory(src)
0090 add_subdirectory(themes)
0091
0092 ecm_qt_install_logging_categories(
0093     EXPORT KNIGHTS
0094     FILE knights.categories
0095     DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0096 )
0097
0098 ki18n_install(po)
0099 kdoctools_install(po)
0100
0101 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)