syndication/src/CMakeLists.txt

0001 add_library(KF5Syndication)
0002 add_library(KF5::Syndication ALIAS KF5Syndication)
0003
0004 set_target_properties(KF5Syndication PROPERTIES
0005     VERSION     ${SYNDICATION_VERSION}
0006     SOVERSION   ${SYNDICATION_SOVERSION}
0007     EXPORT_NAME Syndication
0008 )
0009
0010 target_sources(KF5Syndication PRIVATE
0011     # librss2local
0012     rss2/category.cpp
0013     rss2/cloud.cpp
0014     rss2/document.cpp
0015     rss2/enclosure.cpp
0016     rss2/image.cpp
0017     rss2/item.cpp
0018     rss2/parser.cpp
0019     rss2/source.cpp
0020     rss2/textinput.cpp
0021     rss2/tools_p.cpp
0022
0023     # librdflocal
0024     rdf/contentvocab.cpp
0025     rdf/document.cpp
0026     rdf/dublincore.cpp
0027     rdf/dublincorevocab.cpp
0028     rdf/image.cpp
0029     rdf/item.cpp
0030     rdf/literal.cpp
0031     rdf/model.cpp
0032     rdf/modelmaker.cpp
0033     rdf/node.cpp
0034     rdf/nodevisitor.cpp
0035     rdf/parser.cpp
0036     rdf/property.cpp
0037     rdf/rdfvocab.cpp
0038     rdf/resource.cpp
0039     rdf/resourcewrapper.cpp
0040     rdf/rssvocab.cpp
0041     rdf/sequence.cpp
0042     rdf/statement.cpp
0043     rdf/syndicationinfo.cpp
0044     rdf/syndicationvocab.cpp
0045     rdf/textinput.cpp
0046
0047     # libatomlocal
0048     atom/atomtools.cpp
0049     atom/category.cpp
0050     atom/constants.cpp
0051     atom/content.cpp
0052     atom/document.cpp
0053     atom/entry.cpp
0054     atom/generator.cpp
0055     atom/link.cpp
0056     atom/parser.cpp
0057     atom/person.cpp
0058     atom/source.cpp
0059
0060     # libmapperrss2local
0061     mapper/categoryrss2impl.cpp
0062     mapper/enclosurerss2impl.cpp
0063     mapper/feedrss2impl.cpp
0064     mapper/imagerss2impl.cpp
0065     mapper/itemrss2impl.cpp
0066
0067     # libmapperrdflocal
0068     mapper/feedrdfimpl.cpp
0069     mapper/imagerdfimpl.cpp
0070     mapper/itemrdfimpl.cpp
0071
0072     # libmapperatomlocal
0073     mapper/categoryatomimpl.cpp
0074     mapper/enclosureatomimpl.cpp
0075     mapper/feedatomimpl.cpp
0076     mapper/itematomimpl.cpp
0077
0078     # libsyndicationlocal
0079     abstractparser.cpp
0080     category.cpp
0081     constants.cpp
0082     dataretriever.cpp
0083     documentsource.cpp
0084     documentvisitor.cpp
0085     elementwrapper.cpp
0086     enclosure.cpp
0087     feed.cpp
0088     global.cpp
0089     image.cpp
0090     item.cpp
0091     loader.cpp
0092     person.cpp
0093     personimpl.cpp
0094     specificdocument.cpp
0095     specificitem.cpp
0096     specificitemvisitor.cpp
0097     tools.cpp
0098     loaderutil.cpp
0099 )
0100
0101 ecm_qt_declare_logging_category(KF5Syndication
0102     HEADER syndication_debug.h
0103     IDENTIFIER SYNDICATION_LOG
0104     CATEGORY_NAME kf.syndication
0105     OLD_CATEGORY_NAMES kf5.syndication
0106     DESCRIPTION "syndication"
0107     EXPORT SYNDICATION
0108 )
0109
0110 generate_export_header(KF5Syndication BASE_NAME syndication)
0111
0112 target_include_directories(KF5Syndication
0113     INTERFACE
0114         "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/Syndication;${KDE_INSTALL_INCLUDEDIR_KF}/Syndication/syndication>"
0115     PUBLIC
0116         "$<BUILD_INTERFACE:${Syndication_SOURCE_DIR}/src;${Syndication_BINARY_DIR}/src;${Syndication_BINARY_DIR}>"
0117 )
0118
0119 kde_target_enable_exceptions(KF5Syndication PUBLIC)
0120
0121 target_link_libraries(KF5Syndication
0122 PUBLIC
0123     Qt${QT_MAJOR_VERSION}::Core
0124 PRIVATE
0125     Qt${QT_MAJOR_VERSION}::Xml
0126     KF5::Codecs
0127 )
0128
0129 add_subdirectory(atom)
0130 add_subdirectory(rdf)
0131 add_subdirectory(rss2)
0132
0133 ecm_generate_headers(Syndication_CamelCase_HEADERS
0134   HEADER_NAMES
0135   AbstractParser
0136   Category
0137   Constants
0138   DataRetriever
0139   DocumentSource
0140   DocumentVisitor
0141   ElementWrapper
0142   Enclosure
0143   Feed
0144   Global
0145   Image
0146   Item
0147   Loader
0148   Mapper
0149   ParserCollection
0150   Person
0151   SpecificDocument
0152   SpecificItem
0153   SpecificItemVisitor
0154   Syndication
0155   Tools
0156
0157   PREFIX Syndication
0158   REQUIRED_HEADERS Syndication_HEADERS
0159 )
0160
0161
0162 install(TARGETS KF5Syndication EXPORT KF5SyndicationTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0163
0164 install(FILES
0165     ${CMAKE_CURRENT_BINARY_DIR}/syndication_export.h
0166     ${Syndication_HEADERS}
0167     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/Syndication/syndication
0168     COMPONENT Devel
0169 )
0170
0171 install(FILES
0172     ${Syndication_CamelCase_HEADERS}
0173     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/Syndication/Syndication
0174     COMPONENT Devel
0175
0176 )
0177
0178 ecm_qt_install_logging_categories(
0179     EXPORT SYNDICATION
0180     FILE syndication.categories
0181     DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0182 )
0183
0184 if(BUILD_QCH)
0185     ecm_add_qch(
0186         KF5Syndication_QCH
0187         NAME Syndication
0188         BASE_NAME KF5Syndication
0189         VERSION ${KF_VERSION}
0190         ORG_DOMAIN org.kde
0191         SOURCES # using only public headers, to cover only public API
0192             ${Syndication_HEADERS}
0193             ${Syndication_Atom_APIDOX_SRCS}
0194             ${Syndication_Rdf_APIDOX_SRCS}
0195             ${Syndication_Rss2_APIDOX_SRCS}
0196         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/Mainpage.dox"
0197         LINK_QCHS
0198             Qt5Core_QCH
0199         INCLUDE_DIRS
0200             ${CMAKE_CURRENT_BINARY_DIR}
0201         BLANK_MACROS
0202             SYNDICATION_EXPORT
0203             SYNDICATION_DEPRECATED
0204         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0205         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0206         COMPONENT Devel
0207     )
0208 endif()
0209
0210 ecm_generate_pri_file(BASE_NAME Syndication LIB_NAME KF5Syndication DEPS "" FILENAME_VAR PRI_FILENAME)
0211 install(FILES ${PRI_FILENAME} DESTINATION ${ECM_MKSPECS_INSTALL_DIR})