killbots/src/CMakeLists.txt

0001 ecm_setup_version(${RELEASE_SERVICE_VERSION}
0002     VARIABLE_PREFIX KILLBOTS
0003     VERSION_HEADER killbots_version.h
0004 )
0005
0006 add_executable(killbots)
0007
0008 target_sources(killbots PRIVATE
0009     actions.h
0010     coordinator.cpp
0011     coordinator.h
0012     engine.cpp
0013     engine.h
0014     main.cpp
0015     mainwindow.cpp
0016     mainwindow.h
0017     numericdisplayitem.cpp
0018     numericdisplayitem.h
0019     optionspage.cpp
0020     optionspage.h
0021     renderer.cpp
0022     renderer.h
0023     ruleset.cpp
0024     rulesetdetailsdialog.cpp
0025     rulesetdetailsdialog.h
0026     ruleset.h
0027     rulesetselector.cpp
0028     rulesetselector.h
0029     scene.cpp
0030     scene.h
0031     sprite.cpp
0032     sprite.h
0033     view.cpp
0034     view.h
0035
0036     killbots.qrc
0037 )
0038
0039 ecm_qt_declare_logging_category(killbots
0040     HEADER killbots_debug.h
0041     IDENTIFIER KILLBOTS_LOG
0042     CATEGORY_NAME org.kde.kdegames.killbots
0043     DESCRIPTION "Killbots"
0044     EXPORT KILLBOTS
0045 )
0046
0047 kconfig_add_kcfg_files(killbots settings.kcfgc rulesetbase.kcfgc)
0048
0049 file(GLOB ICONS_SRCS "${CMAKE_SOURCE_DIR}/icons/*-apps-killbots.png")
0050 ecm_add_app_icon(killbots ICONS ${ICONS_SRCS})
0051
0052 if (QT_MAJOR_VERSION STREQUAL "6")
0053     target_link_libraries(killbots KDEGames6)
0054 else()
0055     target_link_libraries(killbots KF5KDEGames)
0056 endif()
0057
0058 target_link_libraries(killbots
0059     KF${KF_MAJOR_VERSION}::CoreAddons
0060     KF${KF_MAJOR_VERSION}::XmlGui
0061     KF${KF_MAJOR_VERSION}::DBusAddons
0062     KF${KF_MAJOR_VERSION}::Completion
0063     KF${KF_MAJOR_VERSION}::Crash
0064     KF${KF_MAJOR_VERSION}::I18n
0065     Qt::Widgets
0066     Qt::Xml
0067 )
0068
0069 install(TARGETS killbots ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0070 install(PROGRAMS org.kde.killbots.desktop DESTINATION ${KDE_INSTALL_APPDIR})
0071 install(FILES org.kde.killbots.appdata.xml DESTINATION  ${KDE_INSTALL_METAINFODIR})
0072 install(FILES killbots.kcfg DESTINATION ${KDE_INSTALL_KCFGDIR})
0073
0074 ecm_qt_install_logging_categories(
0075     EXPORT KILLBOTS
0076     FILE killbots.categories
0077     DESTINATION "${KDE_INSTALL_LOGGINGCATEGORIESDIR}"
0078 )