games/kigo/CMakeLists.txt

0001 cmake_minimum_required (VERSION 3.16 FATAL_ERROR)
0002
0003 # Release Service version, managed by release script
0004 set (RELEASE_SERVICE_VERSION_MAJOR "24")
0005 set (RELEASE_SERVICE_VERSION_MINOR "04")
0006 set (RELEASE_SERVICE_VERSION_MICRO "70")
0007 set (RELEASE_SERVICE_COMPACT_VERSION "${RELEASE_SERVICE_VERSION_MAJOR}${RELEASE_SERVICE_VERSION_MINOR}${RELEASE_SERVICE_VERSION_MICRO}")
0008
0009 # Bump KIGO_BASE_VERSION once new features are added
0010 set(KIGO_BASE_VERSION "0.6")
0011 set(KIGO_VERSION "${KIGO_BASE_VERSION}.${RELEASE_SERVICE_COMPACT_VERSION}")
0012
0013 project(kigo VERSION ${KIGO_VERSION})
0014
0015 set(QT_MIN_VERSION "6.5.0")
0016 set(KF_MIN_VERSION "5.245.0")
0017
0018 find_package(ECM ${KF_MIN_VERSION} REQUIRED CONFIG)
0019 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${ECM_MODULE_PATH})
0020
0021 include(KDEInstallDirs)
0022 include(KDECMakeSettings)
0023 include(KDECompilerSettings NO_POLICY_SCOPE)
0024
0025 include(ECMAddAppIcon)
0026 include(ECMInstallIcons)
0027 include(ECMQtDeclareLoggingCategory)
0028 include(ECMSetupVersion)
0029 include(FeatureSummary)
0030 include(ECMDeprecationSettings)
0031
0032 include(InternalMacros)
0033
0034 find_package(Qt6 ${QT_MIN_VERSION} REQUIRED COMPONENTS
0035     Svg
0036     Widgets
0037 )
0038
0039 find_package(KF6 ${KF_MIN_VERSION} REQUIRED COMPONENTS
0040     CoreAddons
0041     Config
0042     Crash
0043     DBusAddons
0044     DocTools
0045     I18n
0046     ConfigWidgets
0047     TextWidgets
0048     WidgetsAddons
0049     XmlGui
0050     KIO
0051     NewStuff
0052 )
0053
0054 find_package(KDEGames6 6.0.0 REQUIRED)
0055
0056 find_package(GNUGo QUIET)
0057 set_package_properties(GNUGo PROPERTIES
0058     DESCRIPTION "A go-playing program (engine)"
0059     URL "https://www.gnu.org/software/gnugo/"
0060     PURPOSE "Used as backend (or any other compatible with the GTP protocol)"
0061     TYPE RUNTIME
0062 )
0063
0064 ecm_set_disabled_deprecation_versions(
0065     QT 6.5
0066     KF 5.239
0067     KDEGAMES 6.0
0068 )
0069
0070 add_subdirectory(src)
0071 add_subdirectory(data)
0072 add_subdirectory(doc)
0073
0074 ki18n_install(po)
0075 kdoctools_install(po)
0076
0077 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)