games/atlantik/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16 FATAL_ERROR)
0002
0003 project(atlantik VERSION 0.7.80)
0004
0005 set(QT_MIN_VERSION "6.5.0")
0006 set(KF_MIN_VERSION "6.0.0")
0007 set(KDE_COMPILERSETTINGS_LEVEL "5.84")
0008
0009 find_package(ECM ${KF_MIN_VERSION} REQUIRED NO_MODULE)
0010 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${ECM_MODULE_PATH})
0011
0012 include(KDEInstallDirs)
0013 include(KDECMakeSettings)
0014 include(KDECompilerSettings NO_POLICY_SCOPE)
0015 include(FeatureSummary)
0016 include(GenerateExportHeader)
0017 include(ECMQtDeclareLoggingCategory)
0018 include(ECMInstallIcons)
0019 include(CMakePackageConfigHelpers)
0020 include(ECMSetupVersion)
0021 include(ECMAddAppIcon)
0022
0023
0024 ecm_setup_version(PROJECT
0025    VARIABLE_PREFIX ATLANTIK
0026    VERSION_HEADER client/version.h
0027 )
0028
0029 find_package(Qt6 ${QT_MIN_VERSION} REQUIRED COMPONENTS
0030     Core
0031     Core5Compat
0032     Gui
0033     Network
0034     Xml
0035     Widgets
0036 )
0037
0038 find_package(KF6 ${KF_MIN_VERSION} REQUIRED COMPONENTS
0039     Config
0040     ConfigWidgets
0041     CoreAddons
0042     Crash
0043     DBusAddons
0044     I18n
0045     IconThemes
0046     Notifications
0047     NotifyConfig
0048     XmlGui
0049     WidgetsAddons
0050 )
0051
0052 find_package(KF6DocTools)
0053
0054 find_package(KDEGames6 6.0.0 REQUIRED)
0055
0056 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)
0057
0058 add_definitions(-DQT_USE_FAST_CONCATENATION -DQT_USE_FAST_OPERATOR_PLUS)
0059 add_definitions(-DQT_STRICT_ITERATORS)
0060 add_definitions(-DQT_NO_URL_CAST_FROM_STRING)
0061 add_definitions(-DTRANSLATION_DOMAIN="atlantik")
0062 add_definitions(-DQT_DEPRECATED_WARNINGS)
0063 add_definitions(-DKF_DEPRECATED_WARNINGS_SINCE=0x060000)
0064 add_definitions(-DQT_NO_CAST_FROM_BYTEARRAY)
0065 add_definitions(-DQT_NO_CAST_TO_ASCII)
0066 add_definitions(-DQT_NO_CAST_FROM_ASCII)
0067
0068 set(GENERIC_LIB_SOVERSION "5")
0069 set(GENERIC_LIB_VERSION "5.0.0")
0070
0071 add_subdirectory( libatlantic )
0072 add_subdirectory( libatlantikui )
0073 add_subdirectory( libatlantikclient )
0074 add_subdirectory( client )
0075 add_subdirectory( pics )
0076 add_subdirectory( themes )
0077 if(KF6DocTools_FOUND)
0078   add_subdirectory(doc)
0079   kdoctools_install(po)
0080 endif()
0081
0082 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/Atlantik")
0083 configure_package_config_file(
0084   "${CMAKE_CURRENT_SOURCE_DIR}/AtlantikConfig.cmake.in"
0085   "${CMAKE_CURRENT_BINARY_DIR}/AtlantikConfig.cmake"
0086   INSTALL_DESTINATION ${CMAKECONFIG_INSTALL_DIR}
0087 )
0088
0089 ########### install files ###############
0090
0091 install(PROGRAMS org.kde.atlantik.desktop DESTINATION ${KDE_INSTALL_APPDIR})
0092 install(FILES atlantik.notifyrc DESTINATION ${KDE_INSTALL_KNOTIFYRCDIR})
0093 install(FILES "${CMAKE_CURRENT_BINARY_DIR}/AtlantikConfig.cmake" DESTINATION "${CMAKECONFIG_INSTALL_DIR}" COMPONENT Devel)
0094 install(EXPORT AtlanticTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE AtlanticTargets.cmake NAMESPACE Atlantik:: )
0095 install(EXPORT AtlantikUiTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE AtlantikUiTargets.cmake NAMESPACE Atlantik:: )
0096 install(FILES org.kde.atlantik.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR})
0097
0098 ecm_qt_install_logging_categories(
0099     EXPORT ATLANTIK
0100     FILE atlantik.categories
0101     DESTINATION "${KDE_INSTALL_LOGGINGCATEGORIESDIR}"
0102 )
0103
0104 ki18n_install(po)