frameworks/threadweaver/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 set(KF_VERSION "6.0.0") # handled by release scripts
0004 project(ThreadWeaver VERSION ${KF_VERSION})
0005
0006 include(FeatureSummary)
0007 find_package(ECM 5.249.0  NO_MODULE)
0008 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0009 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0010
0011 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0012
0013 include(KDEInstallDirs)
0014 include(KDECMakeSettings)
0015 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0016
0017 include(KDEGitCommitHooks)
0018 include(ECMGenerateExportHeader)
0019 include(ECMSetupVersion)
0020 include(ECMGenerateHeaders)
0021 include(ECMDeprecationSettings)
0022 include(ECMAddQch)
0023
0024 set(REQUIRED_QT_VERSION 6.5.0)
0025 find_package(Qt6Core ${REQUIRED_QT_VERSION} REQUIRED NO_MODULE)
0026
0027 set(EXCLUDE_DEPRECATED_BEFORE_AND_AT 0 CACHE STRING "Control the range of deprecated API excluded from the build [default=0].")
0028
0029 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0030 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0031
0032 set(threadweaver_version_header "${CMAKE_CURRENT_BINARY_DIR}/src/threadweaver_version.h")
0033 ecm_setup_version(PROJECT VARIABLE_PREFIX THREADWEAVER
0034                         VERSION_HEADER "${threadweaver_version_header}"
0035                         PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF6ThreadWeaverConfigVersion.cmake"
0036                         SOVERSION 6)
0037 # --
0038 ecm_set_disabled_deprecation_versions(
0039     QT 6.5
0040 )
0041 add_subdirectory(src)
0042 if (BUILD_TESTING)
0043     add_subdirectory(autotests)
0044     add_subdirectory(benchmarks)
0045 endif()
0046 add_subdirectory(examples)
0047
0048 # create a Config.cmake and a ConfigVersion.cmake file and install them
0049 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF6ThreadWeaver")
0050
0051 if (BUILD_QCH)
0052     ecm_install_qch_export(
0053         TARGETS KF6ThreadWeaver_QCH
0054         FILE KF6ThreadWeaverQchTargets.cmake
0055         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0056         COMPONENT Devel
0057     )
0058     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF6ThreadWeaverQchTargets.cmake\")")
0059 endif()
0060
0061 include(CMakePackageConfigHelpers)
0062
0063 configure_package_config_file("${CMAKE_CURRENT_SOURCE_DIR}/KF6ThreadWeaverConfig.cmake.in"
0064                               "${CMAKE_CURRENT_BINARY_DIR}/KF6ThreadWeaverConfig.cmake"
0065                               INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0066                               )
0067
0068 install(FILES ${threadweaver_version_header}
0069         DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/ThreadWeaver COMPONENT Devel)
0070
0071 install(FILES
0072   "${CMAKE_CURRENT_BINARY_DIR}/KF6ThreadWeaverConfig.cmake"
0073   "${CMAKE_CURRENT_BINARY_DIR}/KF6ThreadWeaverConfigVersion.cmake"
0074   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0075   COMPONENT Devel
0076 )
0077
0078 install(EXPORT KF6ThreadWeaverTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KF6ThreadWeaverTargets.cmake NAMESPACE KF6:: )
0079
0080 include(ECMFeatureSummary)
0081 ecm_feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)
0082
0083 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)