kgoldrunner/themes/CMakeLists.txt

0001 # SPDX-FileCopyrightText: 2022 Friedrich W. H. Kossebau <kossebau@kde.org>
0002 #
0003 # SPDX-License-Identifier: BSD-3-Clause
0004
0005 set(KGOLDRUNNER_INSTALL_THEMESDIR "${KDE_INSTALL_DATADIR}/kgoldrunner/themes")
0006
0007 function(install_theme id)
0008     cmake_parse_arguments(ARG "" "" "FILES" ${ARGN})
0009     install( FILES ${id}.desktop DESTINATION ${KGOLDRUNNER_INSTALL_THEMESDIR} )
0010
0011     foreach(_file ${ARG_FILES})
0012         get_filename_component(_dir "${_file}" DIRECTORY)
0013         get_filename_component(_extension "${_file}" EXT)
0014
0015         if (_extension STREQUAL ".svg")
0016             set(svgz "${CMAKE_CURRENT_BINARY_DIR}/${_file}z")
0017             generate_svgz("${_file}" "${svgz}" "theme-${_dir}-")
0018             set(_file "${svgz}")
0019         endif()
0020         install( FILES ${_file} DESTINATION ${KGOLDRUNNER_INSTALL_THEMESDIR}/${_dir} )
0021     endforeach()
0022 endfunction()
0023
0024 install_theme(default
0025     FILES
0026         default/set.svg
0027         default/actors.svg
0028         default/default.png
0029
0030         default/climb.wav
0031         default/completed.ogg
0032         default/death.ogg
0033         default/dig.ogg
0034         default/falling.ogg
0035         default/gameover.ogg
0036         default/gold.ogg
0037         default/ladder.ogg
0038         default/step.wav
0039         default/victory.ogg
0040 )
0041
0042 install_theme(black-on-white
0043     FILES
0044         accessible/black-on-white-set.svg
0045         accessible/black-on-white-actors.svg
0046         accessible/black-on-white.png
0047 )
0048
0049 install_theme(egypt
0050     FILES
0051         egypt/egypt_kgr.svg
0052         egypt/actors.svg
0053         egypt/egypt.png
0054 )
0055
0056 install_theme(kgr_geek
0057     FILES
0058         kgr_geek/set.svg
0059         kgr_geek/actors.svg
0060         kgr_geek/kgr_geek.png
0061 )
0062
0063 install_theme(nostalgia
0064     FILES
0065         nostalgia/set.svg
0066         nostalgia/actors.svg
0067         nostalgia/nostalgia.png
0068 )
0069
0070 install_theme(nostalgia-blues
0071     FILES
0072         nostalgia/blue-set.svg
0073         nostalgia/blue-actors.svg
0074         nostalgia/nostalgia-blues.png
0075 )
0076
0077 install( FILES README DESTINATION ${KGOLDRUNNER_INSTALL_THEMESDIR})
0078 install( FILES kgoldrunner.knsrc  DESTINATION  ${KDE_INSTALL_DATADIR}/knsrcfiles )