games/kbounce/CMakeLists.txt

0001 cmake_minimum_required (VERSION 3.16 FATAL_ERROR)
0002
0003 # KDE Application Version, managed by release script
0004 set(RELEASE_SERVICE_VERSION_MAJOR "23")
0005 set(RELEASE_SERVICE_VERSION_MINOR "08")
0006 set(RELEASE_SERVICE_VERSION_MICRO "1")
0007 set(RELEASE_SERVICE_VERSION "${RELEASE_SERVICE_VERSION_MAJOR}.${RELEASE_SERVICE_VERSION_MINOR}.${RELEASE_SERVICE_VERSION_MICRO}")
0008
0009 project(kbounce VERSION ${RELEASE_SERVICE_VERSION})
0010
0011 set (QT_MIN_VERSION "5.15.2")
0012 set (KF_MIN_VERSION "5.91.0")
0013
0014 find_package(ECM ${KF_MIN_VERSION} REQUIRED CONFIG)
0015 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${ECM_MODULE_PATH} )
0016
0017 include(KDEInstallDirs)
0018 include(KDECMakeSettings)
0019 include(KDECompilerSettings NO_POLICY_SCOPE)
0020
0021 include(FeatureSummary)
0022 include(ECMInstallIcons)
0023 include(ECMAddAppIcon)
0024 include(ECMSetupVersion)
0025 include(ECMDeprecationSettings)
0026 if (QT_MAJOR_VERSION STREQUAL "6")
0027     set(QT_REQUIRED_VERSION "6.4.0")
0028     set(KF_MIN_VERSION "5.240.0")
0029     set(KF_MAJOR_VERSION "6")
0030 else()
0031     set(KF_MAJOR_VERSION "5")
0032 endif()
0033 include(ECMQtDeclareLoggingCategory)
0034
0035 find_package(Qt${QT_MAJOR_VERSION} ${QT_MIN_VERSION} REQUIRED NO_MODULE COMPONENTS Widgets Svg)
0036
0037 find_package(KF${KF_MAJOR_VERSION} ${KF_MIN_VERSION} REQUIRED COMPONENTS
0038     CoreAddons
0039     Config
0040     Crash
0041     WidgetsAddons
0042     DBusAddons
0043     I18n
0044     ConfigWidgets
0045     Completion
0046     XmlGui
0047     KIO
0048     DocTools
0049 )
0050
0051 if (QT_MAJOR_VERSION STREQUAL "6")
0052     find_package(KDEGames6 7.5.0 REQUIRED)
0053 else()
0054     find_package(KF5KDEGames 7.3.0 REQUIRED)
0055 endif()
0056
0057 ecm_set_disabled_deprecation_versions(
0058     QT 6.4
0059     KF 5.103
0060     KDEGAMES 7.3
0061 )
0062
0063 add_subdirectory(themes)
0064 add_subdirectory(sounds)
0065 add_subdirectory(pics)
0066 add_subdirectory(doc)
0067 add_subdirectory(src)
0068
0069 ki18n_install(po)
0070 kdoctools_install(po)
0071
0072 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)