katomic/src/CMakeLists.txt

0001 ecm_setup_version(${RELEASE_SERVICE_VERSION}
0002     VARIABLE_PREFIX KATOMIC
0003     VERSION_HEADER katomic_version.h
0004 )
0005
0006 add_executable(katomic)
0007
0008 target_sources(katomic PRIVATE
0009     atom.h
0010     chooselevelsetdialog.cpp
0011     chooselevelsetdialog.h
0012     commondefs.h
0013     fielditem.cpp
0014     fielditem.h
0015     gamewidget.cpp
0016     gamewidget.h
0017     highscores.cpp
0018     highscores.h
0019     levelset.cpp
0020     levelsetdelegate.cpp
0021     levelsetdelegate.h
0022     levelset.h
0023     main.cpp
0024     molecule.cpp
0025     molecule.h
0026     playfield.cpp
0027     playfield.h
0028     toplevel.cpp
0029     toplevel.h
0030
0031     katomic.qrc
0032 )
0033
0034 ecm_qt_declare_logging_category(katomic
0035     HEADER katomic_debug.h
0036     IDENTIFIER KATOMIC_LOG
0037     CATEGORY_NAME org.kde.kdegames.katomic
0038     DESCRIPTION "katomic (kdegames)"
0039     EXPORT KATOMIC
0040 )
0041
0042 kconfig_add_kcfg_files(katomic prefs.kcfgc)
0043
0044 ki18n_wrap_ui(katomic levelsetwidget.ui)
0045
0046 file(GLOB ICONS_SRCS "${CMAKE_SOURCE_DIR}/icons/*-apps-katomic.png")
0047 ecm_add_app_icon(katomic ICONS ${ICONS_SRCS})
0048
0049 target_link_libraries(katomic
0050     KDEGames6
0051     KF6::NewStuffWidgets
0052     KF6::I18n
0053     KF6::DBusAddons
0054     KF6::Crash
0055     KF6::XmlGui
0056 )
0057
0058 install(TARGETS katomic  ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0059
0060 install(PROGRAMS org.kde.katomic.desktop  DESTINATION  ${KDE_INSTALL_APPDIR})
0061 install(FILES org.kde.katomic.appdata.xml DESTINATION  ${KDE_INSTALL_METAINFODIR})
0062 # default theme is installed without .desktop file since KGameTheme does not need it
0063 # when only one theme is available. See: 30a1cadd20
0064 install(FILES default_theme.svgz  DESTINATION  ${KDE_INSTALL_DATADIR}/katomic/pics/)
0065 install(FILES katomic.knsrc  DESTINATION  ${KDE_INSTALL_KNSRCDIR})
0066
0067 if(NOT WIN32)
0068     install(PROGRAMS katomic-levelset-upd.pl DESTINATION  ${KDE_INSTALL_KCONFUPDATEDIR})
0069     install(FILES katomic-levelset.upd DESTINATION  ${KDE_INSTALL_KCONFUPDATEDIR})
0070 endif()
0071
0072 ecm_qt_install_logging_categories(
0073     EXPORT KATOMIC
0074     FILE katomic.categories
0075     DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0076 )